En büyük değeri kaç kez almış

[Muhammet Okumuş]

Arkadaşlar merhaba.
Öncelikle sitede ve nette arama yaptım. Buna benzer soru sormuş gibiyim. Ama açtığım konularda da bulamadım.
Dosyada tablo var. Tablodaki değerlere bakarak bir kişinin kaç kez maksimum değeri aldığını bulmak istiyorum. İkinci olarak da bu maksimum değeri kaç kez sadece o almış.
Örneğin 1. Sınavda bir tek ben 100 aldım.
2. Sınavda ben ve bir başkası veya başkaları 100 aldı.

Bu durumda 1. sorunun cevabı 2, 2. sorunun cevabı 1 olmalı.

* Yardımcı sütun kullanılmayacak.

 

[mersilen]

Merhaba
Aşağıdaki formülleri dener misiniz?
Yalnız yardımcı sütununuzuda kullandım.(AF6:AF20)


=TOPLA.ÇARPIM(--((B6:B20)=($AE$6:$AE$20)))

=TOPLA.ÇARPIM(((B6:B20)=(B6:B20))*(AF6:AF20=1)*(--((B6:B20)=MAK(B6:B20))))

 

[Muhammet Okumuş]

Hocam cevabınız için teşekkür ederim. Ama ben yardımcı sütun kullanmak istemiyorum.

 

[Mahir64]

Merhaba,



Düzeltme : Soruyu yanlış yorumlamışım.

 

[Muhammet Okumuş]

Mahir Bey, cevabınız için teşekkür ederim. İstediğim sonuç bu değil.

 

[Erdem Akdemir]

Muhammet bey merhaba,

Sorunuzu daha küçük bir örnekle tekrar açıklayabilir misiniz? Yada manuel olarak birkaç sonuç daha yazın. Yapılabilir birşey ama tam olarak anlamadım.

 

[Muhammet Okumuş]

Dosyada B3 ve B4 hücrelerinin yanında anlatmaya çalıştım.

 

[bzace]

Merhabalar,
1. sorunuzu anladığım kadarıyla deneyiniz.

• A1:A4 Aralığına isimler,
• B1:B4 Aralığına sayılar,
• Aranacak isim Jilly,

olacak şekilde düzenleyiniz.

=MAK(EĞERSAY(B1:B4;B1:B4)*(A1:A4="Jilly"))
[COLOR="Blue"]Formül dizi formülüdür.CTRL + SHIFT +ENTER ile tamamlayınız.[/COLOR]

2. sorunuzu anlayamadım.

 

[Muhammet Okumuş]

Satırda maksimum değeri bulması gerekiyor.

Bir sınıfta 30 öğrenci var ve 20 sınav yapıldı.

1. Soru: Ben bu 20 sınavdan kaç tanesinde en yüksek notu aldım.
2. Soru: Ben bu 20 sınavdan kaç tanesinde sadece en yüksek notu ben aldım.

 

[Erdem Akdemir]

Muhammet bey merhaba,

Formülün daha rahat anlaşılması için bazı değişkenleri elimle manuel belirledim. Dinamik haline getirmek isterseniz yine yardımcı olabilirim.

B3 hücresine

=TOPLA.ÇARPIM(--(B6:B20>=ALTTOPLAM(4;KAYDIR(C6;SATIR(1:15)-1;;;27))))

B4 hücresine,

=TOPLA.ÇARPIM(--(B6:B20>ALTTOPLAM(4;KAYDIR(C6;SATIR(1:15)-1;;;27))))

 

[Muhammet Okumuş]

Sn kuvari,
Cevabınız için teşekkür ederim. Veri sayısı belli olduğu için bu formüller yeterli. Eğer zor değilse dinamik alan formülünü paylaşabilirsiniz.

 

[Erdem Akdemir]

Merhaba,

Dinamik alan olarak aşağıdaki formülü kullanabilirsiniz.

