Soru Tablo karşılaştırma

[canercan02]

Merhaba Arkadaşlar;

Elimde iki ayrı tablo var; sayfa1’deki tablonun A sütununda bulunan Fiş no ile

Sayfa2’deki tablonun G sütununda bulunan Belge No alanı ortak.

Amacım vba koduyla Sayfa1 deki fiş no ile Sayfa2 deki belge no ları karşılaştırarak;

Eğer aradığımız değer sayfa2 de yoksa sayfa1 de I sütunundaki karşılaştır alanına “Aranan Değer yok”

Eğer aradığımız fiş no, sayfa2 deki belge no alanında varsa tutarları karşılaştırması gerekiyor. Eğer tutarlar da aynı ise Tutarlı, Tutarlar farklı ise Tutarlar hatalı şeklinde yazdıracak bir kod için yardımlarınızı rica ediyorum.
Örnek Dosya aşağıdaki linktedir. Teşekkürler

İndir karşılaştırma

Dosyayı indir karşılaştırma

dosya.co

 

[veyselemre]

Sub test()
    son = Sheets("Sayfa2").Cells(Rows.Count, "G").End(3).Row
    veri = Sheets("Sayfa2").Range("G2:J" & son).Value
    With CreateObject("Scripting.Dictionary")
        For i = 1 To UBound(veri)
            If Not .exists(veri(i, 1)) Then
                .Item(veri(i, 1)) = veri(i, 4)
            End If
        Next i
        Sheets("Sayfa1").Select
        son = Cells(Rows.Count, "A").End(3).Row
        Range("I2:I" & son).ClearContents
        For i = 2 To son
            If Not .exists(Cells(i, 1).Value) Then
                Cells(i, "I").Value = "Aranan Değer Yok"
            Else
                If .Item(Cells(i, 1).Value) = Cells(i, "H").Value Then
                    Cells(i, "I").Value = "Tutarlı"
                Else
                    Cells(i, "I").Value = "Tutarlar Hatalı"
                End If
            End If
        Next i
    End With
End Sub

 

[sbayyigit]

Çok teşekkür ederim hocam tam istediğim gibi.

 

[canercan02]

Denedim VeyselEmre bey yaklaşık 5000 satırı çabucak karşılaştırdı. Teşekkürler