Sayfayı mail göndermek

[msnnkk]

Arkadaşlar Merhaba
forumda birçok bu konu hakkında başlık var ama istediğimi bulamadım, bulduğum kodları kendime uyarlayamadım o yüzden bu konuyu açıyorum yardım edenlere şimdiden teşekkürler


arkadaşlar konuya dönücek olursak

A1 ve N35 arasında verilerim var bilgi girişi yapılıyor. ve kenarada karaden mail butonu yaptım.

Mail butonuna bastığımda A1 ve N35 arasında verileri 2 tane mail adresine mail atmasını istiyorum direk.(çalışma kitabını değil sadece A1 ve N35 arasındaki veriyi) Mailin konusunuda R20 satırından almasını istiyorum.

Yardımcı olursanız sevinirirm. Teşekkürler.

 

[Asri]

mail adreslerini aşağıdaki alandan değiştiriniz.

.To = "mailadresi1@isim.com;mailadresi2@isim.com;"

Sub mail_secili_alan()
      Dim wrdEdit
      Dim alan As Range
      
      Set alan = Range("A1:N35")
            
      Set OutApp = CreateObject("Outlook.Application")
      Set OutMail = OutApp.CreateItem(0)
      With OutMail
       .To = "mailadresi1@isim.com;mailadresi2@isim.com;"
       .CC = ""
       .BCC = ""
       .Subject = Cells(20, "R").Value
       .Display
       
       'Maili otomatik göndermek için .send deki tırnak işaretini kaldırın.
       '.send
       .HTMLBody = RangetoHTML(alan) & .HTMLBody
       End With
      
      Set wrdEdit = Nothing
      Set OutMail = Nothing
      Set OutApp = Nothing
End Sub

Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2013
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With

    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With

    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.readall
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")

    'Close TempWB
    TempWB.Close savechanges:=False

    'Delete the htm file we used in this function
    Kill TempFile

    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function