Userformdaki TextBoxlara Personel Sayılarını Çekemedim

[kelti_2000]

Selam

a1 hücresine yaptığımsay formülünü userformdaki personel sayısı textbox'ta nasıl göstere bilirim.

bide kadrodakiler kısmındaki işltme müdürü ve diğerlerini saydırıp textboxlarında nasıl gösterebilirim.

formüllemi iyi olur makro ile dahamı iyi olur.

şimdiden teşekkürler

 

[Recep İpek]

Aşağıdaki linte bununla ilgili birçok örnek bulunmaktadır.

http://www.excel.web.tr/forumdisplay.php?f=119

 

[Ferhat Pazarçevirdi]

TextBox'lar kullanarak, bu işin içinden çıkmanız oldukça zor olur ... Onun için, TextBox'ları kaldırarak, hepsinin yerine bir adet Listbox nesnesi yerleştirilmiştir. Daha sonra, Initialize kodu aşağıdaki şekilde inşa edildi.

Örneği inceleyiniz.

Private Sub UserForm_Initialize()
    Dim col As New Collection
    Dim wF As WorksheetFunction
    Set wF = Application.WorksheetFunction
    
    With ListBox1
        .ColumnCount = 2
        .ColumnWidths = "100;50"
    End With
    
    With Sheets("Sheet1")
        TextBox1 = wF.CountA(.Range("A5:A802"))
        
        On Error Resume Next
        For i = 5 To .Cells(65536, 1).End(xlUp).Row
            col.Add .Cells(i, "F"), .Cells(i, "F")
            If Err > 0 Then
                Err = 0
            Else
                ListBox1.AddItem .Cells(i, "F")
            End If
        Next i
        On Error GoTo 0
    End With
    For i = 0 To ListBox1.ListCount - 1
        ListBox1.List(i, 1) = wF.CountIf(Range("F5:F802"), ListBox1.List(i, 0))
    Next i
    Set wF = Nothing
End Sub

 

[kelti_2000]

Çok teşekkür ederim

g kolonundaki özürlü ve eski hükümlüleri ekleyemedim ben . o ikiside olsa çok güzel olur.

 

[Ferhat Pazarçevirdi]

Şu anki mevcut durumda; Listbox'ın ikinci kolonundaki rakamlar neler olacak? Yani "G" sütunu, hanig kritere göre değerlendirilecek ?

 

[kelti_2000]

ikici kolonu iptal edicem onu başka bir formda kullanıcam daha sonra

bazı personeller özürlü veya eski hükümlü kanunen işyerlerinde olması gerkiyor o yüzden kaç kişi özürlü, kaç kişi eski hükümlü onlarında sayısı gerekiyor.

 

[Ferhat Pazarçevirdi]

Bahsettiğiniz istatistiklerin, form üzerinde nereye yazılacağını söylemediğiniz için, işkembe-i kübra'dan sallayarak, bir tane daha listbox nesnesi forma ilave edilmiştir .. Kodlar da, aşağıdaki şekilde değiştirildi.

Private Sub UserForm_Initialize()
    Dim col As New Collection
    Dim col2 As New Collection
    
    Dim wF As WorksheetFunction
    Set wF = Application.WorksheetFunction
    
    With ListBox1
        .ColumnCount = 2
        .ColumnWidths = "100;25"
    End With
    
    With ListBox2
        .ColumnCount = 2
        .ColumnWidths = "100;25"
    End With
    
    
    With Sheets("Sheet1")
        TextBox1 = wF.CountA(.Range("A5:A802"))
        On Error Resume Next
        For i = 5 To .Cells(65536, 1).End(xlUp).Row
            col.Add .Cells(i, "F"), .Cells(i, "F")
            If Err > 0 Then Err = 0 Else ListBox1.AddItem .Cells(i, "F")
            col2.Add .Cells(i, "G"), .Cells(i, "G")
            If Err > 0 Then Err = 0 Else ListBox2.AddItem .Cells(i, "G")
        Next i
        On Error GoTo 0
    End With
    With ListBox1
        For i = 0 To .ListCount - 1
            .List(i, 1) = wF.CountIf(Range("F5:F802"), .List(i, 0))
        Next i
    End With
    
    With ListBox2
        For i = 0 To .ListCount - 1
            .List(i, 1) = wF.CountIf(Range("G5:G802"), .List(i, 0))
        Next i
    End With
    Set wF = Nothing
End Sub

 

[kelti_2000]

çok teşekkür ederim çok güzel oldu.

userformun şeklini daha sonra biraz değiştiririm ben