Sadece değerler yapıştırılsın.

[burhancavus61]

Sayfa2 ye sadece değerlerin yapıştırılmasını nasıl sağlarım. Nerden ve nasıl kopyalandığı önemli değil ama asıl amacım yapıştırma işlemi yapılırken sayfanın sadece değerleri alması sağlamak.

 

[Merhum İdris SERDAR]

.

Kopyalanmayan şey nasıl yapıştırılır?

.

 

[mustafa1205]

Bu işlemi Makro kaydet yöntemi ile de yapabilirsiniz

 

[burhancavus61]

Kopyalanacak tabiki hocam ama sayfaya değerleri yapıştırabilsin. Kopyalayıp sayfaya geldiğinde enterle yapıştırmasını engellemek amacım.

 

[burhancavus61]

Amacım enter tuşunu tamamen engellemek değil yapıştırma işleminde değerleri yapıştırı sağlamak.

 

[Korhan Ayhan]

Aşağıdaki kodları bu işlemi yapmak istediğiniz dosyanıza uygulayınız.

ThisWorkbook (BuÇalışmaKitabı);

Option Explicit

Private Sub Workbook_Activate()
    Application.OnKey "~", "Paste_Value"
    Application.OnKey "{ENTER}", "Paste_Value"
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    Application.OnKey "~"
    Application.OnKey "{ENTER}"
End Sub

Private Sub Workbook_Deactivate()
    Application.OnKey "~"
    Application.OnKey "{ENTER}"
End Sub

Private Sub Workbook_Open()
    Application.OnKey "~", "Paste_Value"
    Application.OnKey "{ENTER}", "Paste_Value"
End Sub

Boş bir modül;

Option Explicit

Sub Paste_Value()
    If Application.CutCopyMode = xlCopy Or Application.CutCopyMode = xlCut Then
        Selection.PasteSpecial Paste:=xlPasteValues
    Else
        Application.OnKey "~"
        Application.OnKey "{ENTER}"
        On Error Resume Next
        ActiveCell.Offset(1).Select
        On Error GoTo 0
    End If
End Sub

 

[burhancavus61]

Korhan Hocam çok teşekkür ederim çok güzel çalışıyor.