Yıllık İzin Süreleri

[iplikci_80]

31.07.2020 tarihi itibarıyla hak edilen yıllık izin süresi 60 Gün olması gerekirken çalışmadaki koddaki hatadan dolayı yukarıdaki örnekte 54 Gün çıkıyor. Bu hatanın giderilmesi hususunda yardımlarınızı rica ediyorum.

 

[Ömer]

Merhaba,

Kodlarınızı detaylı inceledim. Kendi kullandıklarımı paylaşayım.

=TOPLAM_IZIN(giriş tarihi ; doğum tarihi ; bakılacak tarih)

Function TOPLAM_IZIN(GTarih As Range, DTarih As Range, STarih As Range)

    Dim tarih As Date, IzinTop As Double, Yas As Double, Hizmet As Double, izin As Double

    Application.Volatile True

    tarih = DateAdd("yyyy", 1, CDate(GTarih))
    IzinTop = 0
  
    Do While tarih < STarih
        Yas = Evaluate("DateDif(" & CDbl(CDate(DTarih)) _
            & "," & CDbl(CDate(tarih)) & ", ""Y"")")
      
        Hizmet = Evaluate("DateDif(" & CDbl(CDate(GTarih)) _
                & "," & CDbl(CDate(tarih)) & ", ""Y"")")
      
        If Yas < 18 Or Yas > 49 Then
            If Hizmet > 14 Then
                izin = 26
            Else
                izin = 20
            End If
        Else
            If Hizmet > 14 Then
                izin = 26
            ElseIf Hizmet > 5 Then
                izin = 20
            Else
                izin = 14
            End If
        End If
      
        IzinTop = IzinTop + izin
        tarih = DateAdd("yyyy", 1, tarih)
     Loop
  
    TOPLAM_IZIN = IzinTop

End Function