Tüm hücrelere eğerhata fonksiyonu eklemek

[mesutaygun70]

Bir videoda görmüştüm ama bir türlü yapamıyorum. 200 hücrede formülüm var. Ama ben bu tüm hücrelere Eğerhata formülünü eklemek istiyorum. Video şöyleydi tüm hücreler seçili iken Eğerhata yı mevcut formüle ekleme yaptı Enter basınca tüm hücrelere eklemişti. Nasıl yapıldığını yada yabılabileceğini anlatabilirmisiniz.

 

[Merhum İdris SERDAR]

.

Böyle bir şey mi?


Tüm sütunu seçin, ardından Git penceresini açmak için F5 tuşuna basın, Özel düğmesini tıklatın.

Özelliğe Git penceresinde formülleri seçin (daha sonra yalnızca Hatalar'ı seçebilirsiniz, ancak muhtemelen tüm formüller için yapmak en iyisidir ...), ardından Tamam'ı tıklatın.

Şimdi formül çubuğunda Eğerhata işlevini ekleyerek işlevi değiştirin ve ardından ctrl-enter tuşlarına basın.


.

 

[Korhan Ayhan]

Formüllerinizin hepsi aynı yapıda ise İdris beyin tarif ettiği yöntemle topluca yapılabilir. Aksi durumda makro kullanmanız daha uygun olacaktır.

Formül içeren hücre aralığını seçip kodu çalıştırın. Aralığı geniş tutarsanız işlemin süresi biraz uzayabilir.

Option Explicit

Sub Formula_Add_Iferror_Selection_Cells()
    Dim My_Cell As Range, Formul As String, Say As Long
   
    Application.ScreenUpdating = False
    Application.Calculation = xlCalculationManual
   
    For Each My_Cell In Selection
        If My_Cell.HasFormula Then
            If InStr(1, My_Cell.Formula, "IFERROR") = 0 Then
                Formul = "=IFERROR(" & IIf(Left(My_Cell.Formula, 1) = "=", Mid(My_Cell.Formula, 2, Len(My_Cell.Formula) - 1), My_Cell.Formula) & ",0)"
                My_Cell.Formula = Formul
                Formul = ""
                Say = Say + 1
            End If
        End If
    Next
   
    Application.Calculation = xlCalculationAutomatic
    Application.ScreenUpdating = True
   
    MsgBox "İşleminiz tamamlanmıştır." & Chr(10) & Chr(10) & _
           Say & " adet formül güncellenmiştir.", vbInformation
End Sub

 

[Tevfik_Kursun]

Merhaba Korhan Ayhan Hocam,
Bu makro, EĞERHATA(......;0) yapıyor. EĞERHATA(......;"") nasıl olur?

My_Cell.Formula) & ",0)"

burada 0 yerine boşluk koydum olmadı.
Saygılarımla

 

[Tevfik_Kursun]

Teşekkür ederim Korhan Ayhan Hocam,

My_Cell.Formula) & ","""")"

şeklinde yazılınca oluyor.
Saygılarımla

 

[solgun]

Teşekkürler, işimi çok hızlandırdı.