satır,sütün,hücre rengi

[polis-53]

merhabalar herkese hayorlı günler. İşleriniz rasgele. Benim bir sorum olacak aşağıdaki kod satır sütün hücre renklendiriyor fakan benim dosyada bazı başlıklarım var bu hucreleri kendime göre renklendirmiştim ama bu kodu sayfaya uygulayınca renklendirmiş olduğum hücrelerin renkleri kayboldu bunu engeleme şansımız varmıdır arkadaşlar.
bir soru 50 sayfam olduğu bir dosyada tek bir yerde uygulayarak tüm sayfalarda çalıştırılabilirmi.

Private Sub Worksheet_SelectionChange(ByVal Target As Excel.Range)
Cells.Interior.ColorIndex = xlColorIndexNone
ActiveCell.EntireColumn.Interior.ColorIndex = 7 'Sütun Rengi
ActiveCell.EntireRow.Interior.ColorIndex = 17 ' Satır Rengi
ActiveCell.Cells.Interior.ColorIndex = 4 ' Hücre Rengi
End Sub

 

[Korhan Ayhan]

Selamlar,

Ekteki örnek dosyayı incelermisiniz.

Makro+Koşullu biçimlendirme ile yapılmıştır. Sayfadaki tüm koşullu biçimlendirmeler silindiği için eğer uygulayacağınız dosyada kendinize ait koşullu biçimlendirmeler varsa bu dosyayı kullanmayınız.

Kodlar ThisWorkbook bölümündedir.

Option Explicit
 
Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
    If Application.CutCopyMode = xlCopy Or Application.CutCopyMode = xlCut Then Exit Sub
    Cells.FormatConditions.Delete
    With Sh
        With .Columns(ActiveCell.Column)
            .FormatConditions.Delete
            .FormatConditions.Add Type:=xlExpression, Formula1:="1"
            .FormatConditions(1).Interior.ColorIndex = 4
        End With
        
        With .Rows("" & ActiveCell.Row & ":" & ActiveCell.Row)
            .FormatConditions.Delete
            .FormatConditions.Add Type:=xlExpression, Formula1:="1"
            .FormatConditions(1).Interior.ColorIndex = 4
        End With
        
        With .Range(ActiveCell.Address)
            .FormatConditions.Delete
            .FormatConditions.Add Type:=xlExpression, Formula1:="1"
            .FormatConditions(1).Interior.ColorIndex = 38
        End With
    End With
End Sub

 

[polis-53]

çok teşekkür ederim