Tarihleri arası (Ay) Toplam aldırma

[kaptan14ts]

Tarih	TUTAR			TARİH	TUTAR
13.01.2025	1.000			31.01.2025
28.02.2025	2.000			28.02.2025
12.02.2025	3.000
01.01.2025	1.000
17.01.2025	5.000				Sağ tarafta yer alan ayların toplamını sağ tarafa nasıl ala bilirim.

 

[volki_112]

Tarih	TUTAR			TARİH	TUTAR
13.01.2025	1.000			31.01.2025
28.02.2025	2.000			28.02.2025
12.02.2025	3.000
01.01.2025	1.000
17.01.2025	5.000				Sağ tarafta yer alan ayların toplamını sağ tarafa nasıl ala bilirim.

dosya.tc dosya.co gibi paylaşım sitelerine dosyanızı yükleyip link verebilirsiniz.

 

[ccuneyt13]

Merhaba,
Verilerinizin A sütunundan başladığı varsayılarak aşağıdaki formülü deneyebilir misiniz.

=TOPLA.ÇARPIM((AY($A$2:$A$6)=AY(E2))*(YIL($A$2:$A$6)=YIL(E2))*$B$2:$B$6)

 

[kaptan14ts]

Merhaba,
Verilerinizin A sütunundan başladığı varsayılarak aşağıdaki formülü deneyebilir misiniz.

=TOPLA.ÇARPIM((AY($A$2:$A$6)=AY(E2))*(YIL($A$2:$A$6)=YIL(E2))*$B$2:$B$6)

Konu Çözüldü.
Yardımlarınız için teşekkürler.

 

[Korhan Ayhan]

Alternatifler...

=ÇOKETOPLA(B$2:B$1000;A$2:A$1000;">="&SERİAY(E2;-1)+1;A$2:A$1000;"<="&E2)

=TOPLA.ÇARPIM(--(METNEÇEVİR(A$2:A$1000;"ay")=METNEÇEVİR(E2;"ay"));(B$2:B$1000))

Ofis 365 alternatifler;

Dilediğiniz boş bir hücreye yazdığınızda tüm liste dökülmeli olarak listelenecektir.

=GRUPLAÖLÇÜT(METNEÇEVİR(A1:A1000;"yyyy-aa");B1:B1000;TOPLA;3;;;A1:A1000<>"")

Başlıkları değiştirmek isterseniz;

=DÜŞEYYIĞ({"Dönem";"Tutar"};GRUPLAÖLÇÜT(METNEÇEVİR(A2:A1000;"yyyy-aa");B2:B1000;TOPLA;;;;A2:A1000<>""))

=LET(
     Dönem; METNEÇEVİR(A2:A1000;"yyyy-aa");
     Tutar; B2:B1000;
     Liste; BENZERSİZ(SIRALA(FİLTRE(Dönem;ESAYIYSA(A2:A1000)*ESAYIYSA(Tutar))));
     Sonuç; BYROW(Liste;LAMBDA(X;TOPLA(FİLTRE(Tutar;Dönem=X))));
     DÜŞEYYIĞ({"Dönem";"Tutar"};YATAYYIĞ(Liste;Sonuç))
     )

 

[kaptan14ts]

Alternatifler...

=ÇOKETOPLA(B$2:B$1000;A$2:A$1000;">="&SERİAY(E2;-1)+1;A$2:A$1000;"<="&E2)

=TOPLA.ÇARPIM(--(METNEÇEVİR(A$2:A$1000;"ay")=METNEÇEVİR(E2;"ay"));(B$2:B$1000))

Ofis 365 alternatifler;

Dilediğiniz boş bir hücreye yazdığınızda tüm liste dökülmeli olarak listelenecektir.

=GRUPLAÖLÇÜT(METNEÇEVİR(A1:A1000;"yyyy-aa");B1:B1000;TOPLA;3;;;A1:A1000<>"")

Başlıkları değiştirmek isterseniz;

=DÜŞEYYIĞ({"Dönem";"Tutar"};GRUPLAÖLÇÜT(METNEÇEVİR(A2:A1000;"yyyy-aa");B2:B1000;TOPLA;;;;A2:A1000<>""))

=LET(
     Dönem; METNEÇEVİR(A2:A1000;"yyyy-aa");
     Tutar; B2:B1000;
     Liste; BENZERSİZ(SIRALA(FİLTRE(Dönem;ESAYIYSA(A2:A1000)*ESAYIYSA(Tutar))));
     Sonuç; BYROW(Liste;LAMBDA(X;TOPLA(FİLTRE(Tutar;Dönem=X))));
     DÜŞEYYIĞ({"Dönem";"Tutar"};YATAYYIĞ(Liste;Sonuç))
     )

Zaman ayırıp alternatif çözüm ürettiğiniz için teşekkürler.