koşula göre tablo bağlama

[Fuat Şirin]

arkadaşlar ekli dosyamda
STOK sayfasında stokları giriyorum
TABLO sayfasındada bunları görüntülüyorum
2 cins giriş yaptım normalde bu yüzü buluyor belki daha fazla
benim istediğim stok sayfasında yazan stokları tabloya ilgili yere atması
yani ben ERKEK ATLET / BEYAZ / 5 = 100 dediğimde stokta tabloda ilgili yere atması
bunun için yardımcı olursanız sevinirim

 

[Fuat Şirin]

hocalarımdan bu konuda yardım bekliyorum
en azından bir yol olarak sölerseniz yapmaya çalışırım

 

[Ferhat Pazarçevirdi]

Merhabalar

Dosyada verdiğiniz örnekleri inceledim. Peki, ERKEK ATLET/MAVİ/5 diye bir stok girdiğinizde, "TABLO" adlı sheet'e ne yazılacak?

 

[Fuat Şirin]

tabloya verileri ben elle giricem
verdiğim örneğe benzer şekilde
ben bir tablo hazırlıcam stok sayfasına girdiğim veriler
tabloda ilgili yere gelmesi lazım
bunu ERKEK ATLET \ MAVİ \ 5
BAYAN KİLOT \ YEŞİL 3 gibi düşünün
bunu gibi bir tablo

 

[Fuat Şirin]

hocalarımdan yardım bekliyorum çok rica

 

[N.Ziya Hiçdurmaz]

yanıt

Tabloya girdiğiniz verileri enter dediğinizde ilgili yerlere aktarır.

Sub AUTO_OPEN()
Application.OnKey "{RETURN}", "aktar"
End Sub
Sub AUTO_close()
Application.OnKey "{RETURN}", ""
End Sub
Sub aktar()
Set SS = Sheets("STOK")
Set ST = Sheets("TABLO")
S = SS.[A65536].End(3).Row
SS.Range("A" & S + 1 & ":B" & S + 1) = ST.Range("A3:B3").Value
SS.Range("C" & S + 1) = ST.Range("C2").Value
SS.Range("D" & S + 1) = ST.Range("C3").Value
S = SS.[A65536].End(3).Row
SS.Range("A" & S + 1 & ":B" & S + 1) = ST.Range("A6:B6,C5,C6").Value
SS.Range("C" & S + 1) = ST.Range("C5").Value
SS.Range("D" & S + 1) = ST.Range("C6").Value
End Sub

 

[Fuat Şirin]

hocam çalıştıramadım
biraz açıklarsanız

 

[Fuat Şirin]

hocam birde ben stok sayfasındaki verileri
tablo sayfasına almasını istiyorum bir yanlışlık olmasın

 

[N.Ziya Hiçdurmaz]

Evet tam tersi olmuş.

 

[Fuat Şirin]

bu konuda hocalarımdan yardım bekliyorum
gerçekten çok önemli

 

[Ferhat Pazarçevirdi]

Merhabalar

Aşağıdakileri, "STOK" sheet'inin kod sayfasına kopyalayınız.

Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)
Dim shS As Worksheet, shR As Worksheet
Dim bul As Range
Dim Cinsi As Variant, Renk As Variant, No As Variant
Dim adres As String
Dim i As Integer
If Not Intersect(Target, Range("D2:D" & Cells(65536, 4).End(xlUp).Row)) Is Nothing Then
   Set shS = Sheets("STOK")
   Set shR = Sheets("TABLO")
   Cinsi = Target.Offset(, -3)
   Renk = Target.Offset(, -2)
   No = Target.Offset(, -1)
   Set bul = shR.Columns(1).Find(Cinsi, , , xlWhole)
   If Not bul Is Nothing Then
      adres = bul.Address
      Do
         If bul.Offset(, 1) = Renk Then
            For i = 3 To 8
                If shR.Cells(bul.Row - 1, i) = No Then
                   shR.Cells(bul.Row, i) = Target
                End If
            Next i
         End If
         Set bul = shR.Columns(1).FindNext(bul)
      Loop While Not bul Is Nothing And bul.Address <> adres
   End If
   Set bul = Nothing
   Set shS = Nothing
   Set shR = Nothing
