Topla.Çarpim ile aynı sütunda iki veriyi aratma

[hamitcan]

Arkadaşlar merhaba,

=TOPLA.ÇARPIM((B2:B11="Armut")+(B2:B11="Elma")*(C2:C11))

Hem Armut hem de Elma olan kalemlerini toplatmak istiyorum fakat yanış topluyor. Nerede hata yapıyorum acaba ?

 

[hamitcan]

Galiba buldum. Alternatif Topla.Çarpım çözümlerini de bekliyorum.

TOPLA.ÇARPIM((B2:B11={"Elma";"Armut"})*(C2:C11))

 

[Ömer BARAN]

Merhaba.

=TOPLA.ÇARPIM([B][COLOR="Red"]([/COLOR][/B](B2:B11="Armut")+(B2:B11="Elma")[COLOR="red"][B])[/B][/COLOR]*(C2:C11))

 

[hamitcan]

Ömer Bey, parantezden mi kaybetmişiz ?

 

[Ömer BARAN]

Evet, öyle olmuş.

 

[Erdem Akdemir]

Merhaba,

G1 ve G2 hücresine elma, armut yazın. Hücresel başvuru ile aşağıdaki gibi yapabilirsiniz.Dizi formülüdür.

=TOPLA.ÇARPIM((B2:B11=DEVRİK_DÖNÜŞÜM(G1:G2))*(C2:C11))

 

[hamitcan]

Değişik bir çözüm daha. Daha arttıran yok mu ?

 

[Emir Hüseyin Çoban]

. . .

DİZİ formül;

=TOPLA(EĞER(B:B={"Elma";"Armut"};C:C))

. . .

 

[assenucler]

Farklı çözümler için teşekkürler.

 

[hamitcan]

Arkadaşlar geçmişte buna benzer sorulara çözümler arıyorduk. Şimdi biraz unutuldu sanırım. Arada bir beyin fırtınası yapmakta yarar var.

 

[Merhum İdris SERDAR]

.

Bir kaç örnek:

=SUMIF(B2:B11;"Elma";E2:E11)+SUMIF(B2:B11;"Armut";E2:E11)

=SUMIFS(E2:E11;B2:B11;"Elma")+SUMIFS(E2:E11;B2:B11;"Armut")

=SUM(SUMIF(B2:B11;{"Elma";"Armut"};E2:E11))

=SUMPRODUCT(SUMIF(B2:B11;{"Elma";"Armut"};E2:E11))

=SUM(SUMIFS(E2:E11;B2:B11;{"Elma";"Armut"}))

=SUMPRODUCT(SUMIFS(E2:E11;B2:B11;{"Elma";"Armut"}))

.

 

[hamitcan]

İdris Bey, çözümler için teşekkürler...

 

[kadirdiloglu]

topla çarpım formülü ile saydırma işlemini nasıl yapıyorduk?

 

[assenucler]

.

Bir kaç örnek:

=SUMIF(B2:B11;"Elma";E2:E11)+SUMIF(B2:B11;"Armut";E2:E11)

=SUMIFS(E2:E11;B2:B11;"Elma")+SUMIFS(E2:E11;B2:B11;"Armut")

=SUM(SUMIF(B2:B11;{"Elma";"Armut"};E2:E11))

=SUMPRODUCT(SUMIF(B2:B11;{"Elma";"Armut"};E2:E11))

=SUM(SUMIFS(E2:E11;B2:B11;{"Elma";"Armut"}))

=SUMPRODUCT(SUMIFS(E2:E11;B2:B11;{"Elma";"Armut"}))

.

Ne kadar farklı çözümler olduğunu görüyoruz. Paylaşımlar için bir kez daha teşekkürler.

SUMIFS Türkçe karşılığını öğrenebilir miyim?

 

[Merhum İdris SERDAR]

ne kadar farklı çözümler olduğunu görüyoruz. Paylaşımlar için bir kez daha teşekkürler.

Sumıfs türkçe karşılığını öğrenebilir miyim?

.

Türkçesi:

ÇOKETOPLA

.

 

[assenucler]

Sağ olun, var olun.