Soru PDF Yap Mail Olarak Gönder

[kk199]

Kendinize göre düzenlersiniz.

Bir butona kodu tanımlayp kullanabilirsiniz.

Diğer kodlarınızı silebilirsiniz.

Option Explicit

Sub MAIL_GONDER()
    Dim S1 As Worksheet, S2 As Worksheet
    Dim Uygulama As Object, Yeni_Mail As Object
    Dim Yol As String, Dosya_Adi As String, Son As Long
  
    Set S1 = Sheets("PDF")
    Set S2 = Sheets("VERİ")
  
    Yol = ThisWorkbook.Path & Application.PathSeparator
    Dosya_Adi = S2.Range("E3").Value & "-" & S2.Range("E7").Value & ".pdf"

    Son = S1.Cells(S1.Rows.Count, "B").End(xlUp).Row
  
    S1.Range("A1:AR" & Son).ExportAsFixedFormat Type:=xlTypePDF, _
    Filename:=Yol & Dosya_Adi, _
    Quality:=xlQualityStandard, _
    IncludeDocProperties:=True, _
    IgnorePrintAreas:=False, _
    OpenAfterPublish:=False
  
    On Error Resume Next
    Set Uygulama = GetObject(, "Outlook.Application")
    On Error GoTo 0
 
    If Uygulama Is Nothing Then Call Shell("Outlook.exe", vbHide)
 
    Set Uygulama = CreateObject("Outlook.Application")
    Set Yeni_Mail = Uygulama.CreateItem(0)

    With Yeni_Mail
        .Display
        .To = S2.Range("E8").Value
        .Subject = S2.Range("E9").Value
        .HtmlBody = S2.Range("E10").Value & vbCr & .HtmlBody
        .Attachments.Add Yol & "\" & Dosya_Adi
        .Save
        .Send
    End With
  
    Set S1 = Nothing
    Set S2 = Nothing
    Set Uygulama = Nothing
    Set Yeni_Mail = Nothing
  
    MsgBox "Mail gönderilmiştir.", vbInformation
End Sub

Merhaba;

Kodlarınız çok güzel şekilde çalışmakta. Fakat ben çalışma sayfasını PDF değil de yine Excel olarak kaydederek eklemek istiyorum maile.
"ExportAsFixedFormat Type" kodu sadece PDF olarak kaydetmek için kullanılıyor sanırım. Bu yüzden kodları değiştiremedim.
Yardımcı olabilir misiniz?

 

[Korhan Ayhan]

Ayrı bir başlık açarak sorunuzu yineleyebilirsiniz. Çünkü bu başlık pdf kaydetmeyle ilgili bir başlık. Sorunuzu örnek dosya ile desteklerseniz daha hızlı yanıt alabilirsiniz.