Veri Sildirme Hk.

[metin_0606]

Değerli üstatlar çalışmamda textbox1 e girilen değer eğer SAYILAR sayfasının A sütununda varsa Girilen değer doğrudur mesajı verip bu sayıyı SAYILAR sayfasının A sütunundan silip userformu kapatsın eğer textboxa girielen değer SAYILAR sayfasının A sütununda yoksa değer bulunamadı deyip userformu kapatsın. Yardımlarınız için şimdiden teşekkürler NOT: SAYILAR sayfası gizli olacak

 

[Ömer]

Merhaba

Deneyiniz.

Private Sub CommandButton1_Click()

    Dim Ss As Worksheet, c As Range, Adr As String, k As Range

    Set Ss = Sheets("SAYILAR")

    Set c = Ss.[A:A].Find(TextBox1, , xlValues, xlWhole)
    If Not c Is Nothing Then
        Adr = c.Address
        Do
            If k Is Nothing Then
                Set k = Ss.Rows(c.Row)
            Else
                Set k = Application.Union(k, Ss.Rows(c.Row))
            End If

            Set c = Ss.[A:A].FindNext(c)
        Loop While Not c Is Nothing And c.Address <> Adr
    End If
    
    If k Is Nothing Then
        MsgBox "Bulunamadı"
    Else
        k.Delete
        MsgBox "Doğru değer. Silme Tamamladı."
    End If
    
    Unload UserForm1

End Sub

 

[metin_0606]

Merhaba

Deneyiniz.

Private Sub CommandButton1_Click()

    Dim Ss As Worksheet, c As Range, Adr As String, k As Range

    Set Ss = Sheets("SAYILAR")

    Set c = Ss.[A:A].Find(TextBox1, , xlValues, xlWhole)
    If Not c Is Nothing Then
        Adr = c.Address
        Do
            If k Is Nothing Then
                Set k = Ss.Rows(c.Row)
            Else
                Set k = Application.Union(k, Ss.Rows(c.Row))
            End If

            Set c = Ss.[A:A].FindNext(c)
        Loop While Not c Is Nothing And c.Address <> Adr
    End If
   
    If k Is Nothing Then
        MsgBox "Bulunamadı"
    Else
        k.Delete
        MsgBox "Doğru değer. Silme Tamamladı."
    End If
   
    Unload UserForm1

End Sub

Teşekkürler Ömer hocam zihnine sağlık