Belli satırlara, belli rakamlar verip onları nasıl formüle çevirebiliriz

[ExacTKnoT]

İyi günler benim önemli bir sorum olcaktı , d1 hücresindeki verim rakam olarak 800 , I1 hücresindeki verim 6,10 , T1 hücresindeki verim de 6,10 ve bunların değerlerini d1 e 800 e 160 atıcaz , I1 6,10 a 30 atıcaz , T1 6,10 a 30 atıcaz ve bu atadığımız rakamların toplamını W1 hücresine otomatik atasın istiyorum bunun formülünü yapamadım yardımcı olur musunuz , teşekkür ediyorum saygılarımla ...

 

[muhasebeciyiz]

D1 hücresinde 800 varsa, ona 160 değerini atansın
I1 hücresinde 6,10 varsa, ona 30 değerini atansın
T1 hücresinde 6,10 varsa, ona yine 30 değerini atansın
Bu atanan değerlerin toplamı W1 hücresine otomatik olarak yazılsınmı demek istiyorsunuz

=EĞER(D1=800;160;0)+EĞER(I1=6,1;30;0)+EĞER(T1=6,1;30;0) bu formülü deneyiniz

 

[ExacTKnoT]

D1 hücresinde 800 varsa, ona 160 değerini atansın
I1 hücresinde 6,10 varsa, ona 30 değerini atansın
T1 hücresinde 6,10 varsa, ona yine 30 değerini atansın
Bu atanan değerlerin toplamı W1 hücresine otomatik olarak yazılsınmı demek istiyorsunuz

=EĞER(D1=800;160;0)+EĞER(I1=6,1;30;0)+EĞER(T1=6,1;30;0) bu formülü deneyiniz

Çok teşekkür ederim oldu , peki birşey daha sormak istiyorum bu seçenekleri çoğaltmak istersek aralarına ne koymalıyız mesela d1 sabit kalması sureti ile d1 e 800 olursa orda 160 900 olursa 150 1000 olursa 1400 dersek nasıl yapmalıyız , yani bir dosyada birsürü d1 hücresinde karışık 800 900 1000 rakamları olacak bizim formülün içerisinde onların arasına ne koymalıyız birde aynı şekilde I 1 VE T1 hücrelerinde de mesela 6,00 ile 6,10 arasına ben 30 6,10 - 6,20 olan hücrelerin arasına 20 koymak istiyorum o hücrenin içerisindeki 6,10 ila 6,20 arasında seçeneğinde 30 u otomatik koysun istiyorum birde onu nasıl yapmalıyız yardımcı olursanız çok sevinirim

 

[muhasebeciyiz]

Koşullunuz:
D1 = 800 → 160
D1 = 900 → 150
D1 = 1000 → 140

Formül : =EĞER(D1=800;160;EĞER(D1=900;150;EĞER(D1=1000;140;0)))
Bu formül D1 hücresindeki değere göre uygun sonucu verir. Eğer başka değerler varsa, 0 döner

I1 ve T1 Hücreleri İçin Aralık Kontrolü
6,00 ≤ hücre < 6,10 → 30
6,10 ≤ hücre ≤ 6,20 → 20

Formül I1 için =EĞER(VE(I1>=6;I1<6,1);30;EĞER(VE(I1>=6,1;I1<=6,2);20;0))
Aynı formülü T1 içinde kallanırsınız : =EĞER(VE(T1>=6;T1<6,1);30;EĞER(VE(T1>=6,1;T1<=6,2);20;0))

Tümünü birleştiren formülse

=EĞER(D1=800;160;EĞER(D1=900;150;EĞER(D1=1000;140;0))) +
EĞER(VE(I1>=6;I1<6,1);30;EĞER(VE(I1>=6,1;I1<=6,2);20;0)) +
EĞER(VE(T1>=6;T1<6,1);30;EĞER(VE(T1>=6,1;T1<=6,2);20;0))

 

[ExacTKnoT]

Koşullunuz:
D1 = 800 → 160
D1 = 900 → 150
D1 = 1000 → 140

Formül : =EĞER(D1=800;160;EĞER(D1=900;150;EĞER(D1=1000;140;0)))
Bu formül D1 hücresindeki değere göre uygun sonucu verir. Eğer başka değerler varsa, 0 döner

I1 ve T1 Hücreleri İçin Aralık Kontrolü
6,00 ≤ hücre < 6,10 → 30
6,10 ≤ hücre ≤ 6,20 → 20

Formül I1 için =EĞER(VE(I1>=6;I1<6,1);30;EĞER(VE(I1>=6,1;I1<=6,2);20;0))
Aynı formülü T1 içinde kallanırsınız : =EĞER(VE(T1>=6;T1<6,1);30;EĞER(VE(T1>=6,1;T1<=6,2);20;0))

