Makro ile formül yazdırmak

[trmusic]

Merhaba;

EK'te göndermiş olduğum dosyada C2, C3, E2, E3 hücrelerinde formüller bulunmaktadır. Benim istediğim bu dosyada açılır bir UserForm var ve bu form ile bilgi girişi yaparken bu formülleri de aynı şekilde yazsın. Ayrıca P sütununda da UserForm ile bilgi işlendiği günü otomatik atamasını istiyorum. Mümkün müdür? Yardımlarınızı bekler şimdiden teşekkür ederim.

 

[mancubus]

anladığım kadarı ile B sütununa kayıt sıra no gibi bir şey yazdırmak istiyorsunuz. fakat sonra aynı sütuna TextBox6'daki veriyi yazdırıyorsunuz. farklı renk ile belirttim. düzeltmek lazım.

Private Sub Kaydet_Click()

    Dim ss As Long
    
    With Worksheets("Giriş")
        ss = .Range("B" & .Rows.Count).End(xlUp).Row + 1
        .Cells(ss, "B") = Application.Max(.Columns("B")) + 1
        .Cells(ss, "J") = TextBox1.Text
        .Cells(ss, "K") = TextBox2.Text
        .Cells(ss, "Q") = TextBox3.Text
        .Cells(ss, "R") = TextBox4.Text
        .Cells(ss, "A") = TextBox5.Text
[COLOR="Red"]        .Cells(ss, "B") = TextBox6.Text 'BURASI DÜZELTİLMELİ
[/COLOR]        .Cells(ss, "D") = TextBox7.Text
        .Cells(ss, "F") = TextBox8.Text
        .Cells(ss, "G") = TextBox9.Text
        .Cells(ss, "H") = TextBox10.Text
        .Cells(ss, "I") = TextBox11.Text
        .Cells(ss, "C").FormulaR1C1 = "=IF(RC[7]&RC[8]="""",""Boş"",IF(RC[8]="""",TODAY()-RC[7],TODAY()-RC[8]))"
        .Cells(ss, "E").FormulaR1C1 = "=IF(RC[12]="""","""",IF(RC[13]="""",RC[12],""""))"
        .Cells(ss, "P") = Date
    End With
    
    ActiveWorkbook.Save
    
    MsgBox "Bilgi Girişi Yapıldı.", vbInformation

End Sub

 

[trmusic]

Ellerinize sağlık çok teşekkürler.

 

[mancubus]

rica ederim.

hücredeki formülü olduğu gibi koda aktarmak istiyorsak ve nasıl yapacağımızı bilmiyorsak en iyi yollardan bir tanesi makro kaydedici'den yardım almaktır.

makro kaydedici'yi çalıştırdıktan sonra formül olan hücreyi seçerek F2 ve ENTER tuşlarına basıp sonra kaydediciyi durdururuz.

VBE'ye girdiğimizde bir modül içinde formülün VBA'deki karşılığını görürüz. R1C1 adres referansı satır ve sütun numaralarının ne olacağı konusunda endişeleri ortadan kaldırır.

 

[trmusic]

Aydınlatıcı bilgiler için tekrar teşekkür ederim.