Satırlardaki Özel Karakteri Tespit etmek

[nanotech3485]

Merhaba, hergün binlerce satır veri ile uğraşıyorum. Acaba bu satırlarda geçen özel karakterleri bulup satırı sarıya boyamamız mümkün olur mu?

Örneğin noktalama işaretleri dışındaki emoji veya (kril, çin, kore ve grek alfabesi) gibi bir harf geçiyorsa bunlar tespit edilip ilgili satırlar sarıya boyanabilir mi? Bu konu ile ilgili yardımcı olabilir misiniz? Çok teşekkürler.

Örnek dosyayı paylaşıyorum.

Ornek_Dosya.xlsx dosyasını indir - download

Ornek_Dosya.xlsx dosyasını indir, download. Dosya.tc .Dosya Upload. Dosya Paylaş. Dosya Yükle

www.dosya.tc

 

[Haluk]

Sub Test()
'   Haluk - 09/08/2022
'   sa4truss@gmail.com

    Dim regExp As Object, i As Integer
    
    Set regExp = CreateObject("VBscript.RegExp")
    
    regExp.Pattern = "[^\x00-\x7F]"
    
    regExp.Global = True
    
    For i = 1 To Range("A" & Rows.Count).End(xlUp).Row
        If regExp.Test(Range("A" & i)) Then
            Range("A" & i).Interior.Color = vbYellow
        Else
            Range("A" & i).Interior.Color = xlNone
        End If
    Next
    
    Set regExp = Nothing
End Sub

.

 

[nanotech3485]

Sub Test()
'   Haluk - 09/08/2022
'   sa4truss@gmail.com

    Dim regExp As Object, i As Integer
   
    Set regExp = CreateObject("VBscript.RegExp")
   
    regExp.Pattern = "[^\x00-\x7F]"
   
    regExp.Global = True
   
    For i = 1 To Range("A" & Rows.Count).End(xlUp).Row
        If Range("A" & i) <> regExp.Replace(Range("A" & i), "") Then
            Range("A" & i).Interior.Color = vbYellow
        Else
            Range("A" & i).Interior.Color = xlNone
        End If
    Next
   
    Set regExp = Nothing
End Sub

.

Hocam cevabınız için teşekkürler fakat aşağıdaki hatayı verdi.

Run-time error '429':
ActiveX component can't create object

 

[Haluk]

Kod, Excel - Windows için geçerlidir... Başka bir işletim sistemi kullanıyorsanız, bilemem....

.

 

[nanotech3485]

Hocam windowsta denedim çalıştı. elinize sağlık. Yalnız şöyle bir durum var. Aşağıdaki satırda é harfinden dolayı sanırım sarıya boyadı. Aslında bunlarda normal karakterler. Benim istediğim alfabelerde olmayan karakter kullanımlarında uyarı verebilmesi. Böyle birşey mümkün müdür

ADH Ebéniste, Lanoraie, QC J0K 1E0

 

[Haluk]

Kod, Unicode olmayan karakterlere göre çalışır ve ilk mesajınızda durum böyleydi....

.

 

[nanotech3485]

Kod, Unicode olmayan karakterlere göre çalışır ve ilk mesajınızda durum böyleydi....

.

Hocam diğer dilleri dahil edip bir şey yapılabilir mi? İlk mesajımda çok net ifade edememiş olabilirim. Kusura bakmayınız.

 

[Haluk]

Tam olarak test etmedim, siz denersiniz.... eksik karakter varsa, kodda pattern'a ilave edersiniz.

Sub Test2()
'   Haluk - 09/08/2022
'   sa4truss@gmail.com

    Dim regExp As Object, i As Integer
    
    Set regExp = CreateObject("VBscript.RegExp")
    regExp.Pattern = "[^\x00-\x7FàèìòùÀÈÌÒÙáéíóúyÁÉÍÓÚYâêîôûÂÊÎÔÛãñõÃÑÕäëïöüÿÄËÏÖÜŸçÇßØøÅåÆæœ]"
    
    regExp.Global = True
    
    For i = 1 To Range("A" & Rows.Count).End(xlUp).Row
        If regExp.Test(Range("A" & i)) Then
            Range("A" & i).Interior.Color = vbYellow
        Else
            Range("A" & i).Interior.Color = xlNone
        End If
    Next
    
    Set regExp = Nothing
End Sub

.

 

[nanotech3485]

Haluk Hocam çok teşekkür ederim. 15k veri üzerinden test ettim. Şu an gayet başarılı. Hatta birkaç pattern ekledim. Ellerinize sağlık.