Veri doğrulama ile seç hepsini getir (vba kod ile)

[netvolxxx]

merhaba arkadaşlar çalışma sayfamda veri doğrulama ile müşteri adını seçtiğimde diğer saydafa o müşteriye ait bilgilerin hepsini getirmek istiyorum bu işlemi office 365 de yapabiliyorum ama bunu vba kod ile nasıl yapıcam bulunduğum ortamda office eski sürüm yardımcı olcak arkadaşlar şimdiden allah razı olsun.....
işlemi veri doğrulama yerine combobox ile seçip getirebilirsek oda olur...

dosyayı excel çalışma sayfasını ekledim...

 

[netvolxxx]

merhaba yokmu bir üstad sayfa1 de seçtiğim karşılığı olan sayfa2 deki verileri getircek...

 

[muygun]

Merhaba;
Eki deneyin.
İyi çalışmalar.

 

[veyselemre]

Dim adoCon As Object, rs As Object, strSQL$
Sub connect()
    If adoCon.State = 0 Then
        adoCon.Open "Provider=Microsoft.Ace.Oledb.12.0;Extended Properties='Excel 12.0;HDR=Yes';" & _
                    "Data Source=" & ThisWorkbook.FullName
    End If
End Sub
Private Sub ComboBox1_Change()
    If ComboBox1.Text <> "" Then
        strSQL = "SELECT * FROM [Taslakdatabase$A2:L] WHERE [MÜŞTERİ ADI SOYADI]='" & ComboBox1.Text & "'"
        If adoCon Is Nothing Then
            Set adoCon = CreateObject("ADODB.Connection")
            Set rs = CreateObject("ADODB.Recordset")
        End If
        If adoCon.State = 0 Then Call connect
        Set rs = adoCon.Execute(strSQL)
        Range("A4:L" & Rows.Count).Clear
        Range("A4").CopyFromRecordset rs
        rs.Close
        Sheets("Taslakdatabase").Range("A3:L4").Copy
        Range("A4:L" & Cells(Rows.Count, 1).End(3).Row).PasteSpecial xlPasteFormats
        Application.CutCopyMode = False
    End If
End Sub
Private Sub Worksheet_Activate()
    strSQL = "SELECT DISTINCT [MÜŞTERİ ADI SOYADI] FROM [Taslakdatabase$A2:L] WHERE [MÜŞTERİ ADI SOYADI] IS NOT NULL ORDER BY [MÜŞTERİ ADI SOYADI]"
    If adoCon Is Nothing Then
        Set adoCon = CreateObject("ADODB.Connection")
        Set rs = CreateObject("ADODB.Recordset")
    End If
    If adoCon.State = 0 Then Call connect
    Set rs = adoCon.Execute(strSQL)
    ComboBox1.Column = rs.getrows
    rs.Close
End Sub

 

[netvolxxx]

Merhaba;
Eki deneyin.
İyi çalışmalar.

teşekürr ederim işimi gördü sağolun

 

[netvolxxx]

eyvallah veysel hocam işimi gördü teşekürr ederim....