Pdf Kaydetme, Tek sayfalı Dosya Hk.

[yucelcicekcioglu]

ÖN DÜZELTME: ÇALIŞMA KİTABI BİRKAÇ SAYFADAN OLUŞUYORSA VE YALNIZCA TEK SAYFA GÖRÜNÜR, DİĞERLERİ GİZLİ İSE HATA VERİYOR.

Sayın hocalarım,

ekte göndermiş olduğum "PDF ÇALIŞMA REVİZE" adlı dosyada herhangi bir excel dosyasını kendi adı ile masaüstüne kaydedebiliyorum ancak

"sheets.select" satırından dolayı çoklu sayfalarda çalışıyor tek sayfalı bir dosya olursa hata veriyor, "PDF ÇALIŞMA REVİZE2" dosyasında "if" ile birşeyler denedim ancak bir yerde hata yapıyorum sanırım yardımcı olabilir misiniz ? teşekkürler.

mevcut kod ile birlikte tek sayfalı bir dosyayı kaydetmeye çalıştığımda 16. satırda hata alıyorum

http://s4.dosya.tc/server5/m6z92w/PDF_KAYDETME.rar.html

 

[bonoparte]

Merhaba,

Aşağıdaki kod işini görebilir.

Sub PDFActiveSheet()

Dim wsA As Worksheet
Dim wbA As Workbook
Dim strTime As String
Dim strName As String
Dim strPath As String
Dim strFile As String
Dim strPathFile As String
Dim myFile As Variant
On Error GoTo errHandler

Set wbA = ActiveWorkbook
Set wsA = ActiveSheet
strTime = Format(Now(), "ddmmyyyy\_hhmm")

'get active workbook folder, if saved
strPath = wbA.Path
If strPath = "" Then
  strPath = Application.DefaultFilePath
End If
strPath = strPath & "\"

'replace spaces and periods in sheet name
strName = Replace(wsA.Name, " ", "")
strName = Replace(strName, ".", "_")

'create default name for savng file
strFile = strName & "_" & strTime & ".pdf"
strPathFile = strPath & strFile

'use can enter name and
' select folder for file
myFile = Application.GetSaveAsFilename _
    (InitialFileName:=strPathFile, _
        FileFilter:="PDF Files (*.pdf), *.pdf", _
        Title:="Select Folder and FileName to save")

'export to PDF if a folder was selected
If myFile <> "False" Then
    wsA.ExportAsFixedFormat _
        Type:=xlTypePDF, _
        Filename:=myFile, _
        Quality:=xlQualityStandard, _
        IncludeDocProperties:=True, _
        IgnorePrintAreas:=False, _
        OpenAfterPublish:=False
    'confirmation message with file info
    MsgBox "PDF Dosyası oluşturuldu." _
      & vbCrLf _
      & myFile
End If

exitHandler:
    Exit Sub
errHandler:
    MsgBox "PDF Dosya oluşturulamadı."
    Resume exitHandler
End Sub

 

[yucelcicekcioglu]

ön düzeltme: çalışma kitabı birkaç sayfadan oluşuyorsa ve yalnızca tek sayfa görünür, diğerleri gizli ise hata veriyor.