Soru Excel hücresindeki sayının dosya açıldığında farkedilmesi için yanıp sönmesi gerekmekte. Bu nasıl yapılır

[Ergün ÇUBUK]

Excel hücresindeki sayının dosya açıldığında farkedilmesi için yanıp sönmesi gerekmekte. Bu nasıl yapılır

 

[Korhan Ayhan]

Basit düzende uygulamayı tarif ediyorum..

Boş bir excel dosyası açınız.
A1:A20 hücrelerine =RASTGELEARADA(1;100) formülü yazınız. Bu adım yanıp sönme efektini daha net görebilmeniz içindir.

A1:A20 hücreleri seçiliyken koşullu biçimlendirme formül bölümünü açınız.
Formül kutusuna =VE($Z$1=".";A1<50) formülünü uygulayınız.
Aynı ekranda yazı rengini beyaz ve kalın olarak ayarlayınız. Yine aynı ekranda hücre dolgu rengini kırmızı olarak ayarlayıp bu adımı tamamlayınız.

Bu aşamadan sonra ALT+F11 ile kod penceresini açınız.
Soldaki ThisWorkbook (BuÇalışmaKitabı) bölümüne çift tıklayarak kod bölümüne aşağıdaki kodu uygulayınız.

Option Explicit

Private Sub Workbook_Activate()
    Application.OnKey "{F11}", "Alert_Stop"
    Application.OnKey "{F12}", "Alert_Start"
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    Application.OnKey "{F11}"
    Application.OnKey "{F12}"
End Sub

Private Sub Workbook_Deactivate()
    Application.OnKey "{F11}"
    Application.OnKey "{F12}"
End Sub

Private Sub Workbook_Open()
    Call Alert_On
   
    Application.OnKey "{F11}", "Alert_Stop"
    Application.OnKey "{F12}", "Alert_Start"
End Sub

Sonra çalışmaya boş bir modül ekleyiniz ve modüle aşağıdaki kodu uygulayınız.

Option Explicit
Public My_Check As Boolean

Sub Alert_On()
    If My_Check = True Then Exit Sub
    DoEvents
    Range("Z1") = "."
    Application.OnTime Now + TimeSerial(0, 0, 2), "Alert_Off"
End Sub

Sub Alert_Off()
    DoEvents
    Range("Z1") = Empty
    If My_Check = True Then Exit Sub
    Application.OnTime Now + TimeSerial(0, 0, 2), "Alert_On"
End Sub

Sub Alert_Start()
    My_Check = False
    Call Alert_On
End Sub

Sub Alert_Stop()
    My_Check = True
End Sub

Dosyayı makro içerebilen excel çalışma kitabı biçimiyle masaüstüne kayıt ediniz.

Son olarak dosyayı kapatıp yeniden makroları etkinleştirerek açınız. Dosya sürekli olarak yanıp sönme efektini yapabilmek için zamanlayıcı yardımıyla çalışacaktır. Bu sebeple durdurmak isterseniz F11 tuşuna basabilirsiniz. Tekrar çalıştırmak için F12 tuşuna basabilirsiniz.

 

[kulomer46]

Alternatif Çalışma Dosya açıldığında yanıp sönen hücre örneği

Merhaba

Excel dosyasının Workbook_Open() kısmına aşağıdaki kodlar yazılırsa dosya açıldığında örneğin B3 hücresi yanıp yanıp söner.

Hayırlı Çalışmalar Dilerim.

Örnek Kod Sayfası

 

[Ergün ÇUBUK]

Şöyle bir formül buldum, Koşullu Biçimlendirme ile yapılmakta, ancak bende yazı yanıp sönmemekte =TEKMİ(METNEÇEVİR(ŞİMDİ();"nn"))

 

[Korhan Ayhan]

Yanıp sönmesi için makro ile desteklemeniz gerekiyor..

 

[Ergün ÇUBUK]

Makrosu uygulandığında tüm dosya 1 saniye imleç dahil yanıp sönmekte

 

[Korhan Ayhan]

Bizim önerilerimizi deneyebilirsiniz..

 

[ÖmerBey]

Şöyle bir formül buldum, Koşullu Biçimlendirme ile yapılmakta, ancak bende yazı yanıp sönmemekte =TEKMİ(METNEÇEVİR(ŞİMDİ();"nn"))

F9 tuşuna basın. Tuşa basılı tuttuğunuz sürece yanıp söner.
Ya da Korhan Ayhan'ın önerdiği gibi makro kullanmalısınız.