makro ile çoketopla

[metin80]

=ÇOKETOPLA(satış!$K:$K;satış!$A:$A;$H$2;satış!$E:$E;$E3)

bu formulu yaşlandırma adında sayfanın h3 hücresine yazıp aşağı doğru çekip
e stunun girilmiş verilere göre satış sayfasından çekip işlemi yapabiliyorum.
bunu makro ile yapabilme şansımız varmı

 

[Ömer]

Merhaba,

Bu şekilde deneyin.

Sub BulTopla()
 
    Dim Ss As Worksheet, c As Range, i As Long, Adr As String
 
    Set Ss = Sheets("satış")
    
    Application.ScreenUpdating = False
    Sheets("yaşlandırma").Select
    Range("H3:H" & Rows.Count).ClearContents
 
    For i = 3 To Cells(Rows.Count, "E").End(xlUp).Row
        With Ss.Range("E:E")
            Set c = .Find(Cells(i, "E"), , xlValues, xlWhole)
            If Not c Is Nothing Then
              Adr = c.Address
                Do
                    If Ss.Cells(c.Row, "A") = Range("H2") Then
                        Cells(i, "H") = Cells(i, "H") + Ss.Cells(c.Row, "K")
                    End If
                    Set c = .FindNext(c)
                Loop While Not c Is Nothing And c.Address <> Adr
            End If
        End With
    Next i
 
    Application.ScreenUpdating = True
 
 End Sub

.

 

[metin80]

nerde yanlışlık yaptım bilmiyorum ama çalıştıramadım

 

[metin80]

şimdi oldu
teşekkür ederim