VBA Kodu Yardım: Optik Forma İsim Yazdırma

[BedriA]

Arkadaşlar,

Örnek dosyada iki sayfam var.
Listedeki öğrenci bilgilerini sırayla Optik Forma gönderip formu, PDF ismi öğrencinin numarası olacak şekilde, A5 boyutunda, PDF olarak basmak istiyorum.

Bu işlem hiç durmadan listedeki son öğrenciye kadar devam edecek.
Formlar programın klasörü içinde, yine kod ile açılacak ve sınıfın ismini alacak bir klasöre kaydolacak.

Yardımcı olacak arkadaşlara şimdiden teşekkürler.

 

[Asri]

Arkadaşlar,

Örnek dosyada iki sayfam var.
Listedeki öğrenci bilgilerini sırayla Optik Forma gönderip formu, PDF ismi öğrencinin numarası olacak şekilde, A5 boyutunda, PDF olarak basmak istiyorum.

Bu işlem hiç durmadan listedeki son öğrenciye kadar devam edecek.
Formlar programın klasörü içinde, yine kod ile açılacak ve sınıfın ismini alacak bir klasöre kaydolacak.

Yardımcı olacak arkadaşlara şimdiden teşekkürler.

Aşağıdaki şekilde deneyiniz.
Sayfanın yazıcı ayarlarından A5 yatay yada dikey seçip ayarladıktan sonra programı kaydedip tekrar açıp deneyiniz.

Sub pdf_kaydet()
   Application.ScreenUpdating = False
   Application.DisplayAlerts = False
   Set shliste = Sheets("SinifListesi")
   Set shoptik = Sheets("Optik")
   yol = ActiveWorkbook.Path & "\"
   
   sonsatir = shliste.Cells(Rows.Count, "A").End(3).Row
   For i = 2 To sonsatir
      sinif = shliste.Cells(i, 1).Value
      numara = shliste.Cells(i, 2).Value
      ogrenci = shliste.Cells(i, 3).Value
      
      shoptik.Cells(2, "A").Value = ogrenci
      shoptik.Cells(3, "A").Value = sinif
      shoptik.Cells(4, "A").Value = numara

      yeniklasor = yol & sinif
      dosya = yeniklasor & "\" & ogrenci & "-" & numara

      If Dir(yeniklasor, vbDirectory) = "" Then MkDir yeniklasor

      shoptik.ExportAsFixedFormat Type:=xlTypePDF, Filename:=dosya, Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False

   Next i
   Application.ScreenUpdating = True
   Application.DisplayAlerts = True
End Sub

 

[BedriA]

Asri Hocam,

Harikasınız.

Çok teşekkür ederim.