Sayfa font ayarı!!

[opctebur]

Merhabalar,

excel sayfamıza devamlı farklı sayfalrdan satırlar ekliyoruz...
ama fotlar hep farklı oluyor, kimi farklı font kimi biraz buyuk kimi daha kucuk kimi kalın font oluyor...
sayfaya satırları yapıştırdığımızda otomatik olarak butun satır sütun veya hucrelerın aynı font ve / veya karakterde olmasını nasıl sağlarız.


teşekkürler

 

[Seyit Tiken]

Bu şekilde kendinize uyarlayın.

ActiveCell.Font.Name = "Arial"
ActiveCell.Font.Size = 12
ActiveCell.Font.Bold = 0

 

[opctebur]

Teşekkür ederim..
ama bu sadece seçili olan hücreyi kapsıyor ve buyuk kucuk harf kontrol etmiyor...
benim istediğim butun sayfada bu kontrolu buyuk kucuk harf, font ve karakter olarak yapması...

teşekkürler

 

[Korhan Ayhan]

Merhaba,

Bu işlemi yapacağınız sayfanızın kod bölümüne aşağıdaki kodu uygulayın.

Option Explicit
 
Private Sub Worksheet_Change(ByVal Target As Range)
    On Error Resume Next
    With Cells
        .Font.Name = "Tahoma"
        .Font.Bold = False
        .Font.Size = 10
        .Font.ColorIndex = 0
    End With
End Sub
 
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    On Error Resume Next
    With Cells
        .Font.Name = "Tahoma"
        .Font.Bold = False
        .Font.Size = 10
        .Font.ColorIndex = 0
    End With
End Sub

 

[opctebur]

Teşekkürler...
bu oldu birde buna küçük harfleri buyuk harfe cevirmeyi eklersek harika olacak.

 

[Korhan Ayhan]

Merhaba,

Büyük harf için aşağıdaki uygulamaları yapınız.

Boş bir modüle;

Option Explicit
 
Function HARF_DÜZENİ(Veri As Variant, Optional Tip As Byte = 3)
    Dim AYIR As Variant, SON_KELİME As String
 
    Application.Volatile
 
    If Tip = 1 Then
        HARF_DÜZENİ = UCase(Replace(Replace(Veri, "ı", "I"), "i", "İ"))
    ElseIf Tip = 2 Then
        HARF_DÜZENİ = LCase(Replace(Replace(Veri, "I", "ı"), "İ", "i"))
    ElseIf Tip = 3 Then
        HARF_DÜZENİ = WorksheetFunction.Proper(Veri)
    ElseIf Tip = 4 Then
        AYIR = Split(Veri, " ")
        If UBound(AYIR) = 0 Then
            HARF_DÜZENİ = UCase(Replace(Replace(Veri, "ı", "I"), "i", "İ"))
            Exit Function
        End If
        SON_KELİME = UCase(Replace(Replace(AYIR(UBound(AYIR)), "ı", "I"), "i", "İ"))
        HARF_DÜZENİ = WorksheetFunction.Proper(Replace(Veri, SON_KELİME, "")) & SON_KELİME
    End If
End Function

Sayfanın kod bölümüne;

Option Explicit
Dim Hücre As Range
 
Private Sub Worksheet_Change(ByVal Target As Range)
    On Error Resume Next
 
    Application.EnableEvents = False
 
    With Cells
        .Font.Name = "Tahoma"
        .Font.Bold = False
        .Font.Size = 10
        .Font.ColorIndex = 0
    End With
    For Each Hücre In Cells.CurrentRegion
        Hücre = HARF_DÜZENİ(Hücre.Text, 1)
    Next
 
    Application.EnableEvents = True
End Sub
 
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    On Error Resume Next
 
    Application.EnableEvents = False
 
    With Cells
        .Font.Name = "Tahoma"
        .Font.Bold = False
        .Font.Size = 10
        .Font.ColorIndex = 0
    End With
    For Each Hücre In Cells.CurrentRegion
        Hücre = HARF_DÜZENİ(Hücre.Text, 1)
    Next
 
    Application.EnableEvents = True
End Sub

 

[opctebur]

İlgilenen arkadaşlarıma çok teşekkür ederim...
Korhan AYHAN arkadaşım en son gonderdıgın ornek dosyası tam benım ıstedıgım gibi olmuş...
armut piş azıma düş oldu, çok teşekkür ederim...