TOPLAMA (Aggregate) formülü ile benzersiz bulma

[modoste]

merhaba sayın hocalarım
aşağıdaki formülde P842 arasındaki verilerin benzersiz listesini yapmak istiyorum (Y8 de 1. 2. 3. diye devam edecek kısımdır)

=İNDİS($P$8:$P$42;TOPLAMA(15;6;(SATIR($P$8:$P$42)-SATIR($P$8)+1)/(EĞERSAY($P$8:$P$42;$P$8:$P$42)=1);$Y8)) sonuç çıkmıyor formülde nereyi düzeltmeliyim.

 

[ÖmerBey]

Merhaba,
Toplama işlevi şart değilse aşağıdaki konular işinizi görebilir.
Tekrarsız Liste
Tekrarsız, Boşluksuz, Alfabetik Liste (Excel 365)

 

[modoste]

Ömer Bey tekrarsız liste ile ilgili çalışmalar arşivimde var
ben toplama formülü ile yapabilir miyim diye denedim ama yapamadım. yapılabiliyor mu 1 nolu mesajımdaki formülle

 

[ÖmerBey]

Deneyiniz..
Sizin formülünüze benzeyen hali.

=İNDİS($P$8:$P$42;TOPLAMA(15;6;EĞER(SATIR($P$8:$P$42)-SATIR($P$8)+1=KAÇINCI($P$8:$P$42;$P$8:$P$42;0);SATIR($P$8:$P$42)-SATIR($P$8)+1);$Y8))

Biraz daha sadesi:

=İNDİS($P$8:$P$42;TOPLAMA(15;6;EĞER(SATIR($A$1:$A$100)=KAÇINCI($P$8:$P$42;$P$8:$P$42;0);SATIR($A$1:$A$100));SATIR(A1)))

 

[modoste]

Teşekkür Ederim ÖmerBey Hocam

 

[modoste]

Ömer Hocam benzersiz sıralamayı dizi formülü kullanmadan, TOPLAMA formülünün içinde kullanabilirim diye düşünüyodum ama sizden gelen formüller CTRL+SHİFT+ENTER yapınca doğru sonuç verdi. yani yine dizi formülü ile çözüm üretildi.
TOPLAMA formülünü kullanıp dizi formülü olmayan benzersiz sıralama formülü yapılabilir mi?

 

[ÖmerBey]

Açıkçası ben Excel'in eski bir versiyonunu kullanıyorum, Toplama formülü de dahil birçok işlev yer almıyor. Kullandığım versiyonda formüllerle benzersiz listeleme hususunda dizi formülsüz veya yardımcı sütunsuz bir çözüm bilmiyorum.
Bu işlem 2021 versiyonunda tek bir formülle (Benzersiz) yapılabiliyor. Bunun yerine dilerseniz Online Excel de kullanabilirsiniz.

 

[Merhum İdris SERDAR]

.

Böyle bir şey işinize yarar mı? Dizi formülü değil.

=IFERROR(LOOKUP(2;1/(COUNTIF($B$1:B1;$A$2:$A$15)=0);$A$2:$A$15);"")


.

 

[modoste]

Sayın İdris Hocam
sizin sitenizde benzersiz ile ilgili tüm excel dosyalarını indirdim zaten, çok teşekkür ederim.

 

[Korhan Ayhan]

Bence aranılan formülün B1 hücresine başvurmadan sonuç üreten bir formül olması isteniyor.

 

[modoste]

=İNDİS($P$8:$P$42;TOPLAMA(15;6;EĞER(SATIR($A$1:$A$100)=KAÇINCI($P$8:$P$42;$P$8:$P$42;0);SATIR($A$1:$A$100));SATIR(A1)))
bu formülü kullanırken
benzersiz listelemeye birde A8:A42 arasında "Ali" olanların ve B8:B42 arasında >50 koşulları eklenebilir mi (koşullu benzersiz yani)

 

[modoste]

parantezlerden kurtuldum ve çözüme ulaştım gibi
=İNDİS($P$8:$P$42;TOPLAMA(15;6;EĞER((SATIR($A$1:$A$100)=KAÇINCI($P$8:$P$42;$P$8:$P$42;0))*(A2:A42="Ali")*(B8:B42>50);SATIR($A$1:$A$100));SATIR(A1))) CTRL+SHİFT+ENTER

office 2019 kullandığımdan benzersizlerle ilgili formüllerden en sade olanlarını kullanmak istiyorum, koşullu benzersizlerle de aynı durum

 

[Korhan Ayhan]

Dizi formül olarak kullanacaksanız TOPLAMA formülüne gerek var mı?

 

[modoste]

Korhan Hocam, TOPLAMA formülünü İNDİS içinde kullanıp CTRL+SHİFT+ENTER olmadan çözüm üretilir zannediyordum ama ben 2019 kullandığımdan örneklerdeki formüller hep CTRL+SHİFT+ENTER ile çalıştı.

bu durumda mesajınıza katılıyorum.

 

[Erdem Akdemir]

Merhaba,

Toplama formülünün dizi formülü olmayan hali aşağıdaki gibi kullanabilir.
A1'den başlayarak verilerin olduğu varsayımı ile,

=EĞERHATA(İNDİS($A$1:$A$100;TOPLAMA(15;6;1/--(EĞERSAY(KAYDIR($A$1;;;SATIR($1:$100));$A$1:$A$100)=1)*SATIR($1:$100);SATIR(A1)));"")

 

[modoste]

A5:A48 arasında ise veriler hocam formülü revize edebilir miyiz.
çalışmalarımda genelde listeler aralarda oluyor o bakımdan. ve başka alternatif formüllerde beklemekteyim.

 

[Erdem Akdemir]

A ve B sütunundaki şartlara göre C sütunundan benzersiz verileri dizi formülü olmadan getirmek için,

=EĞERHATA(İNDİS($C$1:$C$10;TOPLAMA(15;6;((A1:A10="A")*(B1:B10>50))^0*SATIR(A1:A10);SATIR(A1)));"")

 

[Erdem Akdemir]

Sayın modeste siz kendi çalışmanızı ekleyin ona göre uyarlayalım.

 

[modoste]

eklediğiniz alternatif formülleri kendi tabloma uyarlıyorum Hocam teşekkür ederim.

dosya her sekmeyle alakalı veriler içeriyor ve ben sizlerden öğrendiğim yöntemleri mavi oklu yerde kullandım hocam teşekkür ederim. daha kısası daha sadesi olabilir mi diye alternatifler istemekteyim. yoksa sorum çözüldü teşekkürler tüm hocalarıma