Puantaj Pazar Gün Kriteri

[modoste]

merhaba sayın hocalarım
2010 ve 2011 yılları için puantajsal sorularım olmuştu ve hocalarımdan gelen çözümlerle 2 yıl içinde nerdeyse hatasız bir program kullanmış gibiydim

2012 yılı için şeflerimiz puantajda hesaplamayı değiştirdiler. bende size metinsel olarak ifade etmek istiyorum ekli dosyada göndericem

2012 yılında istenilen şu
bir ay içinde herhangi bir kişi ay içindeki pazar günleri sayısı kadar izin haketmiş olucak.
örneğin ocak 2012 için bunu düşünürsek ayın 1,8,15,22,29 günlerinde çizelgede 5 gün haketmiş olunuyo (ayın 1 inden 31 ine kadar kişi puantajda ise)
ama mesela ayın 14 ünde işe başlayan (14.15.....31) biri için (15,22,29) pazar günlerine tekabül edeceğinden hakettiği izin 3 gün olucak

birde puantaj çizelgesinin işleniş biçimi önemli (kritik yerler buralar)
benim tuttuğum puantajda personeller
herhangi bir günde çalışıyosa "1" yazıyorum genelde puantajlarda "X" işareti oluyo ben matematiksel toplamlarda kolaylık olsun diye böyle yapıyorum

kişi çalışıyosa "1"
kişi izindeyse "İZ"
kişi resmi izindeyse "Rİ"
kişi raporluysa "RP"
kişi çıkmışsa "Ç" yada boşluk

izin hesaplamada kriter alınca karakterler "1";"İZ";"Bİ"
ocak 2012 için düşünürsek ayın 1 inden 31 ine hergün çalışan birinin 1-8-15-22-29 . günlerine denk gelen değer "1";"İZ";"Bİ" ise bu kişi 5 gün izin haketmiş olmalı (işte formül burda olmalı hem pazar günü hemde bu ifadeler kriteri)
ben formülasyonda bocaladım hocalarımdan yardım istiyorum.
sarı renkli yerlere formülasyonlu çözümler olması gerekiyo
ben yanındaki sütuna manule olması gereken cevabı yazdım açıklamaya çalıştım.

not sorduğum soru aralık 2011 günlerine ait ben formülasyonu anlayabilirsem yeni yılı açıcam ve uygulamaya başlayacam.

 

[modoste]

ilk isteğimi şöyle sorayım
ekli tablomda F4:AJ4 arasındaki verilerin cinsine bakılmadan AK4 hücresinde bulmak istediğim sonuç 4 olmalı
01.12.2011-31.12.2011 tarihleri arasında kaç pazar günü buldurma yani
F4:AJ4 arasındaki tarihleri baz alarak kaç pazar günü olduğunu bulma
AK5 hücresinde bulmak istenen değer ise Q5:AJ5 arasında kaç pazar olduğu (Veli BBB nin puantajında ilk hareket Q5 hücresinde başladığı için ilk tarihi Q5 hücresine karşılık gelen Q2 deki tarih almalı)

 

[modoste]

kendimde birşeyler yapmak istiyorum
tarih saat uygulamaları çalışmalarına baktım fakat varsa da göremedim
2 tarih arasında kaç pazar günü olduğunu nasıl bulurum
A1 hücresinde gg.aa.yyyy formatlı tarih var
A2 hücresinde de gg.aa.yyyy formatlı tarih var
örnek A1: 01.01.2012
A2: 31.01.2012 var A2 ile A1 arasında kaç pazar günü var nasıl bulurum
sorumu sordum araştırmalara devm ederken 2 tarih arasında kaç pazar günü oldupğunu
=AŞAĞIYUVARLA((A2-A1+HAFTANINGÜNÜ(A1;1)-1)/7;0)+EĞER(HAFTANINGÜNÜ(A1;1)=1;1;0) sayın hocalarımdan birinin formülüyle bulabilirim artık

 

[Korhan Ayhan]

Merhaba,

Aşağıdaki formülü denermisiniz.

=TOPLA.ÇARPIM((HAFTANINGÜNÜ($F$2:$AJ$2;2)=7)*($F4:$AJ4<>"")*($F4:$AJ4<>"Ç"))

 

