Userfrom da listboxa veri alımı Hk.

[akmes]

Selamlar

Excel de belilli bir sayfadan seçili tarihe göre ilgili tüm sütundaki verileri
userfromdaki listbox a atacak örnek bir kod çalışmanız varmıdır? Teşekürler.

 

[N.Ziya Hiçdurmaz]

yanıt

Private Sub UserForm_Initialize()
Dim sat As Integer
For sat = 2 To Cells(65536, ActiveCell.Row).End(xlUp).Row
ListBox1.AddItem
ListBox1.List(s, 0) = Cells(sat, ActiveCell.Row)
s = s + 1
Next
End Sub

 

[akmes]

Hocam ilgin için çok teşekkür ederim.Benim ekte bir çalışmam var ama istediğim neticeyi alamıyorum.Bir bakıp nerede hata yaptığımı bulabilirmiyiz.İlgin için tekrar çok teşekkür ederim.

 

[Korhan Ayhan]

Selamlar,

Ekteki örnek dosyayı incelermisiniz.

Private Sub TextBox3_Change()
    Dim Bul As Range, Adres As String, Satır As Long
    Dim X As Long, Saat As Integer, Dakika As Long
    
    ListBox1.RowSource = ""
    TextBox5 = ""
    
    If TextBox3 <> "" And Len(TextBox3) = 10 And IsDate(TextBox3) Then
        Set Bul = Sheets("Sayfa2").Range("A:A").Find(CDate(TextBox3))
        If Not Bul Is Nothing Then
        Adres = Bul.Address
        Do
            ListBox1.AddItem
            ListBox1.List(Satır, 0) = Format(Bul.Value, "dd.mm.yyyy")
            ListBox1.List(Satır, 1) = Bul.Offset(0, 1).Value
            ListBox1.List(Satır, 2) = Bul.Offset(0, 2).Value
            ListBox1.List(Satır, 3) = Bul.Offset(0, 3).Value
            ListBox1.List(Satır, 4) = Format(Bul.Offset(0, 4).Value, "hh:mm")
            Satır = Satır + 1
        Set Bul = Sheets("Sayfa2").Range("A:A").FindNext(Bul)
        Loop While Not Bul Is Nothing And Bul.Address <> Adres
        End If
    
        For X = 0 To ListBox1.ListCount - 1
            Saat = Saat + Hour(ListBox1.List(X, 4))
            Dakika = Dakika + Minute(ListBox1.List(X, 4))
        Next
        
        Saat = Saat + Int(Dakika / 60)
        Dakika = Dakika Mod 60
        
        TextBox5 = Format(Saat, "00") & ":" & Format(Dakika, "00")
    End If
End Sub
 
Private Sub TextBox4_Change()
    Dim Bul As Range, Adres As String, Satır As Long
    Dim X As Long, Saat As Integer, Dakika As Long
    
    ListBox1.RowSource = ""
    TextBox5 = ""
    
    If TextBox4 <> "" Then
        Set Bul = Sheets("Sayfa2").Range("C:C").Find(TextBox4, LookAt:=xlWhole)
        If Not Bul Is Nothing Then
        Adres = Bul.Address
        Do
            ListBox1.AddItem
            ListBox1.List(Satır, 0) = Format(Bul.Offset(0, -2).Value, "dd.mm.yyyy")
            ListBox1.List(Satır, 1) = Bul.Offset(0, -1).Value
            ListBox1.List(Satır, 2) = Bul.Value
            ListBox1.List(Satır, 3) = Bul.Offset(0, 1).Value
            ListBox1.List(Satır, 4) = Format(Bul.Offset(0, 2).Value, "hh:mm")
            Satır = Satır + 1
        Set Bul = Sheets("Sayfa2").Range("C:C").FindNext(Bul)
        Loop While Not Bul Is Nothing And Bul.Address <> Adres
        End If
    
        For X = 0 To ListBox1.ListCount - 1
            Saat = Saat + Hour(ListBox1.List(X, 4))
            Dakika = Dakika + Minute(ListBox1.List(X, 4))
        Next
        
        Saat = Saat + Int(Dakika / 60)
        Dakika = Dakika Mod 60
        
        TextBox5 = Format(Saat, "00") & ":" & Format(Dakika, "00")
    End If
End Sub
 
Private Sub UserForm_Initialize()
    Dim X As Long, Saat As Integer, Dakika As Long
    
    With ListBox1
        .ColumnCount = 5
        .ColumnHeads = False
        .ColumnWidths = "50;60;60;324;50"
        .RowSource = "Sayfa2!A2:E" & Sheets("Sayfa2").Range("A65536").End(3).Row
    End With
    
    For X = 2 To Sheets("Sayfa2").Range("A65536").End(3).Row
        Saat = Saat + Hour(Sheets("Sayfa2").Cells(X, "E"))
        Dakika = Dakika + Minute(Sheets("Sayfa2").Cells(X, "E"))
    Next
    
    Saat = Saat + Int(Dakika / 60)
    Dakika = Dakika Mod 60
    
    TextBox5 = Format(Saat, "00") & ":" & Format(Dakika, "00")
End Sub

 

[akmes]

Üstadım; tam istediğim gibi,çok teşekkür ederim.