Verileri maile kopyalayıp göndermek

[hashim]

Merhaba,

Ekteki dosya bu forumda daha önceki bir soruya cevap olarak verilmiş.
Bu örnekte kendini maile ek olarak ekleyip gönderen bir uygulama mevcut. Benim ihtiyacım ise çalışma sayfasındaki seçili alanı yeni bir maile kopyalayıp gönderen bir versiyon.

Ayrıca Outlook 2007 her mail gönderme teşebbüsünde uyarı veriyor. Bu uyarıyı geçme şansım var mıdır?

Yardımlarınız için şimdiden teşekkürler.

 

[ersoyalan]

Merhaba,

Ekli dosya işinizi görecektir.


E.ALAN

 

[hashim]

İşe yarıyor. Çok teşekkür ederim.

 

[rabbace]

Merhaba,

Ekli dosya işinizi görecektir.


E.ALAN

Merhaba,

Bu dosya ile sadece B15:B20 satırları arasını seçip mail atıyor. Benim istediğim sayfada hangi alanı seçersem orayı mail atsın. Bu mümkün müdür?

Mesela A20:F30'u seçtim bugün ben ama yarin yine aynı kodla A25:F35'i seçip mail attırmak istedim. Mümkün müdür? Dinamik alan seçmesini istiyorum yani

 

[tirEdsOuL]

Merhaba,

Bu dosya ile sadece B15:B20 satırları arasını seçip mail atıyor. Benim istediğim sayfada hangi alanı seçersem orayı mail atsın. Bu mümkün müdür?

Mesela A20:F30'u seçtim bugün ben ama yarin yine aynı kodla A25:F35'i seçip mail attırmak istedim. Mümkün müdür? Dinamik alan seçmesini istiyorum yani

banada böyle birşey lazımdı ve yabancı bir kaynaktan aşağıdaki kodu bulmuştum, işinize yarayacaktır.

Sub Secili_Hucreleri_Gonder()
'For Tips see: http://www.rondebruin.nl/win/winmail/Outlook/tips.htm
'Don't forget to copy the function RangetoHTML in the module.
'Working in Excel 2000-2016
    Dim rng As Range
    Dim OutApp As Object
    Dim OutMail As Object


    Set rng = Nothing
    On Error Resume Next
    'Seçili alanı göndermek için aşağıdaki kodu aktif edin..
    Set rng = Selection.SpecialCells(xlCellTypeVisible)
    'Belirli bir alanı göndermek için aşağıdaki kodu aktif edin..
    'Set rng = Sheets("Sayfadı").Range("A1:AQ30").SpecialCells(xlCellTypeVisible)
    On Error GoTo 0

    If rng Is Nothing Then
        MsgBox "Aralık seçilmemiş yada sayfa korumalıdır." & _
               vbNewLine & "Lütfen düzeltip tekrar deneyin.", vbOKOnly
        Exit Sub
    End If

    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)
    Set fso = CreateObject("Scripting.FileSystemObject")
    yol = "C:\Users\ebulut\AppData\Roaming\Microsoft\Signatures\İmza.htm"
    Set imza = fso.OpenTextFile(yol, 1)

    On Error Resume Next
    With OutMail
        .to = "mail adresi"
        .CC = ""
        .BCC = ""
        .Subject = Format(Date, "DD.MM.YYYY") & " - Satış Raporu.."
        .HTMLBody = RangetoHTML(rng) & "<BR><BR>" & imza.readall
        .Display   'ya da .Send komutunu kullanabilirsiniz..
    End With
    On Error GoTo 0

    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With

    Set OutMail = Nothing
    Set OutApp = Nothing
End Sub

Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2016
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With

    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With

    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.readall
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")

    'Close TempWB
    TempWB.Close savechanges:=False

    'Delete the htm file we used in this function
    Kill TempFile

    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function

 

[rabbace]

Hocam çok teşekkürler işime yarayacak bu

 

[rabbace]

Hocam seçili hücreleri almıyor bu, Outlook ekranı boş çıkıyor. Sadece mail adresi ve Konu içeriği geliyor.

 

[tirEdsOuL]

kodu modüle uyguladınız değil mi ? sayfanızda koruma yoksa çalışması gerekiyor, şimdi denedim bir sıkıntı çıkmadı..

 

[rabbace]

Kodları uyguladığım dosya ekte hocam, tekrar denedim sonuç vermedi.

 

[tirEdsOuL]

imza yolunu sildiğiniz için aşağıda kırmızı ile belirttiğim alanıda silmeniz gerekmektedir.

.HTMLBody = RangetoHTML(rng) [COLOR="Red"]& "<BR><BR>" & imza.readall[/COLOR]