Sıralama

[şehiriçi]

arkadaşlar sıralamayı yapamadım excel forumda bu konu ile ilgili daha öncede yardım almıştım ama o kadar uğraşmama rağmen tam sonuca yaklaşıyorum ama...olmuyor yardımınızı bekliyorum . teşekkürler deneme dosyası ekte

 

[turist]

Dosyanız ektedir.
DİZİ FORMÜL uygulanmıştır.

 

[şehiriçi]

sayın turist mükemmel teşekkür ederim olmuş ,olmayansa ben bu formulün mantığınımı diyem çözemiyorum anlıyamıyorum bu satır kısmını nasıl yaptığınızı (tabi zamanınız varsa )yorumlayabilirseniz ben ve benim gibi acemilere ışık olur diye düşünüyorum yinede ben soruma cevap aldım teşekkürler

 

[turist]

sayın turist mükemmel teşekkür ederim olmuş ,olmayansa ben bu formulün mantığınımı diyem çözemiyorum anlıyamıyorum bu satır kısmını nasıl yaptığınızı (tabi zamanınız varsa )yorumlayabilirseniz ben ve benim gibi acemilere ışık olur diye düşünüyorum yinede ben soruma cevap aldım teşekkürler

=EĞER(SATIRSAY($I$3:I3)>EĞERSAY($A$3:$A$200;$A$1);"";İNDİS($A$3:$A$200;KÜÇÜK(EĞER($A$3:$A$200=$A$1;SATIR($A$3:$A$200)-SATIR($A$3)+1);SATIRSAY($I$3:I3))))

