VBA ile yeni dosya açma ve başvuruya göre dosya adı kaydetme

[aydogankemal]

Merhabalar,
1-VBA kodları ile mevcut dosyamdaki Ring sayfasından ("A1:K14") verilerini kopyalayıp,
2-Yeni bir Çalışma Kitabı açıp,
3-Kopyalanan verileri değer ve biçim olarak yapıştırmak,
4-Dosya adını da verileri kopyaladığım Data dosyasının Ring sayfasından K3 ve C2 değerlerini alarak kaydetmek istiyorum.

Çok gibi oldu farkındayım ama madde madde yazdım ki hepsi daha açık olsun diye. Bence gerek yok ama örnek dosya isterseniz yükleyebilirim

 

[Korhan Ayhan]

Merhaba,

K3 ve C2 hücrelerinde ne yazıyor?

 

[aydogankemal]

Merhaba,

K3 ve C2 hücrelerinde ne yazıyor?

K3 te Proje Kodu (Örneğin 2654), C2 de Proje Adı (Örneğin Hightech Kanada)
Dosya Adının bu verilere göre 2656 Hightech Kanada olarak kaydedilmesini istiyorum

 

[Korhan Ayhan]

Dosyanın kayıt olacağı adres belli mi?

 

[aydogankemal]

Dosyanın kayıt olacağı adres belli mi?

D:\Projects klasörüne kaydolacak

 

[Korhan Ayhan]

Deneyiniz.

Option Explicit

Sub My_Range_to_Workbook()
    Dim WB1 As Workbook, WB2 As Workbook, My_Path As String
    
    Application.ScreenUpdating = False
    
    Set WB1 = ThisWorkbook
    Set WB2 = Workbooks.Add
    
    My_Path = "D:\Projects\"
    
    WB1.Sheets("Ring").Range("A1:K14").Copy
    With WB2.Sheets(1)
        .Range("A1").PasteSpecial xlPasteValues
        .Range("A1").PasteSpecial xlPasteFormats
        .Range("A1").Select
    End With
        
    Application.CutCopyMode = False
    Application.DisplayAlerts = False
    WB2.SaveAs Filename:=My_Path & WB1.Sheets("Ring").Range("K3") & _
    " " & WB1.Sheets("Ring").Range("C2") & ".xlsx", _
    FileFormat:=xlOpenXMLWorkbook, CreateBackup:=False
    Application.DisplayAlerts = True
    WB2.Close

    Set WB1 = Nothing
    Set WB2 = Nothing

    Application.ScreenUpdating = True

    MsgBox "İşleminiz tamamlanmıştır.", vbInformation
End Sub

 

[aydogankemal]

Teşekkür ederim, hocam, emeğine sağlık

 

[aydogankemal]

Dosyanın kayıt olacağı adres belli mi?

Hocam peki kaydettikten sonra o çalışma kitabının aktif olması için nasıl bir kod eklemeliyim

 

[Korhan Ayhan]

Aktif olmasından kastınız açık kalması ise aşağıdaki satırı silmeniz yeterli olacaktır.

WB2.Close