Outlookla hücreyi gönderme ve imza sorunu

[muyat]

Outlooktan aşagıdaki 2 hücrenin içindeki renkli yazıyı aşagıdaki gibi seçtigimde yazılar outlook body ekranına renksiz olarak yapışarak çıkıyor?
1-Body alanına kopyaladıgım yazıyı renkli olarak nasıl yapıştırabilirim?
2-İlk yazdıgım şey mümkün değilse aşagıdaki hücre içindeki yazılar outlook ekranına yapıştıgı an imleç yazının en sonuna yanına H25'in sonuna gitsin istiyorum.Fakat her nedense imleç sürekli yazının en başında kalıyor.Bu iki dedigim şeyi saatlerdir yapamadım?

.Body = SA.Range("A2016").Value & _
Chr(10) & _
Chr(10) & _
SA.Range("H25").Value & _

 

[Asri]

aşağıdaki fonksiyonu kullanarak dener misiniz?

.body olmayacak .htmlbody olmalı.

Set alan1=SA.Range("A2016")
set alan2=SA.Range("H25")

.Htmlbody = "<br>" & RangetoHTML(alan1) & "<br>" & "<br>" & RangetoHTML(alan2) & .Htmlbody

Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2016
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With

    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With

    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.readall
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")

    'Close TempWB
    TempWB.Close savechanges:=False

    'Delete the htm file we used in this function
    Kill TempFile

    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function