Dizi formülünde;
EĞERSAY($A$3:$A$200;$A$1) :Listesi yapılacak Apt.Adının(A1 de)
A3:A200 aralığında kaç adet olduğunu bulur.(Örnek Altınkent b blok
12 adettir)
SATIRSAY($I$3:I3) : Formülde 1 ve alt sıralarda 2,3,4,5......200 yazmak yerine bu formülle 1 sayısını bulur. Formül alttaki satırda SATIRSAY($I$3:I4) olduğu zaman bu da 2 demektir.her satırda 1er artarak bu böyle devam eder.(Dikkat ! I3 sabittir yani $I$3 şeklinde, diğeri ise her satırda artması için değişkendir.)
Formüllü satırlar; SATIRSAY($I$3:I14) yazan yere geldiğinde SATIRSAY($I$3:I14) değeri de 12 demektir.
Bir sonraki satırda SATIRSAY($I$3:I15) olduğunda değeri 13 olacaktır.
Formülün başındaki koşula güre bu satırda
EĞER(SATIRSAY($I$3:I15)>EĞERSAY($A$3:$A$200;$A$1);""
olduğu için satır sayısı (13) Apt. Adı (12) dir yani 13 12den büyüktür.
Formülün bu kısmı bu koşula göre bulunduğu yeri ve sonraki satırları boş ( "") bırakır.
Formülün bulunduğu ilk satırdan,
EĞER(SATIRSAY($I$3:I14)>EĞERSAY($A$3:$A$200;$A$1) yazan satıra kadar ise (1 den 12 ye kadar değer yani satırlar Apt.adı sayısından büyük olmadığı için),
EĞER formülünün ikinci koşulu ,
İNDİS($A$3:$A$200;KÜÇÜK(EĞER($A$3:$A$200=$A$1;SATIR($A$3:$A$200)-SATIR($A$3)+1);SATIRSAY($I$3:I3)))
kısmı devrede olacaktır.
Bu durumda ise; Apt. Adının aranacağı kısım İNDİS($A$3:$A$200 alanında yer almaktadır.
Bu alanda Aranan Apartman adının hangi satırlarda bulunduğunu ise; formülün
KÜÇÜK(EĞER($A$3:$A$200=$A$1;SATIR($A$3:$A$200)-SATIR($A$3)+1);SATIRSAY($I$3:I3))
kısmı belirler.(Bu yapı İNDİS'li formüllerde genellikle kullanılan "KAÇINCI" fonksiyonu gibi düşünülebilir)
EĞER($A$3:$A$200=$A$1;SATIR($A$3:$A$200)-SATIR($A$3)+1)
kısmı dizi formül olarak yazıldığında ve yazılan formüle, üstteki formül çubuğunda F9 yaparak bakıldığında; {1;2;3;4;5;6;7;8;9;10;11;12;YANLIŞ;YANLIŞ;.....YANLIŞ} olarak görülür.
Bu değerler ilk apt. adı için böyle gözükürken, 2.ci sonraki apartman adı seçildiğinde {YANLIŞ;YANLIŞ;13;14;15;16;17;18;19;20;21;22;23;24;YANLIŞ;YANLIŞ} gibi görülür.
Bu değerler bu şekilde dizi halinde belirlenirken,
KÜÇÜK fonksiyonu ;çalışma prensibi ile bu sıralanan dizinin kaçıncı küçük sıradan başlayacağını belirler.
Bu sıra ise yine SATIRSAY($I$3:I3) kısmı belirler (Bu 1 demektir)

KÜÇÜK(EĞER($A$3:$A$200=$A$1;SATIR($A$3:$A$200)-SATIR($A$3)+1);SATIRSAY($I$3:I3)) formülü bulunduğu satır için:
KÜÇÜK({1;2;3;4;5;6;7;8;9;10;11;12;YANLIŞ;YANLIŞ;.....YANLIŞ};1)
şekline girer bunun sonucu da 1 dir yani İNDİS'te belirlenen alanın 1.ci satırı.
Formül'ün bu kısmı
KÜÇÜK(EĞER($A$3:$A$200=$A$1;SATIR($A$3:$A$200)-SATIR($A$3)+1);SATIRSAY($I$3:I14))
olduğunda ise
KÜÇÜK({1;2;3;4;5;6;7;8;9;10;11;12;YANLIŞ;YANLIŞ;.....YANLIŞ};12)
şekline girer ve sonucu da 12 dir. Yani İNDİSte belirlenen alanın 12.ci satırını alır.

DİZİ formüllerin yapısı olmasaydı bütün bu işlemleri yapmak mümkün olmayacaktı.(Tabii ki formüller konu olduğu için makro, özet tablo , filtre, süz gibi özellikler söz konusu değildir)

Bilgim çerçevesinde açıklamaya çalıştım.Hata ve unuttuklarım için değerli uzman ve yöneticilerimin affına sığınırım.
Saygılarımla,
turist

 

[şehiriçi]

EĞER($A$3:$A$200=$A$1;SATIR($A$3:$A$200)-SATIR($A$3)+1 özelikle buraya çok takılıyordum. minnettarım çok faydalı oldu iyiki varsınız iyiki bu form var teşekkürler

 

[şehiriçi]

sayın turist yazdığınız formül üzerinde oldukça düşündüm satır kısmı ile ilgili bir ayrıntı kafama takıldı ekte soruma cevap verirseniz memnun olacağım . teşekkürler

 

[şehiriçi]

ek dosyayı unuttum özür

 

[turist]

ek dosyayı unuttum özür

Dosyanızda Apartman adını A1 hücresinde "canbey ap" olarak seçin bakalım,
sizin formül doğru sonuç verecek mi?
İşte bu nedenle uzunca anlatılan edilen formülün açıklamasını bir daha okuyun.

 

[sayildiz]

Tercih Sıralama nasıl yapılır?

Merhaba Arkadaşlar her zaman olduğu gibi yine yardımınıza ihtiyacım oldu.Ekli tabloya bir göz atıp Formülle yardımcı olabilir misiniz? Şimdiden Teşekkür ederim.İyi Çalışmalar.

 

[şehiriçi]

sayın turist : a sütununu ı sütununda indislemeyi göstermiştiniz şimdide örneğin a sütununda altınkent b blokta oturan apartman sakinlerinin adı soyadı telefonunu (sarı renkle işaretledim) j k l sütunlarına nasıl işleyeceğim .yardımlarınız için şimdiden teşekkürler

 

[turist]

sayın turist : a sütununu ı sütununda indislemeyi göstermiştiniz şimdide örneğin a sütununda altınkent b blokta oturan apartman sakinlerinin adı soyadı telefonunu (sarı renkle işaretledim) j k l sütunlarına nasıl işleyeceğim .yardımlarınız için şimdiden teşekkürler

I3 hücresindeki formülü:

=EĞER(SATIRSAY($I$3:I3)>EĞERSAY($A$3:$A$2000;$A$1);"";İNDİS([B][COLOR="Red"]A$3:A$2000[/COLOR][/B];KÜÇÜK(EĞER($A$3:$A$2000=$A$1;SATIR($A$3:$A$2000)-SATIR($A$3)+1);SATIRSAY($I$3:I3))))

şeklinde değiştirin. CTRL ve SHIFT tuşlarına birlikte basılı tutarak ENTER tuşuna basın (DİZİ Formüldür).
Sonra bu formülü, J3, K3, L3 hücrelerine kopyalayın.
Daha sonra I3,J3,K3 ve L3 hücrelerini seçerek kopyalayın, istediğiniz kadar aşağıya yapıştırın.