=TOPLA.ÇARPIM(--(B6:B20>=ALTTOPLAM(4;KAYDIR(C6;SATIR(DOLAYLI("1:"&BAĞ_DEĞ_SAY(B6:B20)))-1;;;BAĞ_DEĞ_SAY(C6:AC6)))))

=TOPLA.ÇARPIM(--(B6:B20>ALTTOPLAM(4;KAYDIR(C6;SATIR(DOLAYLI("1:"&BAĞ_DEĞ_SAY(B6:B20)))-1;;;BAĞ_DEĞ_SAY(C6:AC6)))))

 

[Muhammet Okumuş]

Çok teşekkür ederim Sn. kuvari.

 

[Ömer BARAN]

Merhaba,

Dinamik alan olarak aşağıdaki formülü kullanabilirsiniz.

=TOPLA.ÇARPIM(--(B6:B20>=ALTTOPLAM(4;KAYDIR(C6;SATIR(DOLAYLI("1:"&BAĞ_DEĞ_SAY(B6:B20)))-1;;;BAĞ_DEĞ_SAY(C6:AC6)))))

=TOPLA.ÇARPIM(--(B6:B20>ALTTOPLAM(4;KAYDIR(C6;SATIR(DOLAYLI("1:"&BAĞ_DEĞ_SAY(B6:B20)))-1;;;BAĞ_DEĞ_SAY(C6:AC6)))))

Tebrik ediyorum Sayın kuvari, güzel formül olmuş.

 

[Erdem Akdemir]

Tebrik ediyorum Sayın kuvari, güzel formül olmuş.

Teşekkür ederim ömer bey, sağolun.

 

[Muhammet Okumuş]

Formül maksimum değeri bir kez alanlar için yanlış hesaplama yapıyor. Acaba $ işaretleri yanlış yere mı koydum veya konulması gereken yerlere konmadı mı?

Kırmızı hücreler maksimum değerin sadece bir kişi, sarı renkli hücreler maksimum değerin bir den fazla alındığını ifade ediyor.

 

[Erdem Akdemir]

Formül maksimum değeri bir kez alanlar için yanlış hesaplama yapıyor. Acaba $ işaretleri yanlış yere mı koydum veya konulması gereken yerlere konmadı mı?

Kırmızı hücreler maksimum değerin sadece bir kişi, sarı renkli hücreler maksimum değerin bir den fazla alındığını ifade ediyor.

Muhammet bey bilgisayarım işyerinde kaldı, yarın sabah bakabilirim.Formül en soldan bakarak sağdaki degerlere göre çalışıyordu.Bütün sutunlara uygulayacaksanız,tekrar düzenlemek gerekir.

 

[Erdem Akdemir]

Merhaba,

B3 hücresine,

=TOPLA.ÇARPIM(--(B6:B20>=ALTTOPLAM(4;KAYDIR($B$6;SATIR(DOLAYLI("1:"&BAĞ_DEĞ_SAY(B6:B20)))-1;;;BAĞ_DEĞ_SAY($B$6:$AC$6)))))

B4 hücresine, dizi formülüdür.

=TOPLA.ÇARPIM(--(EĞER(--(B6:B20=ALTTOPLAM(4;KAYDIR($B$6;SATIR(DOLAYLI("1:"&BAĞ_DEĞ_SAY(B6:B20)))-1;;;BAĞ_DEĞ_SAY($B$6:$AC$6))))=1;EĞER(EĞERSAY(KAYDIR($B$6;SATIR(DOLAYLI("1:"&BAĞ_DEĞ_SAY(B6:B20)))-1;;;BAĞ_DEĞ_SAY($B$6:$AC$6));B6:B20)>1;0;1))))

 

[Muhammet Okumuş]

Çok teşekkür ederim Sn. kuvari.
Sorun çözüldü, formül şimdi doğru hesaplıyor.

 

[Erdem Akdemir]

Çok teşekkür ederim Sn. kuvari.
Sorun çözüldü, formül şimdi doğru hesaplıyor.

Ben teşekkür ederim,iyi çalışmalar.