Veri aktarımı

[kesikbey]

Arkadaşlar 3 ayrı excel sayfasından istenen kritere uyan değerleri bir sayfaya toplamak istiyorum. Mümkün se
şimdiden teşekkürler

 

[Ömer]

Merhaba,

Bu şekilde deneyin;

Private Sub CommandButton1_Click()
    Dim dizi(), i As Byte, syf As Worksheet, c As Range, Adr As Variant, son As Long
    Application.ScreenUpdating = False
    
    Sheets("rapor").Select
    Range("B2:W" & Rows.Count).ClearContents
    
    If isimBox.Value = "" Then Exit Sub
    
    dizi = Array("YENİ", "TAHAKKUK", "mizan")
    
    For i = 0 To UBound(dizi)
        Set syf = Sheets(dizi(i))
        With syf.Range("D:D")
            Set c = .Find(isimBox.Value, , xlValues, xlWhole)
            If Not c Is Nothing Then
                Adr = c.Address
                Do
                    son = Cells(Rows.Count, "D").End(xlUp).Row + 1
                    syf.Range("B" & c.Row & ":W" & c.Row).Copy Range("B" & son)
                    Set c = .FindNext(c)
                Loop While Not c Is Nothing And c.Address <> Adr
            End If
        End With
    Next i
    Application.ScreenUpdating = True
    
    Unload Me
End Sub

.

 

[kesikbey]

ömer bey çok teşekkür ederim bu işimi gördü... selamlar