YATAYYIĞ FORMÜLÜ HK

[emre8456]

Arkadaşlar merhaba
Aşağıda yazdığın formülde H sütunundaki firmaları benzersiz yazsın ve karşısınada b sütündaki en son alım yaptığı tarihi getirsin. Ama formül yok hatası veriyor. Aşağıdaki formülü nasıl revize etmem gerek ?
YATAYYIĞ(BENZERSİZ(İRSALİYELER!$H$2:$H$100000);
ARA(2;1/((İRSALİYELER!$H$2:$H$100000)=(BENZERSİZ(İRSALİYELER!$H$2:$H$100000)));İRSALİYELER!$B$2:$B$100000))

 

[rasimeskil]

=YATAYYIĞ(BENZERSİZ(İRSALİYELER!$H$2:$H$100000), EĞERHATA(KAYDIR(İRSALİYELER!$B$2:$B$100000,KAÇINCI(2;1/((İRSALİYELER!$H$2:$H$100000)=BENZERSİZ(İRSALİYELER!$H$2:$H$100000));0)-1;0);""))

 

[emre8456]

=YATAYYIĞ(BENZERSİZ(İRSALİYELER!$H$2:$H$100000), EĞERHATA(KAYDIR(İRSALİYELER!$B$2:$B$100000,KAÇINCI(2;1/((İRSALİYELER!$H$2:$H$100000)=BENZERSİZ(İRSALİYELER!$H$2:$H$100000));0)-1;0);""))

Sayın rasimeskil merhaba
maalesef ilk satırın karşılığı boş diğer satırların karşılığı yok olarak geldi

 

[Korhan Ayhan]

Böyle deneyiniz.

=LET(Firmalar;BENZERSİZ(KIRPARALIĞI(H2:H100000));
     Tarihler;BYROW(Firmalar;LAMBDA(Firma;ÇOKEĞERMAK(B2:B100000;H2:H100000;Firma)));
     YATAYYIĞ(Firmalar;Tarihler))

 

[emre8456]

Böyle deneyiniz.

=LET(Firmalar;BENZERSİZ(KIRPARALIĞI(H2:H100000));
     Tarihler;BYROW(Firmalar;LAMBDA(Firma;ÇOKEĞERMAK(B2:B100000;H2:H100000;Firma)));
     YATAYYIĞ(Firmalar;Tarihler))

Korhan Bey Merhaba
#AD? hatası verdi.
KIRPARALIĞI da sorun var görünüyor. Benim sürümde bu formül yok gibi

 

[Korhan Ayhan]

Sizde olmayan fonksiyonlar olabilir.

Önerdiğim formüldeki fonksiyonları kendi versiyonunuzda kontrol edermisiniz. Hangisi yoksa ona göre alternatif öneride bulunalım.

 

[emre8456]

Sizde olmayan fonksiyonlar olabilir.

Önerdiğim formüldeki fonksiyonları kendi versiyonunuzda kontrol edermisiniz. Hangisi yoksa ona göre alternatif öneride bulunalım.

KIRPARALIĞI nda sorun var görünüyor. Benim sürümde bu formül yok

 

[ccuneyt13]

Korhan Hocam Gruplaölçüt formülü olmadığı için yeni güncelledim ben 365 türkçeyi, bu formül geldi mesela bana ama
Sizin yazdığınız KIRPARALIĞI sanırım türkçesinde KIRPMAARALIĞI formülü olarak gelmiş lakin oda yok bende, muhtemelen Emre bey de de bu formül hata veriyor.

 

[Korhan Ayhan]

Evet bazıları Insider sürümüyle gelen fonksiyonlar.. Bu sebeple sizlerde olmayabilir.

Fakat ben excelimi Türkçe'ye çevirip hücrede Türkçe olarak ne görünüyorsa onu forumda paylaştım.

Birazdan güncel formülü paylaşırım.

 

[Korhan Ayhan]

KIRPMAARALIĞI fonksiyonu ile ilgili bendeki durum görseldeki gibi...

Önerdiğim çözümü aşağıdaki gibi değiştirip deneyiniz.

=LET(Firmalar;BENZERSİZ(FİLTRE(H2:H100000;H2:H100000<>""));
     Tarihler;BYROW(Firmalar;LAMBDA(Firma;ÇOKEĞERMAK(B2:B100000;H2:H100000;Firma)));
     YATAYYIĞ(Firmalar;Tarihler))

 

[emre8456]

KIRPMAARALIĞI fonksiyonu ile ilgili bendeki durum görseldeki gibi...

Önerdiğim çözümü aşağıdaki gibi değiştirip deneyiniz.

=LET(Firmalar;BENZERSİZ(FİLTRE(H2:H100000;H2:H100000<>""));
     Tarihler;BYROW(Firmalar;LAMBDA(Firma;ÇOKEĞERMAK(B2:B100000;H2:H100000;Firma)));
     YATAYYIĞ(Firmalar;Tarihler))

