• DİKKAT

    DOSYA İndirmek/Yüklemek için ÜCRETLİ ALTIN ÜYELİK Gereklidir!
    Altın Üyelik Hakkında Bilgi

Seride koşula uyan en büyük 2. sayıyı bulma

W

weycell78

Katılım
2 Ağustos 2009
Mesajlar
29
Excel Vers. ve Dili
2003
Merhabalar. Linkte rapor kısmında ne istediğimi detaylı yazdım.

Öyle bir formül yazmalıyım ki seri içinden bölüm koduna sahip veriler arasında en küçük 2. ve en büyük 2. rakamları versin.

Çok uğraştım ama bu basit konuyu çözemedim. Yardımcı olabilecek varmı lütfen ?


http://www.dosyaupload.com/1NM2
 
Son düzenleme:
weycell78' Alıntı:
.........
Çok uğraştım ama bu basit konuyu çözemedim.
Genişletmek için tıkla ...
Merhaba.

Aşağıdaki dizi formüllerini kullanabilirsiniz.
Birinci formül B2, ikincisi C2 için kullanılacak.

Dizi formülü hücreye ENTER ile değil, CTRL+SHIFT+ENTER ile girilmelidir.
Doğru yapmışsanız formül, -kendiliğinden- {....} gibi farklı parantez arasına alınır.
.
Kod: 
=KÜÇÜK(EĞER(veri!$A$2:$A$89=$A2;veri!$B$2:$B$89);EĞERSAY(veri!$B$2:$B$89;KÜÇÜK(EĞER(veri!$A$2:$A$89=$A2;veri!$B$2:$B$89);1))+1)
=BÜYÜK(EĞER(veri!$A$2:$A$89=$A2;veri!$C$2:$C$89);EĞERSAY(veri!$C$2:$C$89;BÜYÜK(EĞER(veri!$A$2:$A$89=$A2;veri!$C$2:$C$89);1))+1)
 
Çok teşekkürler. Sizin dediğiniz gibi yaptı oldu. Kendimde aşağıdaki şekilde buldum. Sizce bir hata olur mu ?

Kod: 
=KÜÇÜK(EĞER(A:A=F2;B:B;"");2)
Kod: 
=BÜYÜK(EĞER(A:A=F2;C:C;"");2)
 
Her iki formül için de aynı durum var, ben birinci üzerinden açıklayayım.

Evet son yazdığınız formül hatalı sonuç üretir.

Belirttiğiniz ilk formülün sonucu 99, oysa ikinci küçük değer 199.
Bunun nedeni seri içerisinde, 1'inci küçük sayı olan 99 sayısından 1 tane değil, 3 tane oluşu.
O nedenle birinci küçük sayının adeti +1 'inci sayı 2'nci küçük sayı olur.
.
 
Şimdi daha iyi anladım, süper oldu. bu durumda Sadece bir sorunum kalıyor.

Değerler arasında boş hücre varsa bunu hesap etmesin. Örneğin iki boş hücre varsa bunları 0 mış gibi algılıyor ve sonucu 0 veriyor.
 
Ömer Bey 'in formülüne bir uyarıda bulunmak isterim.
EĞERSAY ile B2:B89 arasındaki değerler saydırılıyor. 663 için en küçük değer olan 99 değeri örneğin 665 için de tekrar ediyor (en son 5 veriyi 99 yapın deneyin örneğin) olursa değer farklı çıkacaktır. Çünkü küçük teki kaçıncı ibaresinin sayısı artacaktır.

Aynı formülü Veri sayfası için
=KÜÇÜK(EĞER($A$2:$A$89=663;$B$2:$B$89);TOPLA(EĞER((($A$2:$A$89=663)*($B$2:$B$89=KÜÇÜK(EĞER($A$2:$A$89=663;$B$2:$B$89);1)));1))+1)

şeklinde değiştimek gerekli olsa gerek..
 
Son düzenleme:
Tekrar merhaba.

Yine dizi formülü.
.
Kod: 
=KÜÇÜK(EĞER($A$2:$A$89=G1;$B$2:$B$89);TOPLA(EĞER($A$2:$A$89=G1;EĞER($B$2:$B$89<=KÜÇÜK(EĞER($A$2:$A$89=G1;EĞER($B$2:$B$89>0;$B$2:$B$89));1);1)))+1)
NOT: Sayın sakman'ın uyarısı dolayısıyla formüle ilave yapıldı.
.
 
Son düzenleme:
Merhabalar,
Alternatif,
Tüm kontrolleri yapamadım, 0'dan küçük sayıları dikkate almadım.

Kod: 
=KÜÇÜK(EĞERHATA(1/(A2:A12=G1)*B2:B12;MAK(B2:B12));2)
[COLOR="Blue"]Formül dizi formülüdür.CTRL+SHIFT+ENTER ile tamamlayınız.[/COLOR]

Ömer Bey,
Formülünüzü şu şekilde dener misiniz?
A2:A12 aralığına kriter (3 tane arayacağımız kriter olsun)
B2:B12 sayılar (kritere karşılık gelen bir hücreyi boş bırakınız)

Sayın Sakman26,
Önerdiğiniz formülde TOPLAM kısmını TOPLA olarak değiştirebilir misiniz?
 
Alternatif olarak deneyiniz.

DİZİ formüldür...

2. Benzersiz Küçük değer;
Kod: 
=KÜÇÜK(EĞER($A$2:$A$25=E3;EĞER($B$2:$B$25<>0;$B$2:$B$25));TOPLA(--($A$2:$A$25&$B$2:$B$25=E3&KÜÇÜK(EĞER($A$2:$A$25=E3;EĞER($B$2:$B$25<>0;$B$2:$B$25));2)))+1)

2. Benzersiz Büyük değer;
Kod: 
=BÜYÜK(EĞER($A$2:$A$25=E3;EĞER($C$2:$C$25<>0;$C$2:$C$25));TOPLA(--($A$2:$A$25&$C$2:$C$25=E3&BÜYÜK(EĞER($A$2:$A$25=E3;EĞER($C$2:$C$25<>0;$C$2:$C$25));2)))+1)
 
Çok teşekkürler ancak hala sorun var.

Korhan Ayhan Bey verdiginiz formül çalışıyor ama en küçük 2. deger için eger 0 yada boş hücre varsa onları dikkate alıyor.
 
Bilgisayar başında değilim.
Son cevabımı denediniz öi acaba?
Doğru sonucu üretmesi lazım.
 
Bende uyarınız üzerine #9 nolu mesajımda ki önerilerimi güncelledim. Deneyebilirsiniz.
 
Cevap yazmak için giriş yap yada kayıt ol.
Geri
Üst