Vadesi 1 (bir) yılı geçenlerin yevmiye kayıtları

[1903emre34@gmail.com]

Merhabalar,

Dosyada açıklamalar yaptım.

Teşekkürler

 

[Ömer]

Merhaba,

Bu şekilde deneyin. Toplam alanını kendinize göre değiştirebilirsiniz.

=TOPLA.ÇARPIM((A2:A50>=L8)*(A2:A50<=TARİH(YIL(L8);AY(L8)[COLOR="Blue"]+12[/COLOR];GÜN(L8)))*([COLOR="Red"]B2:C50[/COLOR]))

Not: Açıklamada 12 ay süresince dediğiniz için L8 deki tarihe 12 ay ilave ettim.
--------------------------------------------------------------------------------------------
Eğer 12 ay değilde sarı alan mantığıyla 12 satır ilave edilecekse;

301 için:

=TOPLA(KAYDIR(B2;KAÇINCI(L8;A2:A50;0)-1;;12;2))

402 için:

=TOPLA(KAYDIR(C2;KAÇINCI(L8;A2:A50;0)-1;;12;1))

.

 

[1903emre34@gmail.com]

Ömer bey, teşekkürler

Ödeme planında, anapara bölümünde 0.00 olduğu takdirde yanındaki tutarı almayacak şekilde formülde nasıl değişiklik yapabiliriz. (301 ve 402)

402 hesabı, 3.300

301 hesabı 36.300

 

[Ömer]

2 farklı mantığa göre çözüm sunmuştum. Hangisi üzerinden bu istediğiniz yapılacak.?

 

[1903emre34@gmail.com]

Aşağıdaki formüller için;

TOPLA(KAYDIR(B2;KAÇINCI(L8;A2:A50;0)-1;;12;2))

=TOPLA(KAYDIR(C2;KAÇINCI(L8;A2:A50;0)-1;;12;1))

 

[Ömer]

301:

=topla.çarpım((kaydır(b2;kaçıncı(l8;a2:a50;0)-1;;12;1)<>0)*(kaydır(b2;kaçıncı(l8;a2:a50;0)-1;;12;2)))

402:

=topla.çarpım((kaydır(b2;kaçıncı(l8;a2:a50;0)-1;;12;1)<>0)*(kaydır(c2;kaçıncı(l8;a2:a50;0)-1;;12;1)))

------------------------------------------------------------------------------------

Genel 12 ay için:

301:

=TOPLA.ÇARPIM((A2:A50>=L8)*(A2:A50<=TARİH(YIL(L8);AY(L8)+12;GÜN(L8)))*(B2:B50<>0)*(B2:C50))

402:

=TOPLA.ÇARPIM((A2:A50>=L8)*(A2:A50<=TARİH(YIL(L8);AY(L8)+12;GÜN(L8)))*(B2:B50<>0)*(C2:C50))

.