Ekli dosyayı görüntüle 255302

Korhan bey teşekkür ederim formül çalıştı.
3 gün öncesi olanları getirtmesi için formülü nasıl yazmamız gerek.

 

[Korhan Ayhan]

Neye göre 3 gün?

 

[emre8456]

Neye göre 3 gün?

bugünden itibaren en son üç gün ve öncesi olanlar gelsin.

 

[Korhan Ayhan]

Ulaşmak istediğiniz sonuçları gösteren bir örnek paylaşabilirmisiniz.

 

[emre8456]

Ulaşmak istediğiniz sonuçları gösteren bir örnek paylaşabilirmisiniz.

örnek dosya ekte

 

[Korhan Ayhan]

Öncelikle G2:H7 aralığını temizleyiniz.

Aşağıdaki formülü G2 hücresine uygulayıp deneyiniz.

=LET(Firmalar;BENZERSİZ(FİLTRE(C2:C100000;(C2:C100000<>"")*(A2:A100000<BUGÜN()-3)));
     Tarihler;BYROW(Firmalar;LAMBDA(Firma;ÇOKEĞERMAK(A2:A100000;C2:C100000;Firma)));
     DÜŞEYYIĞ({"ALICI"\"TARİH"};YATAYYIĞ(Firmalar;Tarihler)))

 

[Korhan Ayhan]

Eğer sizde aşağıdaki fonksiyon varsa daha kısa çözümü deneyebilirsiniz..

Boş bir hücreye uygulayınız. Tüm sonuçlar bir önceki önerim gibi dökülmeli listelenecektir. Formül bu haliyle kaynak tablodaki başlıkları gösterir.

=GRUPLAÖLÇÜT(C1:C100000;A1:A100000;MAK;3;0;;(A1:A100000<BUGÜN()-3)*(A1:A100000<>"")

Eğer başlıkları kişiselleştirmek isterseniz aşağıdaki gibi kullanabilirsiniz.

=DÜŞEYYIĞ({"ALICI";"TARİH"};GRUPLAÖLÇÜT(C1:C100000;A1:A100000;MAK;0;0;;(A1:A100000<BUGÜN()-3)*(A1:A100000<>"")))

 

[emre8456]

Öncelikle G2:H7 aralığını temizleyiniz.

Aşağıdaki formülü G2 hücresine uygulayıp deneyiniz.

=LET(Firmalar;BENZERSİZ(FİLTRE(C2:C100000;(C2:C100000<>"")*(A2:A100000<BUGÜN()-3)));
     Tarihler;BYROW(Firmalar;LAMBDA(Firma;ÇOKEĞERMAK(A2:A100000;C2:C100000;Firma)));
     DÜŞEYYIĞ({"ALICI"\"TARİH"};YATAYYIĞ(Firmalar;Tarihler)))

Korhan bey Teşekkürler.
Formülü uyguladığım zaman tarihler düzgün geliyor. Ancak sütun başlıklarında sorun var. Karşılığı yok hatası veriyor.
Tarihlerin yanındaki sütuna da en son mal alımı yaptıkları tarihe kadar toplam mal alımını getirtebilir miyiz?

 

[emre8456]

Eğer sizde aşağıdaki fonksiyon varsa daha kısa çözümü deneyebilirsiniz..

Boş bir hücreye uygulayınız. Tüm sonuçlar bir önceki önerim gibi dökülmeli listelenecektir. Formül bu haliyle kaynak tablodaki başlıkları gösterir.

=GRUPLAÖLÇÜT(C1:C100000;A1:A100000;MAK;3;0;;(A1:A100000<BUGÜN()-3)*(A1:A100000<>"")

Eğer başlıkları kişiselleştirmek isterseniz aşağıdaki gibi kullanabilirsiniz.

=DÜŞEYYIĞ({"ALICI";"TARİH"};GRUPLAÖLÇÜT(C1:C100000;A1:A100000;MAK;0;0;;(A1:A100000<BUGÜN()-3)*(A1:A100000<>"")))

Kullandığım sürümde GRUPLAÖLÇÜT formülü yok maalesef

 

[Korhan Ayhan]

Bende başlıklarda düzgün geliyor.. Belki dil/ayıraç farkı sorunu olmuştur. Aşağıdaki gibi deneyebilirsiniz.

=LET(Firmalar;BENZERSİZ(FİLTRE(C2:C100000;(C2:C100000<>"")*(A2:A100000<BUGÜN()-3)));
     Tarihler;BYROW(Firmalar;LAMBDA(Firma;ÇOKEĞERMAK(A2:A100000;C2:C100000;Firma)));
     DÜŞEYYIĞ({"ALICI";"TARİH"};YATAYYIĞ(Firmalar;Tarihler)))

Miktarlar için birazdan güncel formülü paylaşırım..