Sütun karşılaştırma

[emre_by]

Merhaba arkadaşlar,

Karşılaştırma analizi oluşturmak istiyorum forumlara baktım ama yapamadım.Yardımcı olabilirseniz memnun olurum.

A Sütununda Ürünler sıralı
B Sütununda bu ürünlerin fiyatları

Sonrasında C ve D Sutunlarına da liste halinde ekliyeceğim aynı ve farklı ürünler ve fiyatları olacak.

Yapmak istediğim E ve F sütünlarında, ürünlerin fiyatlarında azalış olanları ve sadece yeni eklenen (C ve D sütunlarına) ürünleri göstermesi

 

[savas_145]

Herhangi bir upload sitesine ornek bir dosya eklerseniz. Yardım eden olacaktır.

 

[emre_by]

link

https://ufile.io/fbf20

 

[Ömer]

Merhaba,

Bu şekilde deneyin.

Sub Karsilastir()
    
    Dim c As Range, sat As Long, i As Long
    
    Application.ScreenUpdating = False
    Range("E2:F" & Rows.Count).ClearContents
    
    sat = 2
    For i = 2 To Cells(Rows.Count, "C").End(xlUp).Row
        If Cells(i, "C") <> "" Then
            Set c = [A:A].Find(Cells(i, "C"), , xlValues, xlWhole)
            If Not c Is Nothing Then
                If Cells(c.Row, "B") > Cells(i, "D") Then
                    Cells(sat, "E") = Cells(i, "C")
                    Cells(sat, "F") = Cells(i, "D")
                    sat = sat + 1
                End If
            Else
                Cells(sat, "E") = Cells(i, "C")
                Cells(sat, "F") = Cells(i, "D")
                sat = sat + 1
            End If
        End If
    Next i
    
    Application.ScreenUpdating = True
    
End Sub

.

 

[emre_by]

Teşekkür ederim