Soru Eğerli Tarih farkı

[sirkülasyon]

ekli dosyamın
D sütununda "İlk ve Başlama" yazılı olduğu hücrenin yanındaki hücrede ki tarih Başlama Tarihi
D sütununda "Ayrılma" yazılı olduğu hücrenin yanındaki hücrede ki tarih Bitiş Tarihi
olarak alacak ve tarih farkını "Ayrılma" yazan hücrenin sağına iki tarih farkını yazacak bir formüle ihtiyacım var.
Teşekkür ederim.

 

[ÖmerFaruk]

Üç formül de dizi formülüdür. Ctrl+Shift+Enter ile giriniz
Verdiğiniz örnek dosyada F5-G5-H5 hücrelerine kopyalayın, aşağıda doğru sürükleyerek çoğaltabilirsiniz.

'F5 hücresine
=EĞER($D5="Ayrılma";ETARİHLİ(EĞER(D5="Ayrılma";İNDİS($E$4:$E5;BÜYÜK(EĞER($D$4:$D5="Başlama";SATIR($D$4:$D5)-SATIR($D$4)+1);EĞERSAY($D$4:D4;D4)));"");$E5;"y");"")

'G5 Hücresine
=EĞER($D5="Ayrılma";ETARİHLİ(EĞER(D5="Ayrılma";İNDİS($E$4:$E5;BÜYÜK(EĞER($D$4:$D5="Başlama";SATIR($D$4:$D5)-SATIR($D$4)+1);EĞERSAY($D$4:D4;D4)));"");$E5;"m");"")

'H5 hücresine
=EĞER($D5="Ayrılma";EĞER(GÜN(EĞER(D5="Ayrılma";İNDİS($E$4:$E5;BÜYÜK(EĞER($D$4:$D5="Başlama";SATIR($D$4:$D5)-SATIR($D$4)+1);EĞERSAY($D$4:D4;D4)));""))-GÜN($E5)<0;GÜN($E5)-GÜN(EĞER(D5="Ayrılma";İNDİS($E$4:$E5;BÜYÜK(EĞER($D$4:$D5="Başlama";SATIR($D$4:$D5)-SATIR($D$4)+1);EĞERSAY($D$4:D4;D4)));""));GÜN(SERİAY(EĞER(D5="Ayrılma";İNDİS($E$4:$E5;BÜYÜK(EĞER($D$4:$D5="Başlama";SATIR($D$4:$D5)-SATIR($D$4)+1);EĞERSAY($D$4:D4;D4)));"");0))-GÜN(EĞER(D5="Ayrılma";İNDİS($E$4:$E5;BÜYÜK(EĞER($D$4:$D5="Başlama";SATIR($D$4:$D5)-SATIR($D$4)+1);EĞERSAY($D$4:D4;D4)));""))+GÜN($E5));"")

Formüllerin işlenmiş haliyle dosyanız da ektedir.

 

[ÖmerFaruk]

H5 hücresinin formülünü ETARİHLİ fonksiyonuyla daha kısa yapbiliyoruz.

=EĞER($D10="Ayrılma";ETARİHLİ(EĞER(D10="Ayrılma";İNDİS($E$4:$E10;BÜYÜK(EĞER($D$4:$D10="Başlama";SATIR($D$4:$D10)-SATIR($D$4)+1);EĞERSAY($D$4:D9;D9)));"");$E10;"Md");"")

 

[sirkülasyon]

Ustam
Teşekkür ederim. Ellerine Sağlık.

 

[sirkülasyon]

Sayın NextLevel
Tarih (yıl, ay, gün) hatalı sanki

 

[ÖmerFaruk]

#2 nlo mesajımdaki cevap dosyasında sizin tarihlerle denedim ve hata yoktu.
Hata olduğunu söylediğiniz Başlama ve Ayrılma tarihlerini yazar mısınız?

 

[sirkülasyon]

Ustam
2 nolu mesajda en alt tarih (2 Yıl, 25 Ay, 29 Gün)
22.09.2018 - 21.11.2020
2 yıl 1 ay 30 gün diye hesapladım

 

[ÖmerFaruk]

Haklısın
=EĞER($D5="Ayrılma";ETARİHLİ(EĞER(D5="Ayrılma";İNDİS($E$4:$E5;BÜYÜK(EĞER($D$4:$D5="Başlama";SATIR($D$4:$D5)-SATIR($D$4)+1);EĞERSAY($D$44;D4)));"");$E5;"m");"")