Tümünü birleştiren formülse

=EĞER(D1=800;160;EĞER(D1=900;150;EĞER(D1=1000;140;0))) +
EĞER(VE(I1>=6;I1<6,1);30;EĞER(VE(I1>=6,1;I1<=6,2);20;0)) +
EĞER(VE(T1>=6;T1<6,1);30;EĞER(VE(T1>=6,1;T1<=6,2);20;0))

O kodların sonunda kapanan parantezler , kodun içerisindeki kaçtane yazacaksam ona göre çoğalıyor sanırım , teşekkür ederim deniyeceğim eğer yapamaz isem takılırsam gene sormak isterim çok teşekkür ediyorum emeklerinize sağlık .

 

[ExacTKnoT]

Koşullunuz:
D1 = 800 → 160
D1 = 900 → 150
D1 = 1000 → 140

Formül : =EĞER(D1=800;160;EĞER(D1=900;150;EĞER(D1=1000;140;0)))
Bu formül D1 hücresindeki değere göre uygun sonucu verir. Eğer başka değerler varsa, 0 döner

I1 ve T1 Hücreleri İçin Aralık Kontrolü
6,00 ≤ hücre < 6,10 → 30
6,10 ≤ hücre ≤ 6,20 → 20

Formül I1 için =EĞER(VE(I1>=6;I1<6,1);30;EĞER(VE(I1>=6,1;I1<=6,2);20;0))
Aynı formülü T1 içinde kallanırsınız : =EĞER(VE(T1>=6;T1<6,1);30;EĞER(VE(T1>=6,1;T1<=6,2);20;0))

Tümünü birleştiren formülse

=EĞER(D1=800;160;EĞER(D1=900;150;EĞER(D1=1000;140;0))) +
EĞER(VE(I1>=6;I1<6,1);30;EĞER(VE(I1>=6,1;I1<=6,2);20;0)) +
EĞER(VE(T1>=6;T1<6,1);30;EĞER(VE(T1>=6,1;T1<=6,2);20;0))

yaklaşık 30 a yakın değerler yazdım söylediğiniz şekilde fakat ( bu formül , geçerli dosya biçiminde kullanabilceğinizden daha fazla iç içe yerleştirme düzeyi kullanıyor . ) şeklinde hata verdi ve olmadı ne yapabilirim

 

[Muzaffer Ali]

Merhaba.
Alternatif olarak Ara formülü ile yapabilirsiniz.

Aşağıdaki formül D1 hücre değeri
800-899 arası ise 160
900-999 arası ise 150
1000 ve üzeri ise 140 döner.

Formülde dikkat edilmesi gereken şey aranan rakamların (800, 900 ve 1000) küçükten büyüğe göre yazılması gerekir.

=ARA(D1;{800;900;1000};{160;150;140})

3. mesajda aradığınız formül aşağıda

=ARA(D1;{800;900;1000};{160;150;140})+ARA(D1;{6,1;6,2};{30;20})

 

[muhasebeciyiz]

=EĞER(VE(D1>=800; D1<=899); 160; EĞER(VE(D1>=900; D1<=999); 150; EĞER(D1>=1000; 140; 0)))

D1 hücresindeki değer 800'den büyük veya eşit VE 899'dan küçük veya eşitse, sonuç 160 olur.
İlk koşul sağlanmazsa, D1 hücresindeki değer 900'den büyük veya eşit VE 999'dan küçük veya eşitse, sonuç 150 olur.
Önceki iki koşul da sağlanmazsa, D1 hücresindeki değer 1000'den büyük veya eşitse, sonuç 140 olur.
Bu koşulların hiçbiri sağlanmazsa, sonuç 0 olur.

 

[ExacTKnoT]

