Usb flash disc serial numarasını öğrenmek

[baydeniro]

Merhaba Arkadaşlar,

USD Flash Disklerde Serial numarası oluyor mu ? varsa bunu VBA kodu ile öğrenmek nasıl mümkün olabilir acaba ?

 

[Korhan Ayhan]

Aşağıdaki linkten faydalandım.

File System Object

Sub Sürücü_Seri_Numarası_Göster()
On Error GoTo hata:
Dim ds, d, s, t
Set ds = CreateObject("Scripting.FileSystemObject")
Set d = ds.GetDrive("C:\")
Select Case d.DriveType
Case 0: t = "Bilinmiyor"
Case 1: t = "Çıkarılabilir"
Case 2: t = "HardDisk"
Case 3: t = "Ağ"
Case 4: t = "CD-ROM"
Case 5: t = "RAM Disk"

End Select
s = "Sürücü " & d.DriveLetter & ": " & t
If d.IsReady Then
s = s & vbCrLf & d.SerialNumber
MsgBox s

Else
s = s & vbCrLf & "Sürücü Hazır Değil."
MsgBox s
End If
End
hata:
MsgBox "Böyle Bir Sürücü Yok"
End Sub

 

[baydeniro]

Korhan Ayhan üstadım çok teşekkür ediyorum. Bu haliyle kullanacağım. Bir de şöyle bir durum oluyor; USB Disc takınca bazen F Drive oluyor, bazen G, bazen H gibi. Kodda Drive tanımını belirtince doğru sonu veriyor. Peki Harici Disc olanı bulması için, diğer bir anlatımla USB Disc F de olsa, H de olsa Serial Numarasının bulunmasına istinaden kodun nasıl edilebileceği konusunda öneriniz var mı !

 

[Korhan Ayhan]

Aşağıdaki gibi deneyiniz.

Option Explicit

Sub Sürücü_Seri_Numarası_Göster()
    Dim FSO As Object, Sürücüler As Object, Veri As Object, Sürücü As Object, Sürücü_Tipi As String
    
    Set FSO = CreateObject("Scripting.FileSystemObject")
    Set Sürücüler = FSO.Drives
    
    For Each Veri In Sürücüler
        Set Sürücü = FSO.GetDrive(Veri & "\")
        Select Case Sürücü.DriveType
            Case 0: Sürücü_Tipi = "Bilinmiyor"
            Case 1: Sürücü_Tipi = "Çıkarılabilir"
            Case 2: Sürücü_Tipi = "HardDisk"
            Case 3: Sürücü_Tipi = "Ağ"
            Case 4: Sürücü_Tipi = "CD-ROM"
            Case 5: Sürücü_Tipi = "RAM Disk"
        End Select
        
        If Sürücü.IsReady And Sürücü_Tipi = "Çıkarılabilir" Then
            MsgBox "Sürücü Adı : " & Veri & vbCrLf & _
                   "Sürücü Tipi : " & Sürücü_Tipi & vbCrLf & _
                   "Seri No : " & Sürücü.SerialNumber
        End If
    Next
End Sub

 

[baydeniro]

Korhan Ayhan Üstadım Allah razı olsun, elinize, emeğinize sağlık. Sağlıcakla kalın.