Derece Kademe İlerlemesi

[kerim5555]

Merhaba;

Girdi Değerleri
A4...A8: İlk Göreve Başlama Zamanı
B4....B8: Yardımcı Sütundan(H sütunu) Alınan Değer
H Sütunu: Yardımcı Sütun

Beklenen Değer
I4....I8: Bugünün Tarihini Yazmasını bekliyorum.

J4...J8: İl Göreve Başlama Zamanı (A4...A8) ile bugünkü(I4....I8) tarih arasında (1) yıldan az fark var ise (B4....B8) değerinin aynısını yazmasını,
(1) Yıl veya (2) yıldan az fark var ise B4....B8: Yardımcı Sütundan(H sütunu) aldığı değerin (2) alt hücresindeki değeri yazmasını ,
(2) yıl fark var ise B4....B8: Yardımcı Sütundan(H sütunu) aldığı değerin (üç) alt hücresindeki değeri yazmasını
(3) yıl fark var ise B4....B8: Yardımcı Sütundan(H sütunu) aldığı değerin (dört alt hücresindeki değeri yazmasını (4,5,6,7,....yıl fark varsa diye devam etmesini ),
Bugünün tarihi(I4....I8 itibariyle kademe değeri H sütunundaki son değerden (H17) aşağıdaki değeri yazmak isterse bu değer olmadığından bu durumda (H17) değerini yani(7-3) değerini yazmasını bekliyorum.

K4...K8: İl Göreve Başlama Zamanı(A4...A8)na bakarak gelecekteki(bugünden sonraki) kademe ilerleyeceği tarihi yazmasını bekliyorum.

l4....l8: Burda da K4...K8 tarihine bakarak J4...J8 in değerinin yardımcı sütunundaki (bir) alt değeri yazmasını bekliyorum. (tabi Bugünün tarihi(I4....I8 itibariyle kademe değeri H sütunundaki son değerden (H17) aşağıdaki değeri yazmak isterse bu değer olmadığından bu durumda yine (H17) değerini yani(7-3) değerini yazmasını bekliyorum)

Örnek Dosya Ek'tedir. Yardımlarınızı bekliyorum.

 

[YUSUF44]

I4 hücresi için:

=BUGÜN()

Formülünü kullanıp aşağı doğru kopyalayın.

J4 hücresi için:

=EĞER(B4=$H$17;$H$17;EĞER(I4<TARİH(YIL(A4)+1;AY(A4);GÜN(A4));B4;EĞERHATA(İNDİS($H$4:$H$17;KAÇINCI(B4;$H$4:$H$17;0)+ETARİHLİ(A4;I4;"y"));$H$17)))

Formülünü kullanıp aşağı doğru kopyalayın.

K4 hücresi için :

=EĞER(AY(I4)>AY(A4);TARİH(YIL(I4)+1;AY(A4);GÜN(A4));EĞER(AY(I4)<AY(A4);TARİH(YIL(I4);AY(A4);GÜN(A4));EĞER(GÜN(I4)<GÜN(A4);TARİH(YIL(I4);AY(A4);GÜN(A4));TARİH(YIL(I4)+1;AY(A4);GÜN(A4)))))

Formülünü kullanıp aşağı doğru kopyalayın.

L4 hücresi için:

=EĞER(J4=$H$17;$H$17;EĞERHATA(İNDİS($H$4:$H$17;KAÇINCI(J4;$H$4:$H$17;0)+1);$H$17))

Formülünü kullanıp aşağı doğru kopyalayın.

 

[kerim5555]

Yusuf Bey Çok Teşekkür Ederim.
Yalnız yaptığınız formülde ilk yıl 2 kademe değil her yıl 1 kademe ilerliyor.
İlk Göreve Başlama tarihi(A) ile bugünün tarihi(I) arasında 1 yıl fark varsa Yardımcı Sütunda (2) alt değerini, sonraki yıllarda ise bir önceki kademenin 1 alt değerini J sütununa yazdırabilir miyiz? Yani 1.yılda 2 kademe ilerliyor ve diğer yıllarda ise her yıl 1 kademe ilerlemesini yapabilir misiniz? L sütunu da buna göre olabilir mi?

Yapamazsanız da canınız Sağ olsun. Bu şekilde de formülü kullanmaya çalışırım.
Tekrar Çok Teşekkür Ederim.

 

[YUSUF44]

J4 hücresinde aşağıdaki formülü deneyin:

=EĞER(B4=$H$17;$H$17;EĞER(I4<TARİH(YIL(A4)+1;AY(A4);GÜN(A4));B4;EĞERHATA(İNDİS($H$4:$H$17;KAÇINCI(B4;$H$4:$H$17;0)+ETARİHLİ(A4;I4;"y")+EĞER(YIL(I4)=YIL(A4)+1;1;0));$H$17)))

Yalnız bu nasıl bir terfi işlemi anlamadım

 

[kerim5555]

Yusuf Bey Çok Teşekkür Ederim. Uzm.Erb.lar ilk yıl sonunda 2 kademe veya 3 kademe gibi alabiliyor. Sizin yazdığımız formüle göre 2 veya 3 olarak değiştirip ben ayarlarım. Yukarıda gönderdiğiniz formülde EĞER(YIL(I4)=YIL(A4)+1 burada = yerine >= yapınca formül oldu. Tekrar Çok Teşekkür Ederim. Aklınıza Sağlık. İyi Çalışmalar...