End If
End Sub

 

[Fuat Şirin]

hocam kodlar çalışıyor ama şöle bişey var
ben mesela karışık olarak stok sayfasına giriş yapıyorum bu kayıtlar 2000 3000 i buluyor ben tablo sayfasına tabloyu yapıcam
mesela stok sayfasına ÇOCUK KİLOT / BEYAZ / 5 dirdiğimde
tabloda ilgili yere kaydetmesi lazım
mesela stokta ERKEK ATLET/ BEYAZ / 8 YOK
tablodada boş olması lazım
bilmiyorum açıklayıcı oldu mu?

 

[Fuat Şirin]

hocam tamam
kusura bakmayın
dediğim gibi oldu harika yapmışsınız
tam istediğim gibi

 

[Fuat Şirin]

hocam bir kaç giriş yaptım
ama şöle bişey var
enterle girmeden
tabloya geçmiyor
ben stok a otomatik atacağımdan
sorun olur mu
kopyala yapıştır ile ile gör müyor

 

[Ferhat Pazarçevirdi]

Açıkçası, açıklayıcı olmadı...

Çünkü, örnek dosyanızda; ÇOCUK KÜLOT / BEYAZ / 5 satırı, "TABLO" sheet'inde yok. "STOK" sheet'ine bu bilgiyi girdiğinizde, "TABLO" sayfasında yoksa, bu satır otomatik mi oluşturulacak?

Size gönderdiğim kodlar STOK sayfasının D sütununda herhangi bir değişiklik olduğunda çalışır. Eğer değiştirdiğiniz stokun, "TABLO" da karşılığı yoksa hiçbir işlem yapmaz.

Lütfen, mevcut dosyanız üzerinden örnekleme yapınız... Konuyu siz kafanızda canldırmaktasınız ama şu an olmayan veriler üzerinden bizim muhakeme yürütmemiz kolay olmuyor.

 

[Fuat Şirin]

kusura bakmayın

hocam kesinlikle haklısınız
kendimde okuduğumda pek bişey anlamadıom
dosyaya bir kaç giriş yaptım
açıklamayı dosyada ilgili yerse belirttim saygılar

 

[Ferhat Pazarçevirdi]

Bu son istediğiniz yöntem; göreceli olarak diğerine göre daha güvenilir.

Aşağıdaki kodu, standart bir modül sayfasına kopyalayarak çalıştırınız.

Option Explicit
Sub Getir()
Dim shS As Worksheet, shT As Worksheet
Dim Hucre As Range, Bul As Range
Dim adres As String
Dim i As Integer
Set shS = Sheets("STOK")
Set shT = Sheets("TABLO")
Set Hucre = shT.Cells(1, 1).End(xlDown)
Do While Hucre.Address <> Cells(65536, 1).Address
   shT.Range("C" & Hucre.Row & ":H" & Hucre.Row).ClearContents
   Set Hucre = Hucre.End(xlDown)
Loop
Set Hucre = shT.Cells(1, 1).End(xlDown)
Do While Hucre.Address <> Cells(65536, 1).Address
   Set Bul = shS.Columns(1).Find(Hucre, , , xlWhole)
   If Not Bul Is Nothing Then
      adres = Bul.Address
      Do
          If Bul.Offset(0, 1) = Hucre.Offset(0, 1) Then
             For i = 3 To 8
                 If Hucre.Offset(-1, i - 1) = shS.Cells(Bul.Row, 3) Then
                    shT.Cells(Hucre.Row, i) = shS.Cells(Bul.Row, 4)
                    Exit For
                 End If
             Next
          End If
          Set Bul = shS.Columns(1).FindNext(Bul)
      Loop While Not Bul Is Nothing And Bul.Address <> adres
   End If
   Set Hucre = Hucre.End(xlDown)
Loop
Set shS = Nothing
Set shT = Nothing
Set Hucre = Nothing
Set Bul = Nothing
End Sub

 

[Fuat Şirin]

Hocam tek kelime ile süper hatta süppppperrr
çok saolun Allah razı olsun