sadece sayfa1 e gecince tam ekran yapmak

[dennisf06]

merhaba,

asagidaki kodlarlar ile excel calisma kitabini tam ekran yapiyorum. sadece sayfa1 i tam ekran yapmak mümkün mü ? sayfalar arasi makro ile gidiyorum. sayfa2,sayfa3 den.. sayfa1 e gecince tam ekran, tersinde menüler olsun. tesekkürler.

Sub Autpen()
With Application
.ScreenUpdating = False
.CommandBars("toolbar list").Enabled = False
.CommandBars("Worksheet Menu Bar").Enabled = False
.CommandBars("Cell").Enabled = False
.DisplayFormulaBar = True
.DisplayStatusBar = True
.DisplayFullScreen = True
End With
With ActiveWindow
.DisplayHorizontalScrollBar = False
.DisplayVerticalScrollBar = False
.DisplayWorkbookTabs = False
.DisplayHeadings = False
.WindowState = xlMaximized
End With
End Sub

Sub Auto_Close()
Application.WindowState = xlNormal
End Sub

 

[Korhan Ayhan]

Merhaba,

Aşağıdaki kodları deneyiniz.

Eski kodlarınızı silin.

Boş bir modüle;

Sub Menuleri_Gizle()
    Application.ScreenUpdating = False
    For Each Menu In Application.CommandBars
        Menu.Enabled = False
    Next
    Application.ExecuteExcel4Macro "SHOW.TOOLBAR(""Ribbon"",False)"
    Application.DisplayFormulaBar = False
    Application.DisplayStatusBar = False
    With ActiveWindow
        .DisplayHorizontalScrollBar = False
        .DisplayVerticalScrollBar = False
        .DisplayWorkbookTabs = False
        .DisplayHeadings = False
        .WindowState = xlMaximized
    End With
    Application.ScreenUpdating = True
End Sub

Sub Menuleri_Goster()
    Application.ScreenUpdating = False
    For Each Menu In Application.CommandBars
        Menu.Enabled = True
    Next
    Application.ExecuteExcel4Macro "SHOW.TOOLBAR(""Ribbon"",True)"
    Application.DisplayFormulaBar = True
    Application.DisplayStatusBar = True
    With ActiveWindow
        .DisplayHorizontalScrollBar = True
        .DisplayVerticalScrollBar = True
        .DisplayWorkbookTabs = True
        .DisplayHeadings = True
        .WindowState = xlMaximized
    End With
    Application.ScreenUpdating = True
End Sub

BuÇalışmaKitabı (ThisWorkBook) bölümüne;

Private Sub Workbook_Activate()
    If ActiveSheet.Name = "Sayfa1" Then
        Menuleri_Gizle
    Else
        Menuleri_Goster
    End If
End Sub

Private Sub Workbook_Deactivate()
    Menuleri_Goster
End Sub

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
    If Sh.Name = "Sayfa1" Then
        Menuleri_Gizle
    Else
        Menuleri_Goster
    End If
End Sub

 

[dennisf06]

Korhan hocam harika calisti. Allah yeni senede de sizleri basimizdan eksik etmez insallah. elleriniz dert görmesin.