TextBox' a veri getirme

[soykan]

Sayfamda A sütununda Tarihler B Sütununda rakamlar var bir başka sayfada user formun içerisine yerleştirdiğim combo box ve text box var.
combo box'a tıkladığımda gelen tarihlerin içerisinden birini seçtiğimde o tarihe ait tutarı getirsin istiyorum. Aşağıdaki makroyu yazdım tarihler geliyor ama bir türlü tarihin karşısındaki tutarı getiremedim.

Private Sub UserForm_Initialize()

ComboBox1.Clear
ComboBox1.RowSource = "Data!a2:a" & Sheets("Data").[a50000].End(3).Row
End Sub

Private Sub ComboBox1_Change()

ComboBox1 = Format(ComboBox1, "dd.mm.yyyy")
Dim bul As Range
Dim i As Integer

For i = 2 To Sheets("Data").[a50000].End(3).Row

For Each bul In Sayfa11.Range("a2:a" & Sayfa11.Range("a65536").End(3).Row)
If bul = ComboBox1 Then
bul.Offset(i, -1).Activate
TextBox1 = bul.Offset(i, 2)
End If

Next bul
Next i
End Sub


Bir de ComboBox1.RowSource = "Data!a2:a" & Sheets("Data").[a50000].End(3).Row
Data Sayfamın ismi onun yerine ComboBox1.RowSource = "Sayfa11!a2:a" & Sheets("Data").[a50000].End(3).Row yazdığımda hata alıyorum sayfa ismi ile nsıl yazabilirim.

Çok Teşekkürler

 

[Ömer]

Merhaba,

Sorularınızı örnek dosya ile desteklemeye özen göstermenizi rica ederim.

 

[soykan]

Dosya Ektedir

Dosya ektedir. Teşekkürler

 

[Ömer]

Private Sub ComboBox1_Change()
 
    Dim c As Range, Sd As Worksheet
 
    Set Sd = Sheets("Data")
    
    With ComboBox1
        Set c = Sd.[A:A].Find(CDate(.Value), , xlValues, xlWhole)
        If Not c Is Nothing Then
            TextBox1.Text = Sd.Cells(c.Row, "B")
        Else
            TextBox1.Text = "Bulamadım"
        End If
        .Value = Format(.Value, "dd.mm.yyyy")
    End With
 
End Sub

İkinci sorunuzu anlamadım. Sayfa11 adında bir sayfa yok. Yazım şekli diğeriyle ayıdır. Sayfa adlarını kontrol edin.

 

[soykan]

Çok teşekkürler elinize sağlık.

Sayfa11 Data olarak adlandırılmış Sayfa

 

[Ömer]

Çok teşekkürler elinize sağlık.

Sayfa11 Data olarak adlandırılmış Sayfa

Bu şekilde deneyin.

Private Sub UserForm_Initialize()
 
    With ComboBox1
        .Clear
        .RowSource = "'" & Sayfa11.Name & "'!" & _
                    Range("A2:A" & Sayfa11.[A50000].End(3).Row).Address
    End With
 
End Sub

.