sütundan tek değer getirme

[KMLZDMR]

Merhaba,
A sütunundaki sayı değerlerinden sadece bir tanesini E SÜTUNUNA GETİRECEK formül gerekli
Excel 2003 için formül gerekli. Ekli dosya örnek vardır.

 

[AdemCan]

Merhaba;
E2 hücresine

=EĞERHATA(İNDİS($A$2:$A$39;KAÇINCI(0;EĞERSAY($E$1:E1;$A$2:$A$39);0));0)

formülünü ekleyiniz ve CTRL+SHIFT+ENTER ile formülü tamamlayıp deneyiniz.

 

[Korhan Ayhan]

Excel 2003 için önerilen formülü aşağıdaki gibi değiştirmeniz daha uygun olacaktır.

=EĞER(EHATALIYSA(İNDİS($A$2:$A$39;KAÇINCI(0;EĞER($A$2:$A$39<>0;EĞERSAY($E$1:E1;$A$2:$A$39));0)));"";İNDİS($A$2:$A$39;KAÇINCI(0;EĞER($A$2:$A$39<>0;EĞERSAY($E$1:E1;$A$2:$A$39));0)))

EĞERHATA fonksiyonu eski sürümlerde çalışmaz.

 

[AdemCan]

Merhaba Korhan Bey;
Düzeltme için teşekkür ederim.

Formülün 2003 Excel'de çalışıp çalışmayacağı konusunda tereddüt edince, Microsoft'un Excel İşlevleri sayfasına baktım. Orada bazı formüllerin hangi versiyon ile çıktığını belirtmişler. Eğerhata ve diğerlerinde versiyon belirtmesi olmayınca, 2003 Excel'de çalışır diye düşünmüştüm. Yanlış paylaşım için özür dilerim, kusura bakmayın.

 

[Korhan Ayhan]

Özür dilenecek bir durum yok...

Sadece bilgilendirmek amacıyla yazmıştım..

 

[AdemCan]

Teşekkür ederim.

 

[KMLZDMR]

sayın korhan ayhan ve faye_efsane
Malesef iki formülde işlem yapmıyor. Formüllerinizi E2 hücresine yazdım.
lütfen gönderdiğim tablodan yapıp iletebilir misiniz.

Korhan bey formülü boş değer getiriyor

=EĞERHATA(İNDİS($A$2:$A$39;KAÇINCI(0;EĞERSAY($E$1:E1;$A$2:$A$39);0));0) olan formülü
excel 2003 için =EĞER(EHATALIYSA(İNDİS($A$2:$A$39;KAÇINCI(0;EĞERSAY($E$1:E1;$A$2:$A$39);0)));0;İNDİS($A$2:$A$39;KAÇINCI(0;EĞERSAY($E$1:E1;$A$2:$A$39);0))) olarak düzenledim. her satırda 0 verdi.

 

[Erdem Akdemir]

Dizi formülü oldukları için CTRL+SHIFT+ENTER ile kapatmanız gerekir.

2. no'lu mesajda nasıl çalışacağı belirtilmiş.

 

[KMLZDMR]

Sayın kuvari teşekkür ederim.
Ancak bazı konular gelişti.
a) 2 nolu mesajdaki formülü 2003 excel versiyona {=EĞER(EHATALIYSA(İNDİS($A$2:$A$39;KAÇINCI(0;EĞERSAY($E$1:E11;$A$2:$A$39);0)));0;İNDİS($A$2:$A$39;KAÇINCI(0;EĞERSAY($E$1:E11;$A$2:$A$39);0)))} çevirdim. oldu. ANCAK, aralıkta bulunan sıfır (0) değerler olunca gelmemesini nasıl sağlarız. Formülü bu şekilde geliştirebilir miyiz.

 

[Korhan Ayhan]

Benim önerdiğim formülü denerseniz sıfır olan değerler listede görünmez.

DİZİ formülü olarak uygulayınız.

 

[KMLZDMR]

Sayın Korhan Ayhan Bey,
9 nolu mesajda da belirttiğim ve yazdığım gibi Dizi formülü olarak uyguladım. Formül çalıştı ancak indis in dizi alanında (0) sıfır değerler var...
sonuç alanında sıfırların gelmemesini sağlamak gerekli.... lütfen tekrar bakabilir misiniz.

