Tamamı-Yapılan-Kalan Kesimlerle ilgili

[modoste]

Merhaba sayın hocalarım
ekli tablomda sorumu ilettim

 

[tugkan]

Harici siteye de yüklerseniz altın üye olmayanlardan da yardımcı olmak isteyen olabilir.

 

[modoste]

İndir Tamamı Yapılan Kalan Ayrımları

Dosyayı indir Tamamı Yapılan Kalan Ayrımları

dosya.co

 

[modoste]

sorunun kısa açıklaması ve benim işlerimde çokça karşıma çıkan bir durumdur
bir yolun 150. ile 1000. km leri (yolun tamamı diyelim) içinde farklı aralıklar tamamlanıyor örneğin 200-250. metresi tamamlandı 400-500. metresi ve 780-820. metresi tamamlandı bilgileri varken nereleri tamamlanmadı?? işte bunu bulabilmek adına sorduğum sorudur.
bu mesajıma göre çözersem yolun
150-200 arası
250-400 arası
500-780 arası
820-1000 arası tamamlanmadı. gönderdiğim excel dosyasında örneğimde aralıklar daha fazla
office 2019 eski formüllerle çözümü gerekmekte (office 365 fonksiyonlarıyla da çözüm üretilirse de ilerde kullanabilirim olur)

 

[modoste]

Makro ile de olsa bir çözüm bekliyorum bu sorum için çok karşıma çıkan bi durum

 

[Korhan Ayhan]

Belki işinize yarayabilir..

 

[52779]

Alternatif olarak, Formülle çözüm önerileri

Not : Ne yazık ki, bu çözüm için de sizden bir geri dönüş beklemiyorum. Ekstra zahmete gerek yok....

A​

B​

C​

D​

E​

F​

G​

H​

I​

J​

K​

L​

1​

Excel365

Excel 2019

2​

3​

TAMAMI

YAPILAN KISIM

EKSİK KISIMLAR

EKSİK KISIMLAR

4​

​

Başl. Km​

Bitiş km​

​

Başl. Km​

Bitiş km​

​

Başl. Km​

Bitiş km​

​

Başl. Km​

Bitiş km​

5​

​

108​

1245​

​

172​

238​

​

108​

172​

​

108​

172​

6​

​

​

​

​

238​

250​

​

250​

362​

​

250​

362​

7​

​

​

​

​

362​

400​

​

672​

688​

​

672​

688​

8​

​

​

​

​

400​

672​

​

695​

764​

​

695​

764​

9​

​

​

​

​

​

​

​

841​

875​

​

841​

875​

10​

​

​

​

​

764​

795​

​

912​

927​

​

912​

927​

11​

​

​

​

​

795​

841​

​

1114​

1229​

​

1114​

1229​

12​

​

​

​

​

927​

1008​

​

1238​

1245​

​

1238​

1245​

13​

​

​

​

​

1008​

1114​

​

​

​

​

​

​

14​

​

​

​

​

1229​

1238​

​

​

​

​

​

​

15​

​

​

​

​

875​

912​

​

​

​

​

​

​

16​

​

​

​

​

688​

695​

​

​

​

​

​

​

17​

​

​

​

​

​

​

​

​

​

​

​

​

18​

​

​

​

​

​

​

​

​

​

​

​

​

19​

​

​

​

​

​

​

​

​

​

​

​

​

Excel 365 ile
H5 hücresine yazılır. Tek hücredeki bu formülle, Sonuçlar komple dökülmeli gelecektir.

=LET(p;B5;q;C5;a;E5:F100;b;FİLTRE(a;(İNDİS(a;;1)<>"")*(İNDİS(a;;2)<>""));c;İNDİS(b;;1)&"-"&İNDİS(b;;2);d;SIRALA(BENZERSİZ(DÜŞEYYIĞ(p;q;SÜTUNA(EĞER((b<p)+(b>q);1/0;b);3))));e;BIRAK(d;-1)&"-"&BIRAK(d;1);f;FİLTRE(e;EYOKSA(KAÇINCI(e;c;0)));YATAYYIĞ(--METİNBÖL(f;"-");--SONRAKİMETİN(f;"-")))

Excel 2019 için 3 adet Ad Tanımlaması mevcut
p :

=XMLFİLTRELE("<x><a>"&METİNBİRLEŞTİR("</a><a>";;EĞERHATA(KÜÇÜK((Sayfa1!$E$5:$F$100;Sayfa1!$B$5:$C$5);SATIR(Sayfa1!$1:$100));""))&"</a></x>";"//a[not(. = preceding::a/.)]")

q :

=SATIRSAY(p)

s :

=İNDİS(p;SATIR(DOLAYLI("1:"&q-1)))&"-"&İNDİS(p;SATIR(DOLAYLI("2:"&q)))

ve
K5 hücresine yazılır aşağıya doğru kopyalanır

=EĞERHATA(İNDİS(p;TOPLAMA(15;6;SATIR(DOLAYLI("1:"&q))/EYOKSA(KAÇINCI(s;$E$5:$E$100&"-"&$F$5:$F$100;0));SATIR(A1)));"")

L5 hücresine yazılır ve aşağıya kopyalanır.

=EĞERHATA(İNDİS(p;1+TOPLAMA(15;6;SATIR(DOLAYLI("1:"&q))/EYOKSA(KAÇINCI(s;$E$5:$E$100&"-"&$F$5:$F$100;0));SATIR(A1)));"")

Ve koşullar :
1 - B5 ve C5 hücreleri Dolu olup Pozitif SAYI olmalı. C5, B5 ten BÜYÜK olmalı
2 - Yapılan Kısımlar için
a - Başlama km si B5 ten Büyük ya da Eşit olmalı. Bitiş km si C5 ten Küçük ya da Eşit olmalı.
Diğer deyişle veriler, B5 - C5 aralığında olmalı. Pozitif SAYI.
b - Bitiş km ve Başlama km her ikisi de Dolu olmalı.
c - Veriler arasında BOŞ hücre değil ama BOŞ satır bırakılabilir.
d - Veriler Sıralı olacak diye bir kural yok. Sırasız olabilir.
e - En az 1 satır veri içermeli... Veri aralığı E5 : F100 olarak alındı.

ANONYMOUS - Filemail

Click here to view and download these shared files from Filemail.com

www.filemail.com

 

[modoste]

Çözümler için teşekkür ederim