makro ile sheet bulma

[hergelex]

merhaba makro ile herhangi bir text yada numberi icerisnd birkac tane sheet bulunan bir workbookta aratip sonuc olarak icind bulunan sheetin ismini weren 1kod var midir?

 

[Orion1]

merhaba makro ile herhangi bir text yada numberi icerisnd birkac tane sheet bulunan bir workbookta aratip sonuc olarak icind bulunan sheetin ismini weren 1kod var midir?

Türkçemizi katletmişsiniz.Tamam , bizde hata yapıyoruz ama bu sizin ki resmen cinayet.Yazınızı düzeltirseniz,sorunuza cevap vericem.

 

[uzmanamele]

Türkçemizi katletmişsiniz.Tamam , bizde hata yapıyoruz ama bu sizin ki resmen cinayet.Yazınızı düzeltirseniz,sorunuza cevap vericem.

.
.
.
:bravo:

 

[hergelex]

Türkçemizi katletmişsiniz.Tamam , bizde hata yapıyoruz ama bu sizin ki resmen cinayet.Yazınızı düzeltirseniz,sorunuza cevap vericem.

Kusura bakmayın Evren Bey;

Mesaji cep telefonu kullanarak, dar bir zamanda yazmiş olduğumdan dolayı, haberimiz olmadan değişen çağ ve koşulların neticesinde farketmeden yozlaştırdığımız Tükçemizi kullanmış bulundum, uyarınız için ayrıca teşekkür ederek, sorumu iletmek isterim...

Benim üzerinde çalışmış olduğum bir çalışma kitabında birden çok sayfa mevcut, sayfa 1 de dağınık halde bulunan sözcük ve sayıları, varsa başka sayfalarda aratmak istiyorum ve eğer bulursa cevaben o sayfanın ismini herhangi bir hücreye atamasını ya da sadece "TRUE" ya da "FALSE" olarak tanımlamasını istiyorum...


Örnek olarak;

Sayfa 1 de d1 hücresi "ahmet"

aynı zmanda sayfa 7 de d41 de yazılı...

1 - sayfa 1 f1 e sayfa 7 yazdırılması
2 - eğer 1 olmuyorsa f1 e true yada false ataması...

yardımlarınıza göre ben kodu geliştirebilirim sanıyorum...

 

[leumruk]

Merhaba,
Aşağıdaki örneği inceleyiniz. Adresleri f sütununa çıkarıyor.

Sub Ara()
Columns("f").ClearContents
Sat = 1
For Each Bul In Range("a1:d20")
If Bul = "" Then GoTo Atla
  For x = 2 To Sheets.Count
    With Sheets(x).Cells
    Set c = .Find(Bul, LookIn:=xlValues, SearchOrder:=xlByRows)
    If Not c Is Nothing Then
        firstaddress = c.Address
        Do
        Cells(Sat, "f") = Sheets(x).Name & " " & c.Address
        Set c = .FindNext(c)
        Sat = Sat + 1
        Loop While Not c Is Nothing And c.Address <> firstaddress
    End If
    End With
  Next
Atla:
Next
End Sub

 

[leumruk]

Ayrıca bu kodla da farklı bir şekilde sıralama yaptırabilirsiniz. Önce aranan veriyi yanına da bulduğu adresleri yazar. Tercih sizin.

Sub Ara()
Columns("f").ClearContents
Sat = 1
For Each Bul In Range("a1:d20")
If Bul = "" Then GoTo Atla
  For x = 2 To Sheets.Count
    With Sheets(x).Cells
    Set c = .Find(Bul, LookIn:=xlValues)
    If Not c Is Nothing Then
        firstaddress = c.Address
        Do
        Aranan = Aranan & " - " & Sheets(x).Name & " " & c.Address
        Set c = .FindNext(c)
        Loop While Not c Is Nothing And c.Address <> firstaddress
    End If
    End With
  Next
  Cells(Sat, "f") = Bul & ": " & Aranan
  Aranan = ""
  Sat = Sat + 1
Atla:
Next
End Sub

 

[Korhan Ayhan]

Selamlar,

Aşağıdaki kodu denermisiniz.

Option Explicit
 
Sub SAYFALARDA_ARA()
    Dim SAYFA As Worksheet, X As Long, BUL As Range
    
    Range("F:F").ClearContents
    
    For Each SAYFA In Worksheets
        If SAYFA.Name <> ActiveSheet.Name Then
        For X = 1 To Range("D65536").End(3).Row
            If Cells(X, "D") <> Empty Then
                Set BUL = SAYFA.Cells.Find(Cells(X, "D"))
                If Not BUL Is Nothing Then
                    Cells(X, "F") = SAYFA.Name
                End If
            End If
        Next
        End If
    Next
    
    Set BUL = Nothing
    
    MsgBox "İşleminiz tamamlanmıştır.", vbInformation
End Sub

 

[hergelex]

cevap olarak vermiş olduğunuz iki kodda aktif olarak çözüme ulaştırdı ve çalıştı cevaplarınızı için çok teşekkür ederim...