Yazılan veriye göre ilgili sheetinden veri getirme

[u.L.a.s]

Merhabalar

aşağıdaki linkteki dosyada örnek dosyam mevcuttur. bu dosyada daha ayrıntılı ve daha anlaşılır yazdım aşağıda yazdığım biraz anlaşılmaz şekilde olacaktır. o yüzden dosyayı indirerek bakabilirseniz sevinirim. bütün formüllerde o dosya içerisinde mevcuttur o formülleri belirttiğim şekle göre düzenlemek gerekiyor.

kısaca özetlemem gerekirse bir formül yazacağım. örneğin vlookup formülü diyelim bunu sheet1 de yazdığımı düşünürsek
benimde iki ayrı sheetim varsa bu sheetlerden birisi aa.aa.0.0 diğeri aa.bb.0.0 şeklindeyse
benim sheet1 de b3 te vlookuplı bir formülüm varsa. bu formülde ben b2 hücresindeki veriyi diğer sheetlerde arıyorsam. b2 hücresindeki verinin başlangıç şeklinde göre ilgili sheetten veriyi bulsun getirsin istiyorum. yani b2 hücresine aa.aa. ile başlayan veri yazmışsam b3 teki vlookup formülü gitsin aa.aa.0.0 sheetinden veriyi bulsun getirsin
eğer ben b2ye aa.bb diye aşlayan bir veri yazmışsam örneğin aa.bb.10.10 diye. bu veriyide aa.bb.0.0 sheetinde arayıp getirmesi gerekiyor.

bilgi ve yardımlarınızı rica ederim

http://s7.dosya.tc/server11/envtr3/ornek.xlsx.html

 

[turist]

B3 hücresine formülü:
=VLOOKUP(B2;INDIRECT("'"&LEFT(B2;5)&".0.0'!C:E");2;0)
=DÜŞEYARA(B2;DOLAYLI("'"&SOLDAN(B2;5)&".0.0'!C:E");2;0) (Türkçe Dil versiyonu için)
şeklinde uygulayın, diğer hücrelerde de bu yazılış mantığına uygun formüllerinizi revize edebilirsiniz.

 

[uzmanamele]

=EĞERHATA(DÜŞEYARA(B2;'10.26.0.0'!C;2;0);DÜŞEYARA(B2;'10.22.0.0'!C;2;0))

 

[u.L.a.s]

turist üstadım vlookup formüllerine dediğiniz gibi revizeyi yaptım. ama a1 hücresindeki formül varya. aşağıdaki formül düzeneğini revize edemedim. her ne yaptıysam hep bir hata verdi. aşağıdaki formül konusunda bahsettiğim mevzu hususunda yardımlarınızı rica ederim

=MID(INDEX('10.26.0.0'!$B$2:$B$10000;MATCH(B2;'10.26.0.0'!$C$2:$C$10000;0));FIND("ATM";INDEX('10.26.0.0'!$B$2:$B$10000;MATCH(B2;'10.26.0.0'!$C$2:$C$10000;0)));50)

 

[turist]

INDIRECT("'"&LEFT(B2;5)&".0.0'!C:E")
kısmını INDEX ve MATCH kısımlarında uygulayın.

 

[u.L.a.s]

dediğiniz gibi çok defa uyguladım. ama enter basınca bir hata geliyor sürekli o hatada ikinici INDIRECT formülündeki ("'" konumlanıyor. hani ilk INDIRECT te sorun yok gibi ama formülün ilerleyen yerlerinde koyduğum yani ilk MATCH(B2;INDIRECT("'" yerine konumlanıyor. acaba MATCH(B2; de noktalı virgülmü konulmayacak

 

[turist]

MATCH(B2;INDIRECT("'"&LEFT(B2;5)&".0.0'!$C$2:$C$10000");0)
olacak

 

[u.L.a.s]

üstadım selamlar A1 hücresindeki formülde gerekli yerlerde revize yapıyorum ama aşağıdaki resimdeki gibi hata veriyor sürekli. bu formül diğer sayfada veriyi bulup sol sütunda ilgili satırındaki veriyi getiren bir formül. yani vlookupın tersi işlemi yapıyor. acaba ondan kaynaklanan bir sorun mu var. örnek dosyamı aşağıda ekledim. formülde = olmadan a1 hücresinde bıraktım. bakarsanız sevinirim.



http://s7.dosya.tc/server11/tkp3hj/ornek.xlsx.html

 

[turist]

=MID(INDEX(INDIRECT("'"&LEFT(B2;5)&".0.0'!$B$2:$B$10000");MATCH(B2;INDIRECT("'"&LEFT(B2;5)&".0.0'!$C$2:$C$10000");0));FIND("ATM";INDEX(INDIRECT("'"&LEFT(B2;5)&".0.0'!$B$2:$B$10000");MATCH(B2;INDIRECT("'"&LEFT(B2;5)&".0.0'!$C$2:$C$10000");0)));50)

 

[u.L.a.s]

ellerine sağlık emeğine bilgine sağlık üstadım. çok teşekkür ederim.

 

[turist]

ellerine sağlık emeğine bilgine sağlık üstadım. çok teşekkür ederim.

Sağ olun.

 

[u.L.a.s]

Üstadım Selam yine benzer bir problemle karşındayım

Bu seferde şu formül üstünde uğraşıyorum ama ne yaptıysam hep hata veriyor. ya #VALUE getiriyor ya #REF getiriyor ya popoup bir hata veriyor.

kod şu şekilde

INDIRECT("aa.aa.0.0!B" & MATCH(C8;'aa.aa.0.0'!$C:$C;0))

ama bu kodu hem aa.aa.0.0 sheetinde hemde aa.bb.0.0 sheetinden veri getirecek şekilde yazmalıyım. yani kod üstünde ben aa.aa.xx.xx yazdığımda aa.aa.0.0 sheetine bakacak aa.bb.xx.xx yazdığımda aa.bb.0.0 sheetine bakarak veri getirecek.

en son şu kodu yazdım ama buda hata verdi
=INDIRECT("'"&LEFT(C3;5)&".0.0'!B" & MATCH(C3;LEFT(C3;5)&".0.0'!$C:$C";0))

yardımını rica ediyorum

Teşekkürler tekrardan

 

[turist]

=INDIRECT("'"&LEFT(C3;5)&".0.0'!$B"&MATCH(C8;INDIRECT("'"&LEFT(C3;5)&".0.0'!$C:$C");0))

 

[u.L.a.s]

Üstadım fazlasıyla teşekkür ederim. emeğine bilgine sağlık