=EĞER(D1=800;160;EĞER(D1=900;150;EĞER(D1=1000;140;EĞER(D1=1100;135;EĞER(D1=1200;130;EĞER(D1=1300;120;EĞER(D1=1400;110;EĞER(D1=1500;100;EĞER(D1=1600;90;EĞER(D1=1700;80;EĞER(D1=1800;70;EĞER(D1=1900;60;EĞER(D1=2000;50;EĞER(D1=2100;40;EĞER(D1=2200;30;EĞER(D1=2400;20;EĞER(D1=2800;10;0)))))))))))))))))+EĞER(VE(I1>=5,60;I1<5,69);80;+EĞER(VE(I1>=5,70;I1<5,79);70;+EĞER(VE(I1>=5,80;I1<5,89);60;+EĞER(VE(I1>=5,90;I1<5,99);50;+EĞER(VE(I1>=6,0;I1<6,09);40;+EĞER(VE(I1>=6,1;I1<6,19);30;EĞER(VE(I1>=6,2;I1<=6,3);20;0))+EĞER(VE(T1>=5,60;I1<5,69);80;+EĞER(VE(T1>=5,70;I1<5,79);70;+EĞER(VE(T1>=5,80;I1<5,89);60;+EĞER(VE(T1>=5,90;I1<5,99);50;+EĞER(VE(T1>=6,0;I1<6,09);40;+EĞER(VE(T1>=6,1;T1<6,19);20;EĞER(VE(T1>=6,2;T1<=6,3);30;0))

Bu tarz bir kod oluşturdum fakat sonlara doğru yanlış yapmış olabilirim lütfen hatam varsa düzeltin birde , ( bu formül , geçerli dosya biçiminde kullanabilceğinizden daha fazla iç içe yerleştirme düzeyi kullanıyor . ) şeklinde hata verebilir bu kodu nasıl düzgün ve doğru bir şekilde yazabiliriz

 

[netzone]

Merhaba,
Yukarıda Muzaffer Bey'in belirttiği Ara ile yapacak olursanız son mesajınızdaki formülü şu şekilde yazabilirsiniz.

İyi çalışmalar.

=ARA(D1;{800;900;1000;1100;1200;1300;1400;1500;1600;1700;1800;1900;2000;2100;2200;2400;2800};{160;150;140;135;130;120;110;100;90;80;70;60;50;40;30;20;10})
+ARA(I1;{5,6;5,7;5,8;5,9;6;6,1;6,2};{80;70;60;50;40;30;20})
+ARA(T1;{5,6;5,7;5,8;5,9;6;6,1;6,2};{80;70;60;50;40;30;20})

 

[muhasebeciyiz]

Merhaba, verdiğiniz formülü inceledim. Görünen o ki, Excel'deki iç içe EĞER (IF) fonksiyonu sınırını aşmışsınız ve bu nedenle hatalı sonuçlar alıyorsunuz. Excel'in eski sürümlerinde bu tür bir sınırlama bulunuyordu. Ayrıca, formülünüzde bazı mantık hataları ve eksik parantezler de mevcut.



1 ve 2’deki tabloları oluşturmak hem formül karmaşasını azaltır hem de Excel’in iç içe EĞER sınırını aşmadan daha sağlıklı çalışmanı sağlar. Bu tabloları bir kez oluşturduktan sonra, formüllerin çok daha sade ve anlaşılır hale gelir.Tablo kullanırsan

Daha az hata riski: Uzun formüllerde parantez hatası çok olur.Kolay güncelleme: Yeni değer eklemek istediğinde sadece tabloya satır eklersin.
Daha okunabilir: Hem sen hem başkaları neyin neye karşılık geldiğini kolayca görür.

=EĞERHATA(DÜŞEYARA(D1;A1:B17;2;YANLIŞ);0) + ARA(I1;C1:C8;D1:D8) + ARA(T1;C1:C8;D1:D8)

Bu şekilde hem Excel’in sınırlarına takılmazsın hem de formülün çok daha esnek olur.

veya bu formülünüz karışık olsada çalışacaktır

=EĞER(D1=800;160;EĞER(D1=900;150;EĞER(D1=1000;140;EĞER(D1=1100;135;EĞER(D1=1200;130;EĞER(D1=1300;120;EĞER(D1=1400;110;EĞER(D1=1500;100;EĞER(D1=1600;90;EĞER(D1=1700;80;EĞER(D1=1800;70;EĞER(D1=1900;60;EĞER(D1=2000;50;EĞER(D1=2100;40;EĞER(D1=2200;30;EĞER(D1=2400;20;EĞER(D1=2800;10;0))))))))))))))))+EĞER(VE(I1>=5,6;I1<5,69);80;EĞER(VE(I1>=5,7;I1<5,79);70;EĞER(VE(I1>=5,8;I1<5,89);60;EĞER(VE(I1>=5,9;I1<5,99);50;EĞER(VE(I1>=6;I1<6,09);40;EĞER(VE(I1>=6,1;I1<6,19);30;EĞER(VE(I1>=6,2;I1<=6,3);20;0)))))))+EĞER(VE(T1>=5,6;T1<5,69);80;EĞER(VE(T1>=5,7;T1<5,79);70;EĞER(VE(T1>=5,8;T1<5,89);60;EĞER(VE(T1>=5,9;T1<5,99);50;EĞER(VE(T1>=6;T1<6,09);40;EĞER(VE(T1>=6,1;T1<6,19);20;EĞER(VE(T1>=6,2;T1<=6,3);30;0))))))))

 

[alicimri]

Deneyin
Deneyin

=ELEMAN((D1-800)/100+1;160;150;140;135;130;120;110;100;90;80;70;60;50;40;30;0;20;0;0;0;10)+(80-((T1*10-50)-6)*10)+(80-((I1*10-50)-6)*10)