Şehirler arası gidiş-Dönüş

[Mdemir63]

Selamlar
Ekteki dosyada yazdığım formülümde 3 şehir ismi olduğunda herhangi bir sıkıntı olmuyor. Ancak 2 şehir ismi olduğunda formülüm Değer hatası veriyor.
Formülde sanırım bir eksiklik var. Nasıl çözebilirim?

Saygılar

=EĞER(A2="";"";PARÇAAL(A2;BUL("-";A2;BUL("-";A2;1)+1)+1;UZUNLUK(A2))&"-"&PARÇAAL(A2;BUL("-";A2)+1;BUL("-";A2;BUL("-";A2;1)+1)-BUL("-";A2)-1)&"-"&SOLDAN(A2;MBUL("-";A2)-1))

 

[çıtır]

Aşağıdaki şekilde deneyiniz.

=EĞERHATA(EĞER(A2="";"";PARÇAAL(A2;BUL("-";A2;BUL("-";A2;1)+1)+1;UZUNLUK(A2))&"-"&PARÇAAL(A2;BUL("-";A2)+1;BUL("-";A2;BUL("-";A2;1)+1)-BUL("-";A2)-1)&"-"&SOLDAN(A2;MBUL("-";A2)-1));EĞER(A2="";"";PARÇAAL(A2;BUL("-";A2)+1;UZUNLUK(A2))&"-"&PARÇAAL(A2;1;BUL("-";A2)-1)))

 

[Ömer BARAN]

Merhaba.
Elbette çok farklı bir çözüm önerisi değil ama alternatif olsun.

=EĞERHATA(EĞERHATA(PARÇAAL(A2;BUL("|";YERİNEKOY(A2;"-";"|";2))+1;255);PARÇAAL(A2;BUL("|";YERİNEKOY(A2;"-";"|";1))+1;255))&EĞERHATA(PARÇAAL(A2;BUL("-";A2);BUL("|";YERİNEKOY(A2;"-";"|";2))-BUL("-";A2));"")&"-"&SOLDAN(A2;BUL("-";A2)-1);EĞER(A2="";"";A2))

 

[Mdemir63]

Selamlar
Sayın @çıtır ve @Ömer BARAN hocalarım öncelikle teşekkür ederim.
Ben kendi formülüm de neyi eksik yapmışım anlatma şansınız var mı?


Saygılar

 

[Merhum İdris SERDAR]

.

Alternatif:

KTF ile.

Function Ters(aln As Range, Optional ayr As String = "-") As String

    Dim sz1 As Variant, sz2  As Long
    sz1 = Split(aln, ayr)
    For sz2 = UBound(sz1) To LBound(sz1) Step -1
        Ters = Ters & ayr & sz1(sz2)
    Next sz2
    Ters = Replace(Ters, ayr, "", 1, 1)
    
End Function

Dosyanız ekte.

.

 

[Mdemir63]

Sayın @İdris SERDAR hocam elinize sağlık.

Saygılar

 

[Ömer BARAN]

Ben kendi formülüm de neyi eksik yapmışım anlatma şansınız var mı?

Merhaba.
Kullandığınız formülde, metin içerisinde 1 adet "-" karakteri olduğunda aşağıda ilk satırdaki kırmızı kısım hata vereceğinden sonuç alamıyorsunuz.
Mevcut formülünüzü aşağıdaki mavi renklendirilmiş ikinci satırdaki gibi düzenleyerek sorun aşılabilir.

BUL("-";A2;BUL("-";A2;1)+1)
=EĞERHATA(PARÇAAL(A2;BUL("-";A2;BUL("-";A2;1)+1)+1;UZUNLUK(A2));PARÇAAL(A2;BUL("-";A2)+1;UZUNLUK(A2)))&"-"&EĞERHATA(PARÇAAL(A2;BUL("-";A2)+1;BUL("-";A2;BUL("-";A2;1)+1)-BUL("-";A2)-1);"")&"-"&SOLDAN(A2;MBUL("-";A2)-1)

 

[Mdemir63]

Merhaba.
Kullandığınız formülde, metin içerisinde 1 adet "-" karakteri olduğunda aşağıda ilk satırdaki kırmızı kısım hata vereceğinden sonuç alamıyorsunuz.
Mevcut formülünüzü aşağıdaki mavi renklendirilmiş ikinci satırdaki gibi düzenleyerek sorun aşılabilir.

BUL("-";A2;BUL("-";A2;1)+1)
=EĞERHATA(PARÇAAL(A2;BUL("-";A2;BUL("-";A2;1)+1)+1;UZUNLUK(A2));PARÇAAL(A2;BUL("-";A2)+1;UZUNLUK(A2)))&"-"&EĞERHATA(PARÇAAL(A2;BUL("-";A2)+1;BUL("-";A2;BUL("-";A2;1)+1)-BUL("-";A2)-1);"")&"-"&SOLDAN(A2;MBUL("-";A2)-1)

Selamlar
Sayın @Ömer BARAN hocam verdiğiniz açıklama için çok teşekkür ederim.

Saygılar