Soru Formül ile benzersiz tarih verileri getirme

[Seli]

Arkadaşlar herkese selamlar uzun bir aradan sonra tekrar sizinleyim umarım herkes için her şey yolundadır. Soruma gelecek olursam öncelikle eğitim tarihleri tekrar eden bir veri setim var burdan özet sayfasına benzersiz B sütunu ile en son alınan eğitim tarihinin c ve d sütun karşılıklarını özet sayfasına getirmek istiyorum nasıl yapabilirim formül ile yardımcı olabilir misiniz, ofis 365 kullanıyorum. herkese selamlar sevgiler.dosya linktedir

 

[Korhan Ayhan]

Merhaba,

ofis 365 kullanıyorum

Bu bilgiyi rica etsem profilinizde yazan "İngilizce" yazan bölümde de güncellermisiniz.

 

[Seli]

Merhaba,



Bu bilgiyi rica etsem profilinizde yazan "İngilizce" yazan bölümde de güncellermisiniz.

Tabii ki hocam

 

[Korhan Ayhan]

Deneyiniz..

=SIRALA(LET(Tablo;SIRALA(Sheet1!A2:D15;;-1);
            Sicil_No;İNDİS(Tablo;;2);
            Benzersiz_Sicil_No;BENZERSİZ(Sicil_No);
            İNDİS(Tablo;KAÇINCI(Benzersiz_Sicil_No;Sicil_No;0);SIRALI(1;SÜTUNSAY(Tablo))));2)

 

[Seli]

Deneyiniz..

=SIRALA(LET(Tablo;SIRALA(Sheet1!A2:D15;;-1);
            Sicil_No;İNDİS(Tablo;;2);
            Benzersiz_Sicil_No;BENZERSİZ(Sicil_No);
            İNDİS(Tablo;KAÇINCI(Benzersiz_Sicil_No;Sicil_No;0);SIRALI(1;SÜTUNSAY(Tablo))));2)

Hocam 2013 versiyon ile nasıl yapabilirim? benzersiz modülü gönderdiğim excellerde çalışmıyor

 

[Seli]

Hocam cevap yok mudur?

 

[Korhan Ayhan]

Deneyiniz..

B2; (Dizi Formül)

=EĞERHATA(İNDİS(Sheet1!$B$2:$B$15;KAÇINCI(0;EĞERSAY(B$1:B1;Sheet1!$B$2:$B$15);0));"")

A2; (Dizi Formül)

=EĞER(B2="";"";MAK(EĞER(Sheet1!$B$2:$B$15=B2;Sheet1!$A$2:$A$15)))

C2;

=EĞERHATA(İNDİS(Sheet1!$C$1:$C$15;TOPLAMA(15;6;SATIR(Sheet1!$C$2:$C$15)/(Sheet1!$A$2:$A$15=A2)*(Sheet1!$B$2:$B$15=B2);1));"")

D2;

=EĞERHATA(İNDİS(Sheet1!$D$1:$D$15;TOPLAMA(15;6;SATIR(Sheet1!$C$2:$C$15)/(Sheet1!$A$2:$A$15=A2)*(Sheet1!$B$2:$B$15=B2);1));"")

 

[Seli]

Deneyiniz..

B2; (Dizi Formül)

=EĞERHATA(İNDİS(Sheet1!$B$2:$B$15;KAÇINCI(0;EĞERSAY(B$1:B1;Sheet1!$B$2:$B$15);0));"")

A2; (Dizi Formül)

=EĞER(B2="";"";MAK(EĞER(Sheet1!$B$2:$B$15=B2;Sheet1!$A$2:$A$15)))

C2;

=EĞERHATA(İNDİS(Sheet1!$C$1:$C$15;TOPLAMA(15;6;SATIR(Sheet1!$C$2:$C$15)/(Sheet1!$A$2:$A$15=A2)*(Sheet1!$B$2:$B$15=B2);1));"")

D2;

=EĞERHATA(İNDİS(Sheet1!$D$1:$D$15;TOPLAMA(15;6;SATIR(Sheet1!$C$2:$C$15)/(Sheet1!$A$2:$A$15=A2)*(Sheet1!$B$2:$B$15=B2);1));"")

Çok teşekkür ederim hocam emeğinize sağlık