KORHAN BEY, sizin formülünüz çalıştı sıfırları getirmiyor.Faye-efsane nin 2 mesajdaki formülündekini kast ettim.
teşekkür ederim.

 

[Korhan Ayhan]

Benim önerdiğim çözüm zaten 2. mesajdaki çözümle aynı. Sadece formülün içine sıfır koşulu ekledim.

 

[KMLZDMR]

şimdi gördüm. sağolun.

 

[Erdem Akdemir]

Alternatif sıfırlar hariç dizi formülü,

=EĞERHATA(İNDİS($A$2:$A$39;KÜÇÜK(EĞERHATA(KAÇINCI(SATIR($A$2:$A$39)-1;KAÇINCI(EĞER($A$2:$A$39>0;$A$2:$A$39);$A$2:$A$39;0);0);"");SATIR(A1)));"")

 

[KMLZDMR]

Sayın Kuvari,
14. mesjda düzenlediğiniz Eğer(hata(..... formülünüzü Excel2003 olarak formülü düzenlemeniz mümkün mü?
Dönüştüremedim. Birleştirme alanını yapamıyorum.... teşekkür ederim.
=EĞER(EHATALIYSA(İNDİS($A$2:$A$39;KÜÇÜK(EĞERHATA(KAÇINCI(SATIR($A$2:$A$39)-1;KAÇINCI(EĞER($A$2:$A$39>0;$A$2:$A$39);$A$2:$A$39;0);0);"");SATIR(A3)))/1));"";İNDİS($A$2:$A$39;KÜÇÜK(EĞERHATA(KAÇINCI(SATIR($A$2:$A$39)-1;KAÇINCI(EĞER($A$2:$A$39>0;$A$2:$A$39);$A$2:$A$39;0);0);"");SATIR(A3)))/1;"")))

 

[Korhan Ayhan]

Merhaba,

Son önerilen formülde iki adet EĞERHATA var. Formülü buna göre düzenlemelisiniz.

 

[KMLZDMR]

Sayın Kuvari ve Korhan Ayhan
Malesef, içi içe iki adet EĞERHATA( formülünü EĞER(EHATALIYSA( parantezine almayı yapamadım... Lütfen düzenleyebilir misiniz?

=EĞERHATA(İNDİS($A$2:$A$39;KÜÇÜK(EĞERHATA(KAÇINCI(SATIR($A$2:$A$39)-1;KAÇINCI(EĞER($A$2:$A$39>0;$A$2:$A$39);$A$2:$A$39;0);0);"");SATIR(A3)))/1;"")


=EĞER(ehatalıysa(İNDİS($A$2:$A$39;KÜÇÜK(EĞER(ehatalıysa(KAÇINCI(SATIR($A$2:$A$39)-1;KAÇINCI(EĞER($A$2:$A$39>0;$A$2:$A$39);$A$2:$A$39;0);0);"");SATIR(A3)))/1;"")));"hatalı";İNDİS($A$2:$A$39;KÜÇÜK(EĞER(ehatalıysa(KAÇINCI(SATIR($A$2:$A$39)-1;KAÇINCI(EĞER($A$2:$A$39>0;$A$2:$A$39);$A$2:$A$39;0);0);"");SATIR(A3)))/1;"")))

 

[Erdem Akdemir]

Merhaba,

2003 versiyonları için aşağıdaki dizi formülü olabilir. 2003 'ü değiştirmenin zamanı gelmedi mi?

=İNDİS($A$2:$A$39;KÜÇÜK(EĞER((EĞERSAY(KAYDIR($A$2;;;SATIR($A$2:$A$39)-1);$A$2:$A$39)=1)*($A$2:$A$39>0);SATIR($A$2:$A$39)-1;"");SATIR(A1)))

Hata mesajından kurtulmak için alternatif,

=EĞER(SATIR(A1)<=TOPLA(1/EĞERSAY($A$2:$A$39;$A$2:$A$39))-EĞER(EĞERSAY($A$2:$A$39;0)>=1;1;0);İNDİS($A$2:$A$39;KÜÇÜK(EĞER((EĞERSAY(KAYDIR($A$2;;;SATIR($A$2:$A$39)-1);$A$2:$A$39)=1)*($A$2:$A$39>0);SATIR($A$2:$A$39)-1;"");SATIR(A1)));"")