malzeme seçme ve kaydetme

[sirkülasyon]

Sayfa1 de yer alan commanbuton1 düğmesi Sayfa2 de çalışmıyor.
Birde userformdaki taşınır malzeme adı Sayfa2 de ki taşınır malzeme adı altına "D7 hücresinden itibaren "alt alta seçtikçe kaydetsin.

şimdiden teşekkür ederim

 

[Emir Hüseyin Çoban]

Sayfa1 de yer alan commanbuton1 düğmesi Sayfa2 de çalışmıyor.

. . .

Bunun için aşağıdaki kodları, userformdakiler ile değiştirin.
Sorunuzun geri kalanı için Combobaxların hangi sütunlara gelmesi gerektiğini belirtiniz.

. . .

Option Explicit

Private Sub ComboBox1_Change()
    Dim DİZİB As New Collection, HÜCRE As Range, VERİ As Variant
    
    On Error Resume Next
    
    For Each HÜCRE In Sheets("Sayfa1").Range("A2:A" & Sheets("Sayfa1").Range("A65536").End(3).Row)
        If HÜCRE.Value = ComboBox1 Then
        DİZİB.Add HÜCRE.Offset(0, 1).Value, CStr(HÜCRE.Offset(0, 1).Value)
        End If
    Next
    
    On Error GoTo 0
    
    ComboBox2.Clear
    
    For Each VERİ In DİZİB
        ComboBox2.AddItem VERİ
    Next
End Sub

Private Sub ComboBox2_Change()
    Dim DİZİC As New Collection, HÜCRE As Range, VERİ As Variant
    
    On Error Resume Next
    
    For Each HÜCRE In Sheets("Sayfa1").Range("A2:A" & Sheets("Sayfa1").Range("A65536").End(3).Row)
        If HÜCRE.Value = ComboBox1 And CStr(HÜCRE.Offset(0, 1).Value) = ComboBox2 Then
        DİZİC.Add HÜCRE.Offset(0, 2).Value, CStr(HÜCRE.Offset(0, 2).Value)
        End If
    Next
    
    On Error GoTo 0
    
    ComboBox3.Clear
    
    For Each VERİ In DİZİC
        ComboBox3.AddItem VERİ
    Next
End Sub

Private Sub ComboBox3_Change()
    Dim DİZİD As New Collection, HÜCRE As Range, VERİ As Variant
    
    On Error Resume Next
    
    For Each HÜCRE In Sheets("Sayfa1").Range("A2:A" & Sheets("Sayfa1").Range("A65536").End(3).Row)
        If HÜCRE.Value = ComboBox1 And CStr(HÜCRE.Offset(0, 1).Value) = ComboBox2 And CStr(HÜCRE.Offset(0, 2).Value) = ComboBox3 Then
        DİZİD.Add HÜCRE.Offset(0, 3).Value, CStr(HÜCRE.Offset(0, 3).Value)
        End If
    Next
    
    On Error GoTo 0
    
    ComboBox4.Clear
    
    For Each VERİ In DİZİD
        ComboBox4.AddItem VERİ
    Next
End Sub


Private Sub UserForm_Initialize()
    Dim DİZİA As New Collection, HÜCRE As Range, VERİ As Variant
    
    On Error Resume Next
    
    For Each HÜCRE In Sheets("Sayfa1").Range("A2:A" & Sheets("Sayfa1").Range("A65536").End(3).Row)
        DİZİA.Add HÜCRE.Value, CStr(HÜCRE.Value)
    Next
    
    On Error GoTo 0
    
    For Each VERİ In DİZİA
        ComboBox1.AddItem VERİ
    Next
End Sub

. . .

 

[sirkülasyon]

Hüseyin bey;
AKTAR düğmesi ile sayfa2 de d7 den itibaren alt alta taşınır malzeme adını yazabilir miyiz?
Yardımınız için teşekkür ederim

 

[Emir Hüseyin Çoban]

. . .

Aktar butonu için

Private Sub CommandButton1_Click()
Sheets("sayfa2").Range("A7:I50").ClearContents
Dim S1sonsat, i, S2sonsat
S1sonsat = Sheets("Sayfa1").[A65536].End(3).Row

For i = 2 To S1sonsat
If Sheets("Sayfa1").Cells(i, "A") = ComboBox1 And _
Sheets("Sayfa1").Cells(i, "B") = ComboBox2 And _
Sheets("Sayfa1").Cells(i, "C") = ComboBox3 Then

S2sonsat = Sheets("Sayfa2").[D65536].End(3).Row + 1
Sheets("Sayfa2").Cells(S2sonsat, "D") = Sheets("Sayfa1").Cells(i, "D")
Else: End If
Next i

End Sub

. .

 

[sirkülasyon]

Hüseyin abi hepsini aktardı bu?
Sadece seçilen aktarılsın olabilir mi?

 

[Emir Hüseyin Çoban]

. . .

Örnek bir ürün için listenin doldurulmuş halini ekleyin, ona göre kodlayalım.

. . .

 

[sirkülasyon]

Hüseyin abi;
Userformu açtığımız zaman "taşınır malzeme adı" dördüncü combobox da yer alan taşınır ne ise sadece onu yazsın.
İkinci bir seçimde ne seçildi ise bu sefer altına onu yazsın.

 

[Emir Hüseyin Çoban]

. . .

Private Sub CommandButton1_Click()
Dim S2sonsat
S2sonsat = Sheets("Sayfa2").[D65536].End(3).Row + 1
Sheets("Sayfa2").Cells(S2sonsat, "D") = ComboBox4
End Sub

. . .

 

[sirkülasyon]

Hüseyin Abi ;
Teşekkür ederim. Allah senden razı olsun. Ellerine sağlık