VBA'da kodlama sorunu

[Tornael]

Selam arkadaşlar,

Ekteki dosyada yapmak istediğim "Ozet" sayfasında "A" kolonunun son dolu hücresine kadar "B" kolonunda düşeyara fonksiyonu uygulaması.
Son dolu hücreyi özellikle belirtmek isterim, çünkü verilerin adeti sürekli değişiyor.

Yapmak istediğim düşey ara fonksiyonunu VBA ile denedim beceremedim, kod aşağıdaki gibidir;

"B" kolonuna "A" kolonundaki son dolu hücreye kadar =DÜŞEYARA(A2;MRC!A:B;2;0)

Şimdiden teşekkür ederim.

 

[Necdet]

Merhaba,

Aşağıdaki kodları dener misiniz?

Sub Karsilastir()
    
    Dim i   As Long, _
        Adt As Long, _
        c   As Range, _
        Sho As Worksheet, _
        Shm As Worksheet
    
    Set Sho = Sheets("Ozet")
    Set Shm = Sheets("MRC")
    
    Sho.Select
    
    Application.ScreenUpdating = False
    Range("B2:B" & Rows.Count).ClearContents
    
    For i = 2 To Cells(Rows.Count, "A").End(3).Row
        Set c = Shm.Range("A:A").Find(Cells(i, "A"), LookIn:=xlValues, LookAt:=xlWhole)
        If Not c Is Nothing Then
            Cells(i, "B") = Shm.Cells(c.Row, "B")
            Adt = Adt + 1
        End If
    Next i
    
    If Adt = 0 Then
        MsgBox "HİÇ TUTAN YOK"
    Else
        MsgBox Adt & " ADET EŞLEŞEN KAYIT BULDUM"
    End If
    
    Application.ScreenUpdating = True
    
End Sub

 

[Tornael]

Tebrikler

Teşekkürler Necdet Bey,

Tam istediğim gibi elinize sağlık.