çok koşullu benzersiz formülleri

[modoste]

merhaba sayın hocalarım
bu konu ile ilgili çok soru sordum ama (çok karşıma çıkıyo ve raporlarda çok kullanıyorum) hala takıldığım yada formülün dosyayı yorduğu durumlar var
an itibariyle
=EĞERHATA(İNDİS($AS$8:$AS$10000;KÜÇÜK(EĞER(SIKLIK(EĞER(($AR$8:$AR$10000>=$BR$4)*($AR$8:$AR$10000<=$CG$4)*($AO$8:$AO$10000=BR$7);KAÇINCI("~"&$AS$8:$AS$10000;$AS$8:$AS$10000&"";0));SATIR($AS$8:$AS$10000)-SATIR($AS$8)+1);SATIR($AS$8:$AS$10000)-SATIR($AS$8)+1);$BQ8));"") bu formülle sonuç buluyorum ancak 10000 satırlık dosyada dosya yavaşlatıyo.

aggregate ile olan formül ile koşul yokken yada tek koşul varken kullanıyorum ancak birden fazla koşul olduğunda formülü tamamlayamıyorum
eklediği formülün alternatifleri gerekmekte
office 2019 kullanmaktayım

 

[modoste]

formülü sarı yere yazıp sağa doğru ve aşağıya çektiğimde formülün tamamlanması 10 saniyeyi geçiyo o yüzden alternatif formüller denemekteyim ama şimdi yine takıldım

 

[modoste]

çok koşullu benzersiz listelerle ilgili biryerde çözüm yapılmış, eklemek istedim

 

[modoste]

ekli dosyadaki çözümün alternatifleri. çok koşullu benzersiz listeler yazabilir miyiz.
office 2019 kullanmaktayım

tek seferlik çözümlerde yardımcı hücrelerle çözümler yapıyorum ancak resimdeki gibi birden fazla veri grubunda koşullu benzersiz ihtiyaç duyduğumda alternatif formüllere ihtiyaç duymaktayım şu ana kadar
EĞERHATA(İNDİS($AS$8:$AS$10000;KÜÇÜK(EĞER(SIKLIK(EĞER(($AR$8:$AR$10000>=$BR$4)*($AR$8:$AR$10000<=$CG$4)*($AO$8:$AO$10000=BR$7);KAÇINCI("~"&$AS$8:$AS$10000;$AS$8:$AS$10000&"";0));SATIR($AS$8:$AS$10000)-SATIR($AS$8)+1);SATIR($AS$8:$AS$10000)-SATIR($AS$8)+1);$BQ8));"") bu formül grubunu kullanarak çözdüm ancak dosya yavaşlamasına sebep oluyo bazı formüller işte bu yüzden birkaç kere bu konu ile ilgili soru sordum eski sorularıma ve çözümlere de baktım

 

[Korhan Ayhan]

10.000 satır diyorsunuz.. Çok koşul diyorsunuz... Yavaş çalışması gayet doğaldır..

Yardımcı sütun kullanmayı deneyebilirsiniz. (Gerçi siz bu yöntemi pek kullanmayı tercih etmiyorsunuz ama yinede hatırlatmak istedim.)

 

[modoste]

satır sayısı 10000 olabiliyo geçebiliyo bir yada 2 yıllık motorin tablolarından dinamik bir şekilde seçilen zaman aralıklarında seçilen makine gruplarına denk gelen çalışan araçları benzersiz bulmam gerekiyo ve tek seferlik olduğunda artık yardımcı sütun kullanıyorum hocam emin olun hatta kaydır ile dinamik alan yapıp olabildiğince tek sütuna çevirip çözmeye çalışıyorum ama resimdeki gibi 14 farklı makine gruplarında benzersiz liste ile bulmam gerekince ihtiyaç duyuyorum

 

[Korhan Ayhan]

İşin içinde çok satır ve çok koşul olunca pek performans beklemenizi tavsiye etmem.