Formülün en sonundaki "m" yerine "YM" olarak değiştirip, dizi formülü olarak G sütununa kopyalayalım.

 

[sirkülasyon]

teşekkür ederim

 

[ÖmerFaruk]

Hepsi dizi formülü olmaz üzere, aşağıdakileri kullanırsanız olacak
F sütunu
=EĞER($D10="Ayrılma";ETARİHLİ(İNDİS($E$4:$E9;BÜYÜK((EĞER($D$4:$D9="Başlama";1;0))*(SATIR($D$4:$D9));1)-3);$E10;"Y");"")

G sütunu
=EĞER($D10="Ayrılma";ETARİHLİ(İNDİS($E$4:$E9;BÜYÜK((EĞER($D$4:$D9="Başlama";1;0))*(SATIR($D$4:$D9));1)-3);$E10;"YM");"")

H sütunu
=EĞER($D10="Ayrılma";ETARİHLİ(İNDİS($E$4:$E9;BÜYÜK((EĞER($D$4:$D9="Başlama";1;0))*(SATIR($D$4:$D9));1)-3);$E10;"MD");"")

 

[Ramocino]

Üstadlar benimde ekteki şekilde tarihleri AA Sütünuna b yazdırmak istiyorum.
Yani AA1 de 12 yazıyor ise giriş tarihi 12 ise b veya çıkış tarihi 12 ay ise b veya giriş tarihi ve çıkış tarihi ay olarak eşit ise b veya giriş tarihi 12 de küçük ve çıkış tarihi 12 den büyük ise yani ay olarak ortasında ise yine b yazsın değil

 

[ÖmerFaruk]

=EĞER(YADA(VE(AY(E2)<$AA$1;AY(F2)>$AA$1);AY(E2)=AY(F2);AY(E2)=$AA$1;AY(F2)=$AA$1);"b";"")

Ancak dosyanızda ve sorunuzda aşağıdaki sıkıntılar var.

• 2.satırda 30.02.2021 bir tarih değildir.
• Son önermenizde belirttiğiniz şekilde çıkış tarihi mesela 12.01.2021 ise bu 12.aydan büyük mü küçük mü anlamına geliyor

 

[Ramocino]

Evet haklısınız 28.02.2021 olacak.
01.2021 tarihi 12.2020 tarihinden büyük olacak hocam.

 

[Ramocino]

AA1 de 12 varsa

01.12.2020 - 31.12.2020 12 ay var "B" yaz
01.11.2020 - 30.11.2020 12 ay yok 0 yaz
01.11.2020 - 01.01.2021 arada 12 ay var "B" yaz
01.01.2021 - 05.05.2021 12 ay yok 0 yaz
01.08.2020 - 01.12.2020 12 ay var "B" yaz
01.12.2020 - 01.01.2021 12 ay var "B" yaz

 

[ÖmerFaruk]

=EĞER(VE(YADA(VE(AY(E2)<>$AA$1;AY(F2)<>$AA$1;EĞER(YIL(E2)<YIL(F2);VE(E2<TARİH(YIL(E2);$AA$1;SERİTARİH(TARİH(YIL(E2);$AA$1;1);0)<F2));VE(MİN(AY(E2);AY(F2);$AA$1)<>$AA$1;MAK(AY(E2);AY(F2);$AA$1)<>$AA$1)));AY(E2)=$AA$1;AY(F2)=$AA$1;AY(E2)=AY(F2));E2<>"";F2<>"");"b";"")

 

[Ramocino]

Hocam ekledim çok sağolun. Ekteki şekilde hata verdi.

 

[ÖmerFaruk]

Evet haklısınız 28.02.2021 olacak

Halen aynı yerde düzeltmeden takılmışsınız.

 

[Ramocino]

Evet hocam haklısınız teşekkür ederim. Bu mavileri niye böyle yaptı anlamadım.

 

[ÖmerFaruk]

Çünkü #11 nolu mesajınızda demiştiniz ki;
"Üstadlar benimde ekteki şekilde tarihleri AA Sütünuna b yazdırmak istiyorum.
Yani AA1 de 12 yazıyor ise giriş tarihi 12 ise b veya çıkış tarihi 12 ay ise b veya giriş tarihi ve çıkış tarihi ay olarak eşit ise b veya giriş tarihi 12 de küçük ve çıkış tarihi 12 den büyük ise yani ay olarak ortasında ise yine b yazsı "

 

[Ramocino]

Konuya tam olarak hakim olamadığınızda dediğiniz durum ortaya çıkıyor. Çok haklısınız. Mazur görünüz.