sayfalar arası bulma;

[abbasonline]

sayfalar arası bulma ve toplama işlemi makrolu

 

[Ömer]

Merhaba,

Miktar ve tutarı "NETİCE" sayfasında hangi sütunlara yazacak.

 

[abbasonline]

Merhaba,

geçen yıldan olanları 2010 devreden miktar ve tutara - giriş çıkış sayfasındakileride 2011 giren miktar,tutar - çıkan miktar , tutara - kalanlarıda 2012 devreden miktar, tutara yazılacak

 

[abbasonline]

Ömer bey mesajınıza biraz geç cevap yazdým ama kusura bakmayýn interneti ortak kullanýyoruz bazen modem ile ilgili sorunlar olabiliyor.

 

[Ömer]

Bu şekilde deneyin.

Sub Rapor_Al()
 
    Dim dizi(), syf As Worksheet, Wf As WorksheetFunction
    Dim i As Long, j As Byte
    
    Set Wf = WorksheetFunction
    
    Application.ScreenUpdating = False
    
    Sheets("NETİCE").Select
    Range("C3:J" & Rows.Count).ClearContents
    
    dizi = Array("", "geçen yıl", "giriş", "çıkış")
    
    For i = 3 To Cells(Rows.Count, "A").End(xlUp).Row
        For j = 1 To 3
            Set syf = Sheets(dizi(j))
            With syf
                If j = 1 Then
                    Cells(i, "C") = Wf.SumIf(.[G:G], Cells(i, "A"), .[J:J])
                    Cells(i, "D") = Wf.SumIf(.[G:G], Cells(i, "A"), .[L:L])
                ElseIf j = 2 Then
                    Cells(i, "E") = Wf.SumIf(.[G:G], Cells(i, "A"), .[J:J])
                    Cells(i, "F") = Wf.SumIf(.[G:G], Cells(i, "A"), .[L:L])
                ElseIf j = 3 Then
                    Cells(i, "G") = Wf.SumIf(.[G:G], Cells(i, "A"), .[J:J])
                    Cells(i, "H") = Wf.SumIf(.[G:G], Cells(i, "A"), .[L:L])
                End If
            End With
        Next j
        Cells(i, "I") = Cells(i, "C") + Cells(i, "E") - Cells(i, "G")
        Cells(i, "J") = Cells(i, "D") + Cells(i, "F") - Cells(i, "H")
    Next i
    
    Application.ScreenUpdating = True
End Sub

.

 

[abbasonline]

Merhaba
Ömer bey teşekkürler. denemedim deneyince ayrıca bilgi verecegim.

 

[abbasonline]

Merhaba,
Ömer bey çok sağolun makrolar çalışıyor, çok olmazsam birde NETİCE sayfasında A sütununda yazan stok numaralarını yazdığımda diğer 3 sayfadada (giriş, çıkış, geçen yıl) stok numaralarında kontrol etsin eğer stok numarası her üç sayfadada yoksa uyarı vermesi isteyecektim

 

[Ömer]

Sonuçları K sütununda gözlemleyin.

Sub Rapor_Al()
 
    Dim dizi(), syf As Worksheet, Wf As WorksheetFunction
    Dim i As Long, j As Byte, deg As String
    
    Set Wf = WorksheetFunction
    
    Application.ScreenUpdating = False
    
    Sheets("NETİCE").Select
    Range("C3:K" & Rows.Count).ClearContents
    
    dizi = Array("", "geçen yıl", "giriş", "çıkış")
    
    For i = 3 To Cells(Rows.Count, "A").End(xlUp).Row
        For j = 1 To 3
            Set syf = Sheets(dizi(j))
            With syf
                If j = 1 Then
                    Cells(i, "C") = Wf.SumIf(.[G:G], Cells(i, "A"), .[J:J])
                    Cells(i, "D") = Wf.SumIf(.[G:G], Cells(i, "A"), .[L:L])
                    If Wf.CountIf(.[G:G], Cells(i, "A")) > 0 _
                                Then deg = "Var" Else deg = "Yok"
                    Cells(i, "K") = "1.Sayfafa " & deg
                ElseIf j = 2 Then
                    Cells(i, "E") = Wf.SumIf(.[G:G], Cells(i, "A"), .[J:J])
                    Cells(i, "F") = Wf.SumIf(.[G:G], Cells(i, "A"), .[L:L])
                    If Wf.CountIf(.[G:G], Cells(i, "A")) > 0 _
                                Then deg = "Var" Else deg = "Yok"
                    Cells(i, "K") = Cells(i, "K") & " 2.Sayfafa " & deg
                ElseIf j = 3 Then
                    Cells(i, "G") = Wf.SumIf(.[G:G], Cells(i, "A"), .[J:J])
                    Cells(i, "H") = Wf.SumIf(.[G:G], Cells(i, "A"), .[L:L])
                    If Wf.CountIf(.[G:G], Cells(i, "A")) > 0 _
                                Then deg = "Var" Else deg = "Yok"
                    Cells(i, "K") = Cells(i, "K") & " 3.Sayfafa " & deg
                End If
            End With
        Next j
        Cells(i, "I") = Cells(i, "C") + Cells(i, "E") - Cells(i, "G")
        Cells(i, "J") = Cells(i, "D") + Cells(i, "F") - Cells(i, "H")
    Next i
    
    Application.ScreenUpdating = True
 
End Sub

.

 

[abbasonline]

Merhaba,
Ömer bey Teşekkürler, ellerinize sağlık.
ayrıca makrolar ile ilgili bir şey sormak istiyorum, bazen makroyu çalıştırdığımda aşağıdaki gibi hatalar alıyorum bunların anlamı ne demek ve bu hatalar nasıl düzeltilir, sitede arama yaptım ancak açıklayıcı bir bilgiye rastlamadım, yardımlarınız için tekrar teşekkürler.

(WorksheelFunction sınıfının SumIf özelliği alınamıyor.)

(WorksheelFunction sınıfının VLookup özelliği alınamıyor.)

 

[Ömer]

Sanırım formül sonucunda hatalı değer ürettiği zaman bu hatayı alıyorsunuz.

Örneği düşeyara fonksiyonu nasıl aradığını bulamadığı zaman #yok hatası veriyorsa, yüksel ihtimalle bu aldığınız hata da onunla ilgilidir.

 

[abbasonline]

Ömer bey teşekkürler, kolay gelsin.