Performans için farklı teknikleri deneyebilirsiniz. Mesela makro kullanabilirsiniz. Yok ben ısrarla formülle çözüm arayışındayım diyorsanız ofis 365 sürümünü deneyebilirsiniz.

 

[modoste]

office 365 çok iyi ama hocam diğer kullanıcılar eski versiyonlar olunca sizler biliyonuz zaten, office 365 yeni formülleri eski versiyonda açıkken hata oluşuyo şu an için kullanışlı değil benim için makro zaten kullanmıyorum bu tip çalışmalarda çok çok değişkenlik gösteriyo benim çalıştığım dosyalar ve karşıma çıkan dosyalar ve kod makro bilgim yok zaten
işi yokuşa sürmek istemem ama benimde çalışma şeklim bu hocam, soruyu iletmeden önce rahmetli hocamızın sitesinden indiridğim koşullu benzersizleri bulma alternatif çalışmalara da baktım ama işte en çok İNDİS(ARALIK;TOPLAMA(15;6; ..... bu formül grubunda çözüm merak ediyorum ve koşulsuz benzersiz bulmada kullanıyorum ama işin içine koşullar girince doğru sonuçları alamadım

 

[Korhan Ayhan]

Umarım aradığınız sonuca ulaşabilirsiniz.

 

[52779]

..... ama işte en çok İNDİS(ARALIK;TOPLAMA(15;6; ..... bu formül grubunda çözüm merak ediyorum ve koşulsuz benzersiz bulmada kullanıyorum ama işin içine koşullar girince doğru sonuçları alamadım

İşin 10.000 satır için performans olayını bir tarafa bırakarak,

İNDİS - TOPLAMA işlevleri kullanarak Çok Koşul için Listedeki Sırasıyla ve Alfabetik Sıralı olarak Benzersizlerin bulunmasına örnek olsun....
Dosyanızı göremediğim için, tablo ile örnek...

Başlıklar : A1 : E1
Veriler : A2 : E79 aralığında ama tablo için 20 satır veri alındı.
Koşullar : H2 : H5 aralığında olmak üzere 4 adet koşul

Listedeki sırasına göre Benzersizler J2 hücresine formül yazılır aşağıya doğru kopyalanır.
(Formül J2 de ama J1 hücresine başvuru yapmakta. Bu nedenle J1 hücresinde yazılan ibare Ürün kolonunda olmayan bir ibare olmalıdır.)

=EĞERHATA(İNDİS(A:A;TOPLAMA(15;6;SATIR($A$2:$A$1000)/($B$2:$B$1000=$H$2)/($C$2:$C$1000=$H$3)/($D$2:$D$1000=$H$4)/($E$2:$E$1000>$H$5)/(EĞERSAY(J$1:J1;$A$2:$A$1000)=0);1));"")

Not : Daha fazla koşul da eklenebilir. Eklemek için koşulları Bölü İşareti ve Parantez içerisinde Koşul şeklinde yazabilirsiniz.

Alfabetik Sıralı olarak ise K2 hücresine formül yazılır ve aşağıya kopyalanır.

=EĞERHATA(İNDİS(A:A;MOD(TOPLAMA(15;6;EĞERSAY($A$2:$A$1000;"<"&$A$2:$A$1000)*10^6+SATIR($A$2:$A$1000)/($B$2:$B$1000=$H$2)/($C$2:$C$1000=$H$3)/($D$2:$D$1000=$H$4)/($E$2:$E$1000>$H$5)/(EĞERSAY(K$1:$K1;$A$2:$A$1000)=0);1);10^6));"")

(Formül K2 de ama K1 hücresine başvuru yapmakta.)

	A​	B​	C​	D​	E​	F​	G​	H​	I​	J​	K​
1​	Ürün​	Renk	Beden​	E/K​	Adet​		Koşullar			Benz. Ürün​	Alf. Benz​
2​	B​	Mavi	L​	E​	14​		Renk	Siyah​		A​	A​
3​	A​	Siyah	L​	E​	4​		Beden	M​		C​	B​
4​	C​	Siyah	L​	K​	7​		E/K	E​		B​	C​
5​	B​	Mavi	L​	K​	12​		Adet >	5​
6​	A​	Mavi	S​	E​	7​
7​	C​	Mavi	M​	E​	10​
8​	A​	Siyah	M​	K​	7​
9​	B​	Gri	S​	E​	7​
10​	B​	Mavi	M​	E​	11​
11​	A​	Mavi	S​	K​	15​
12​	B​	Mavi	S​	K​	11​
13​	C​	Mavi	L​	K​	10​
14​	A​	Siyah	S​	E​	6​
15​	B​	Mavi	S​	E​	13​
16​	C​	Gri	S​	E​	11​
17​	B​	Siyah	S​	K​	8​
18​	B​	Siyah	L​	E​	4​
19​	B​	Siyah	L​	K​	13​
20​	A​	Mavi	L​	K​	10​

 

[modoste]

sayın 52779 örneğinizi excele yazıp formülü denedim ama kriterlere göre sonuç vermiyo
sizin örneğinizdede kriterlere bakarsak yanlış sonuç vermişsiniz (Beden sütununda 3 adet "M" var ve bu "M" ler içinde sadece 1 adet "SİYAH" eşleşiyo). dosyayı ekledim çözüm yapabilir miyiz.

 

[modoste]

11 nolu mesajımı dikkate almadan direk bu mesajımdan devam edebiliriz
ben formülü ve verileri revize edip ve bir alternatif formül daha ekleyip bir çözüme ulaştım, diğer alternatif formüller ile çözümler beklemekteyim

 

[modoste]

uygulaması ve anlaması açısından bu formülü kullanarak devam edicem. eski formülden çok daha hızlı şekilde sonuç verdi. çok saniye bekletmedi şeçilen başlangıç ve bitiş tarihi ve seçilen araç sınıfına göre (3 koşullu) benzersiz listeleme uygulaması, formülü BR8 e yazdıktan sonra yatay ve düşey kopyalayıp sonuçlara ulaşıldı.

 

[52779]

11 nolu mesajımı dikkate almadan direk bu mesajımdan devam edebiliriz

Ben yine de, verdiğim formülle ilgili olduğundan 11 no lu mesaja cevap vereceğim.

sayın 52779 örneğinizi excele yazıp formülü denedim ama kriterlere göre sonuç vermiyo
sizin örneğinizdede kriterlere bakarsak yanlış sonuç vermişsiniz (Beden sütununda 3 adet "M" var ve bu "M" ler içinde sadece 1 adet "SİYAH" eşleşiyo).

Mesajımda da belirtmiştim

Veriler : A2 : E79 aralığında ama tablo için 20 satır veri alındı.

Normalde 78 satır veri var. Tabloya da tümünü yazmaya çalıştım, ama, Mesajınız 15000 karakterden daha az olmalıdır diye bir uyarı gelince, tablodaki satırların çoğunu sildim. Dolayısıyla örnek tablo, gerçek veri tablosunun çeyreğini ancak gösteriyor.

Önemli olan formüllerin yapısı dedim ve mesajımı ekleyip cevap yazdım.

İNDİS - TOPLAMA işlevleri kullanarak Çok Koşul için Listedeki Sırasıyla ve Alfabetik Sıralı olarak Benzersizlerin bulunmasına örnek olsun....
Dosyanızı göremediğim için, tablo ile örnek...

Dosya olarak ekliyorum. İncelersiniz.

Download files - Filemail

Click here to view and download these shared files from Filemail.com

www.filemail.com

 

[modoste]

teşekkür ederim sayın 52779

 

[52779]

Ben teşekkür ediyorum...
İyi çalışmalar sizlere...