vba ile cmd kullanımı hk

[chakistes]

merhaba arkadaşlar bir program üzerinde çalışma yapıyorum amacım dos ortamında komut göndermek ve gelen sonucu b sütununa aktarmak
örnek userformda commandbutton ile dos ortamında exceldeki a sütununda ipconfig yazdık varsayalım dos ekranında çıkan soncu b sütununa aktarmasını istiyorum.

 

[Asri]

Komutlarınızı ipconfig /all > veri.txt olarak çalıştırın. Yani her komuttan sonra > veri.txt yi ekleyin.
Sonra da bu veri.txt dosyasının içinden istediğiniz verileri alırsınız.

Kaynak: http://www.vbaexpress.com/kb/getarticle.php?kb_id=537

Sub IPtest()
    Dim wsh As Object
    Dim RegEx As Object, RegM As Object
    Dim FSO As Object, fil As Object
    Dim ts As Object, txtAll As String, TempFil As String
    Set wsh = CreateObject("WScript.Shell")
    Set FSO = CreateObject("Scripting.FileSystemObject")
    Set RegEx = CreateObject("vbscript.regexp")
    TempFil = "C:\myip.txt"
     ' Save ipconfig info to temporary file
    wsh.Run "%comspec% /c ipconfig > " & TempFil, 0, True
    With RegEx
        .Pattern = "(\d{1,3}\.){3}\d{1,3}"
        .Global = False
    End With
    Set fil = FSO.GetFile(TempFil)
     ' Access temporary file
    Set ts = fil.OpenAsTextStream(1)
    txtAll = ts.ReadAll
    Set RegM = RegEx.Execute(txtAll)
     ' Return IP address to Activesheet cell A1 by parsing text
    ActiveSheet.Range("A1").Value = RegM(0)
    ActiveSheet.Range("A1").EntireColumn.AutoFit
    ts.Close
     ' Remove temp file
    Kill TempFil
    
    Set ts = Nothing
    Set wsh = Nothing
    Set fil = Nothing
    Set FSO = Nothing
    Set RegM = Nothing
    Set RegEx = Nothing
End Sub

 

[Tevfik_Kursun]

Merhaba Asri Hocam,
Bu hatayı niçin vermiş olabilir?
Saygılarımla

 

[Asri]

Merhaba Asri Hocam,
Bu hatayı niçin vermiş olabilir?
Saygılarımla

Myip.txt dosyası için bir klasörü belirleyin. Direkt C:\ ye dosya oluşturmayın.

TempFil = "C:\temp\myip.txt"

 

[Tevfik_Kursun]

Teşekkür ederim
Saygılarımla