[modoste]

hocam birazdan deneyecem
sizede daha detayı ne yapmak istediğimi sormam gerekişyo anlatımda hata yada fazla detay söylemiş olablirim.

 

[modoste]

hocam yaptığınız formülün açıklamasını yapabilirmisiniz
anladığım kadarıyla;
(HAFTANINGÜNÜ($F$2:$AJ$2;2)=7) demekle F2:AJ2 arasında pazar günleri olanların
$F4:$AJ4<>"" F4:AJ4 arası değerlerden boş olmayanların
$F4:$AJ4<>"Ç") F4:AJ4 arasında "Ç" yazmayanların toplamı mı demek oluyo

eğer anladığım gibi ise .... *($F4:$AJ4<>"")*($F4:$AJ4<>"Ç")) bu kısmında kriter eklemem gerekebilecek
mesela, F4:AJ4<>"RP" gibi

topla.çarpım antığında formüllerde son kısımda yer alan (şu aralıkta şu olmayanların) * (şu aralıkta şu olmayanların) *... kısımlarını tek bir parantezde yazılması durumu yapılabilirmi örnekleyecem ama excelde böyle forumül yoktur gibi
=TOPLA.ÇARPIM((HAFTANINGÜNÜ($F$2:$AJ$2;2)=7)*($F4:$AJ4<>"";<>"Ç";<>"RP":"Zİ") istediğimi anlatabilmişimdir umarım

sizin formülünüzü genişleterek
=TOPLA.ÇARPIM((HAFTANINGÜNÜ($F$2:$AJ$2;2)=7)*($F5:$AJ5<>"")*($F5:$AJ5<>"Ç")*($F5:$AJ5<>"RP")*($F5:$AJ5<>"Rİ")*($F5:$AJ5<>"Z.İ")*($F5:$AJ5<>"B.İ")) halinde uyguladım ve sonuçları doğru Korhan Hocam formülün daha sadeleştirilmiş hali yada alternatif diğer formüller nelerdir

 

[modoste]

=TOPLA.ÇARPIM((HAFTANINGÜNÜ($F$2:$AJ$2;2)=7)*($F5:$ AJ5<>"")*($F5:$AJ5<>"Ç")*($F5:$AJ5<>"RP")*($F5:$AJ 5<>"Rİ")*($F5:$AJ5<>"Z.İ")*($F5:$AJ5<>"B.İ"))

bu formülüm alternatif formülü nü yazabilir mi sayın hocalarım

 

[Korhan Ayhan]

Merhaba,

Sorgulama yaptığınız alandaki kriterleriniz metinsel ifadelerden oluşuyor. Bu durumda aşağıdaki şekilde kullanabilirsiniz.

=TOPLA.ÇARPIM((HAFTANINGÜNÜ($F$2:$AJ$2;2)=7)*($F5:$AJ5<>"")*(DEĞİL(EMETİNSE($F5:$AJ5))))

 

[modoste]

sayın Korhan Hocam en son yazdığınız formülasyon hatalı sonuç verdi. bir detayı atladınız aralıkta yazan her metinsel ifadeden olmayanı saydırmıyoruz mesela "İZ" yazanları saydırıyorum.
benim mantıksal olarak sormak istediğim yada asıl formüle alternatif formül nasıl olur idi.
=TOPLA.ÇARPIM((HAFTANINGÜNÜ($F$2:$AJ$2;2)=7)*($F5: $ AJ5<>"")*($F5:$AJ5<>"Ç")*($F5:$AJ5<>"RP")*($F5:$AJ 5<>"Rİ")*($F5:$AJ5<>"Z.İ")*($F5:$AJ5<>"B.İ")) doğru sonuçla veren bu formül yerine geçebilecek daha kısaltılmış bir formül yazılabilirmi

bu formülün anlamı
F2:A2 aralığında Pazar güne denk gelenlerden
F5:A5 aralığında, "" olmayanların, "Ç" olmayanların,"RP" olmayanların,"Rİ" olmayanların,"Z.İ" olmayanların,"B.İ" olmayanların toplamını bulma
işte olmayanların kısmını daha sade bi halde yazmak mümkünmü (sorgulanan aralık aynı olması formülü sade hale getiremezmi)

 

[Korhan Ayhan]

Merhaba,

Aşağıdaki formülü deneyin.

=TOPLA.ÇARPIM((HAFTANINGÜNÜ($F$2:$AJ$2;2)=7)*($F5:$AJ5<>"")*(DEĞİL(ESAYIYSA(MBUL({"";"Ç";"RP";"Rİ";"Z.İ";"B.İ"};$F5:$AJ5)))))

 

[uzmanamele]

Merhaba

Sorunuzu baştan sona okumadım ama nasıl birşey yapmaya çalıştığınızı biliyorum.
Korhan bey'in son formülüne 1 kriter daha koymak istediğiniz çözüme ulaştırır sanıyorum.

=TOPLA.ÇARPIM((HAFTANINGÜNÜ($F$2:$AJ$2;2)=7)*($F6:$AJ6<>"")*[COLOR="Blue"]($F6:$AJ6<>"Ç")[/COLOR]*(DEĞİL(ESAYIYSA(MBUL({"";"Ç";"RP";"Rİ";"Z.İ";"B.İ"};$F6:$AJ6)))))

Yalnız puantaj dosyasında sorun var, hata yapmaya çok müsait, çalışılmayan günleri harflerle ifade ederken bunu manuel yazarsanız yaptığınız hatayı görmeniz çok zor olur.
örneğin; Bİ veya B.İ şeklinde 2 farklı ifade olmaz. bunlar için veri doğrulama kullanın, hata yapmazsınız.

 

[modoste]

sayın hocam formülü uyguluyorum

=TOPLA.ÇARPIM((HAFTANINGÜNÜ($F$2:$AJ$2;2)=7)*($F5:$AJ5<>"")*(DEĞİL(ESAYIYSA(MBUL({"";"Ç";"RP";"Rİ";"Z.İ";"B.İ"};$F5:$AJ5)))))


sizin formülünüzü uygulayıp şimdi ekleyeceğim formülde hatalı sonuç buluyo formülde bi uyumsuzluk var gibi
ALi adlı kişinin (01.01.2012-31.01.2012) günleri arasında işlenmiş puantajında ayın (1-8-15-22-29) una karşılık gelen pazar günleri için sadece 08.01.2012 ye rastlayana pazar gününde "İZ" ifadesi olduğu için 1 gün izin haketmesi gerekiyo

formülün mantığından pazar günlerine karşılık gelen günlerde (Ç,B.İ,RP,Z.İ,"").."olmayan günler toplamıda 1 yapması gerekmez mi hata lı olan ne acaba

 

[modoste]

sayın uzmanamele hocam sizin formülüde deniyorum ama biryerde hata veriyo gibi
tam anlayamadım çözümü uyguluyorum formülüama hatalı sonuç veriyo
irdeleyebilirmisiniz.

sizin formülüde uygulayıp dosyamı ekliyorum doğru cevap 1 çıkması gerekirken sizin formülde 4 çıkıyo

 

[Korhan Ayhan]

Merhaba,

Birde aşağıdaki formülü denermisiniz.

Kriterlerinizi AO1:AO10 aralığına yazın.

=TOPLA.ÇARPIM((HAFTANINGÜNÜ($F$2:$AJ$2;2)=7)*($F4:$AJ4<>"")*(1-EĞERSAY($AO$1:$AO$10;$F4:$AJ4)))

 

[Ömer]

Merhaba,

Alternatif olsun.

AK4 hücresindeki formüle göre;

=TOPLA.ÇARPIM((HAFTANINGÜNÜ($F$2:$AJ$2;2)=7)
 *EHATALIYSA(KAÇINCI($F4:$AJ4;{0;"ÇIKIŞ";"RP";"Rİ";"Z.İ";"B.İ"};0)))

yazılabilir.

.

 

[modoste]

tek kelimeyle mükemmel 2 çözümleme olmuş sayın Korhan Hocam ve Ömer hocam
alternatif çözümler her zaman düşünceyi arttırıyo
izne ayrılıyorum döndüğümde tek bir örnek için deneyip sizlerden gelen fomülasyonu tüm çizelgee aktarmaya çalışacağım